D:ドライブにいくつかのフォルダーがあるとしましょう：

D:\Air
D:\Abonden
D:\All
D:\Whatever

「A」で始まるすべてのフォルダー（すべてのサブフォルダーとファイルを含む）を削除したい。私はこのコマンドを試しました：

rmdir D:\A* /s /q

しかし、エラーが表示されます:(

ファイル名、ディレクトリ名、またはボリュームラベルの構文が正しくありません。

このdelコマンドはで機能し*ますが、フォルダーも削除する必要があります。コマンド
を介してそれを達成する方法はありrmdirますか？

cd c:\temp
for /f %i in ('dir /a:d /s /b A*') do rd /s /q %i

ただし、これを使用してテストします。

for /f %i in ('dir /a:d /s /b A*') do echo rd /s /q %i

これにより、実行されるコマンドがコマンドプロンプトにパイプされ、何が起こっているのかを確認できます。

これにより、「C：\ temp \ jjj \ aaa」などのサブフォルダーも検索され、aaaフォルダーが削除されることに注意してください。最上位のフォルダー「C：\ temp \ aaa」のみを参照する場合"/s"は、コマンドから削除します。

これの鍵は、検索文字列に入力するA *です。これは、ワイルドカードなどを受け入れるaaa*、aaa*と*aaa*あなたはそれがしたい場合。

ワイルドカードを使用してフォルダーを削除する

rmdir/ rdコマンドだけでは対応していません。ワイルドカード文字を（つまり、*と?）。この制限を回避するには、forループでラップします。

使用例

for /d %G in ("X:\A*") do rd /s /q "%~G"

注ファイルとフォルダーを削除する場合、rdコマンドをecho最初に置き換えることができます。このようにして、実際に削除されるべきではないものはすべて確認できます。

複数のパターン

異なるパターンに一致する複数のフォルダーを削除するために、構文はそれほど変わりません。@dbenhamが正しく指摘したように、1行のコマンドで十分です。別のパスを指定することもできます。

for /d %G in ("X:\A*","Y:\Whatever\B*","Z:\C?D") do rd /s /q "%~G"

ボーナス-フォルダーの存在の確認

特定のフォルダーが存在するかどうかを確認する場合は、次のコマンドを使用できます。

dir /b /a:d "X:\A*" >nul 2>&1 && echo Folders exist. || echo No folders found.

参考文献

• for / d-ディレクトリをループします
• 条件付き実行
• コマンドラインリファレンス

誰もまだforfilesについてOPに言っていないのですか？！

forfiles /P D:\ /M A* /C "cmd /c if @isdir==TRUE rmdir /s /q @file"

/ Pはパス名-検索を開始する場所
/ Mは検索マスクで、Aで始まるファイルを探します
/ Cは実行するコマンドです
/ Sは再帰的なサブフォルダーです（opは要求しなかったため、ここには含めませんでした）

adn31415の答えは正しいですが、これをバッチまたはcmdスクリプトに入れると壊れます。私はこれがあなたがそれをどのように使用するかを理解するまで、何時間も頭を打ちました。

DOSコマンドウィンドウで：

for /d %G in ("X:\A*") do rd /s /q "%~G"

Batchまたはcmdスクリプトで：

for /d %%G in ("X:\A*") do rd /s /q "%%~G"

「.bat」または「.cmd」ファイルに配置する場合は、「％」文字を2倍にする必要があります。