新しいバージョンがリリースされるたびにFlash Playerを自動的に更新するにはどうすればよいですか？

概要：

Flash Playerのアップデートサービスは、信頼性の高いスケジュールで実行されません、それはときに自動的に更新をダウンロードし、適用されないん実行します。

最新バージョンのFlash Playerをインストールすることの重要性を考慮して（組み込みプレーヤーでChromeを使用していない人のために）、新しい更新プログラムが迅速に検出されるようにする方法を見つけたいと思います。そしてインストール。

以下は、この問題を自分で解決するための私の努力の詳細です...

付録A：Flash Playerアップデートサービス

Flash Playerの11.2でOK、ウェイバック（またはそう？）Adobeはそれをして、Flash Playerの更新サービス（FlashPlayerUpdateService.exe）を加えはず Flash Playerが最新の状態に保つために...

• インストール時に、FPUSはWindowsサービスとして実行するように設定され、開始タイプは手動に設定されます。

• このサービスを1時間ごとに開始するために、スケジュールされたタスク（Adobe Flash Player Updater.job）が追加されます。

これまでのところ、非常に良い-この設定により、継続的に実行されるサービスを回避できますが、更新が迅速に検出されるのに十分な頻度でチェックが実行されるようになります。Googleのソフトウェアアップデータは、同様のやり方で構成され、それがうまく動作します...

...さらに、インストールされているFlash Playerのバージョンを確認したところ、11.6.602.180であることがわかりました。これは、3月12日火曜日C:\Windows\System32\Macromed\Flashに最終更新（またはインストール）されたファイルのタイムスタンプに基づいています。 2013 --- 3/12 / 13、5：00：08pm。

2013年4月25日（木）13時4月25日7:00:00にこの観察を行い、AdobeのWebサイトを確認したところ、Flash Playerの現在のバージョンは11.7.700.169であることがわかりました。

前回の更新から1か月以上が経過し、新しいものがWebサイトで明確に入手可能になりましたが、私のマシンで実行されている毎時チェックがそれに気づいたか、ダウンロードする意図があるかどうかはわかりません。

付録B：Flash Playerアップデーターを手動で実行する

むかしむかし、実行すると、インストールボタンのあるウィンドウが表示されます。それを押すと、現在のバージョンのインストーラーが（ブラウザーを開かずに自動的に）ダウンロードされて実行され、そのインストーラーをクリックして完了します。マニュアルでしたが、うまくいきました！現在のインストールが古くなっていることを確認し（付録Aを参照）、最初にこの手動更新プロセスを試しました。しかしながら...FlashUtil32_<version>_Plugin.exe -update plugin

• 実行中（私の場合は）... [ダウンロード]ボタンのあるウィンドウのみが表示されます。[ダウンロード]ボタンをクリックすると、ブラウザーでURL https://get3.adobe.com/flashplayer/update/activexが開きます。FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• 実行中（私の場合は）... [ダウンロード]ボタンのあるウィンドウのみが表示されます。[ダウンロード]ボタンをクリックすると、ブラウザーでURL https://get3.adobe.com/flashplayer/update/pluginが開きます。FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

私は可能性が foistwareボックス（「！無料マカフィーセキュリティスキャンプラス」）のチェックを外し、それが送ってくれたダウンロードページに進んで、ダウンロードすることをインストーラ（ActiveXの、無foistware：install_flashplayer11x32axau_mssd_aih.exe、プラグイン、ノーfoistware：install_flashplayer11x32au_mssd_aih.exe）＆おそらく更新されたFlashを持っています...しかし、別のexeを手動でダウンロードして実行する必要がある場合、Flash Player Update Serviceのポイントは何ですか？

エピローグ

それ以来、私は、更新サービスが意図的に手に入れられず、アーリーアダプターをマニュアルダウンロードページに誘導するのではないかと疑うようになりました。これが当てはまる場合、私自身のアップデーターを書くことのこの短い解決策はおそらくないでしょう。うまくいけば私は間違っています。

おそらく、アップデーターは11.6.xの範囲の更新のみを適用しますか？

インストーラーへの直接リンクをいつでも使用できますが、私はより信頼性が高いと思います：ActiveX ; プラグイン。

この.batファイルを使用すると、Internet Explorer、Firefox（SeaMonkeyなど）、Chromiumベース（Chrome、Opera 15以降など）のフラッシュプレーヤーが自動的に更新またはインストールされます。

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

必要なwgetはここからダウンロードでき、.batが置かれたのと同じディレクトリに置く必要があります。

Autoitで書かれたもう少し高度な例。

機能：新しいバージョンの簡単なチェック。ここに新しいバージョンがない場合は、Flash Playerインストーラーをダウンロードせずにプログラムを終了します。インストーラーのダウンロードが失敗した場合は、エラーのあるメッセージボックスを表示して終了します。非表示のコマンドプロンプトウィンドウ。wgetは必要ありません。

Autoit and Editorをインストールした後。デスクトップ->新規->スクリプトの自動化を右クリックします。この作成されたファイルを右クリックして、[編集]をクリックします。これで、ScITEウィンドウが表示され、「ここにコードを追加してください」行の後にこのコードが追加されます。

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

次に、SciTEウィンドウで[ツール]-> [ビルド]を押すか、F7を押します。これで、Autoitスクリプトと同じディレクトリにスタンドアロンの実行可能ファイルを取得できます。

この「アップデーター」に新しいフォルダー（書き込みアクセス許可付き）を作成することをお勧めします。この「アップデータ」にショートカットを追加して、起動することもできます。

ここでは、アンインストールフラッシュプレーヤーのためのアプリ。

ちょうど、バッチスクリプトを共有します。このコードをメモ帳に保存し、Download_Install_Last_Flash_Player.batという名前を付けます。

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************