Windowsにアップデートを強制的にチェックさせるにはどうすればよいですか？

Windowsの新規インストール（XPまたは7）後、Windowsの更新を「強制」するにはどうすればよいですか？

1週間後に「古い」Windows更新プログラムを取得したくないので、「1ステップ」で実行できますか？Windowsに更新プログラムのチェックを強制する「魔法の」コマンドはありますか。更新プログラムがある場合はインストールしますか？

スクリプトを使用して、更新を自動的に確認してインストールできます。これはXPまたはWindows 7で動作します。

ダウンロードできるスクリプトは多数ありますが、ここに私のスクリプトがあります。

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop 

これは、次のようにコマンドラインから実行します。

cscript wsusupdate.vbs

私のスクリプトは最小限の機能しかありませんが、それでも役に立つかもしれません。他にも多くの追加機能を備えたこのようなスクリプトがあります。Google検索をお試しください。

Windows Updateの通常の使用方法を超えて、コマンドラインからチェックを強制することができます。

管理者のコマンドプロンプトを開き、次を実行します。

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exeは、Windows UpdateのAutoUpdateクライアントであり、Microsoft Updateから（MS Windowsプラットフォームのさまざまなバージョンの）利用可能な更新を確認するために使用されます。

これはインストールを強制しません。

更新を確認するには、[コントロールパネル]、[セキュリティ]、[Windows Update]に移動し、[更新の確認]をクリックします。

更新の真の再スキャンを強制する別の方法は、％windir％\ Windows \ SoftwareDistribution \ Downloadに保存されているすべての更新を削除することにより、スレートを完全に消去することです。

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

次に、Windows Updateに移動し、「更新プログラムの確認」。システムボリューム上の更新可能なすべてのファイルがチェックされるため、1時間かかる場合があります（その後の「更新のチェック」は高速になります）。このアプローチにより、少なくともMSが認識している限り、エラーや不具合のある更新が排除され、クリーンで最新のシステムが得られます。

私は、新しいWindowsインストールを更新するためにwuinstallと呼ばれるセカンドパーティツールを使用しています。これにより、自動再起動を含む更新プロセス全体を自動化できます。これは、ユーザーの出席なしに最新のウィンドウを最新の状態にする最も速い方法の1つだと思います。

Windows 7での新規インストールの一環として、IEをアップグレードした場合、またはIEをまだ実行しておらず、最初の質問に答えた場合、Windows Updateでエラーが発生することがわかりました。また、GUIを使用せずにWindows UpdateをMicrosoft Updateに切り替える方法を見つけていないため、IEを手動で起動し、初期化してから、GUIを介してWindows Updateをセットアップするため、Microsoft Updateに切り替えて、初期エラー。あなたのマイレージは異なる場合があります。

IE8とWI4.5をインストールすることで、この投稿の手順に従って成功し、ダウンロードを開始する自動更新がトリガーされます。