キーボードショートカットで現在のフォルダーのコマンドプロンプトを開くにはどうすればよいですか？

Windows 7のキーボードショートカットで現在のフォルダーのコマンドプロンプトを開くにはどうすればよいですか？
これを実装する方法はありますか？
Autohotkeyはこれを行うことができると思いますが、方法はわかりません。

このキーボードショートカットを使用してください：Shift+ Menu、W、Enter

1. Shift+ Menu（または、Shift+ F10）、（現在のフォルダーで拡張右クリックメニューを開きます）

2. W （「ここでコマンドウィンドウを開く」を選択）、

3. Enter（選択を有効にします。「新規」もで選択できるため必要ですW）

Menuキーは通常、右の右に、マイクロソフトによって導入され、特殊なキーを参照するWinキー。

このショートカットは、サードパーティのソフトウェアがインストールされていないWindows（7）のデフォルトインストールで使用できます。

AHKの方法。Win+C（または定義したいもの）を押すだけです。

SetTitleMatchMode RegEx
return

; Stuff to do when Windows Explorer is open
;
#IfWinActive ahk_class ExploreWClass|CabinetWClass

    ; create new text file
    ;
    #t::Send !fwt

    ; open 'cmd' in the current directory
    ;
    #c::
        OpenCmdInCurrent()
    return
#IfWinActive


; Opens the command shell 'cmd' in the directory browsed in Explorer.
; Note: expecting to be run when the active window is Explorer.
;
OpenCmdInCurrent()
{
    ; This is required to get the full path of the file from the address bar
    WinGetText, full_path, A

    ; Split on newline (`n)
    StringSplit, word_array, full_path, `n

    ; Find and take the element from the array that contains address
    Loop, %word_array0%
    {
        IfInString, word_array%A_Index%, Address
        {
            full_path := word_array%A_Index%
            break
        }
    }  

    ; strip to bare address
    full_path := RegExReplace(full_path, "^Address: ", "")

    ; Just in case - remove all carriage returns (`r)
    StringReplace, full_path, full_path, `r, , all


    IfInString full_path, \
    {
        Run,  cmd /K cd /D "%full_path%"
    }
    else
    {
        Run, cmd /K cd /D "C:\ "
    }
}

ボーナスとして、また、上記のスクリプトは、このショートカットを使用して新しいテキストファイルを作成しますWin+T

クレジット：Eli Bendersky

プレスAlt+ D、タイプcmdキーを押しEnter。詳細についてはブログ投稿を参照してくださいここに。

windows7で同様のことを行うネイティブな方法は、shift「コマンドプロンプト」を実行するフォルダー上でマウスの右ボタンを押したままにすることです。コンテキストメニューに新しいメニュー項目が表示されます。 「。

純粋なキーボードアクションが必要な場合は、これを行う必要があります。

• 開いた regedit
• に移動しHKEY_CLASSES_ROOT\Directory\shell\cmd、Extendedキーの名前を変更しますExtended_save
• Extended_save`に移動しHKEY_CLASSES_ROOT\Drive\shell\cmdて名前を変更しますExtended key to

これにより、「ここでコマンドウィンドウを開く」エントリがコンテキストメニューに永続的に追加されます。次のキーを押すと、このエントリをトリガーできます。

• alt
• 離して、コンテキストメニューが開きます
• 「ここでコマンドウィンドウを開く」エントリの「アンダースコア」文字を押すか、カーソルキーを押して下に移動します enter

メニューエントリの名前は、OSの言語に応じてラベル付けされています。

代替ルートはこれを行うことです：

• エクスプローラーを介してコマンドプロンプトで目的のフォルダーを開きます
• f4
• ctrla
• ctrlc
• winr
• cmd /k cd ctrlventer

エクスプローラーのアドレスバーから現在のパスを取得して実行しcmd /k cd PATHます。オートホットキーを使用すると、同じことができますが、オートホットキーがわかりません。

どのようにツーオープンCMD-に電流フォルダ・バイ・ショートカットウィンドウ-10

Windows 8/10を使用している場合、より高速で独創的な方法があります。

Alt+ F、P

他のプログラムの助けを借りずに、3つのキーを2回入力するだけです。

最新のWindows 10アップデートの時点で、Leftiumの回答のShift+ Menu、Wメソッドは機能しなくなりました。ただし、わずかな変更により、さらにいくつかのキーストロークがありますが、回避策を提示できます。

問題は、コマンドプロンプトが拡張右クリックメニューで使用できなくなったことです。代わりに、Windows Powershellができました。

Shift+ Menu、SターゲットフォルダーでWindows Powershellを開きます。Windows Powershellで、入力してcmdから押すEnter.

これにより、Windows Powershell内のコマンドプロンプトにアクセスできます。

PS

Ashwin NanjappaのCtrl+ のメソッドはL、タイプしcmd、Enter作品を押す。ただし、Windowsエクスプローラーウィンドウに戻ってディレクトリ間の移動を続行する予定がない場合にのみエレガントです。残念ながら、この方法では、Windowsエクスプローラーのカーソルがメインウィンドウから離れTab、矢印キーを使用してフォルダー内を移動できる場所に戻るために多くのキーストロークが必要になります。これらのTabキーストロークを押しているときに視覚的な確認が限られているため、これはイライラする可能性があります。

Windows Powershellはほとんどの方法でコマンドプロンプトと同じように機能しますが、Windows Powershellが@javaタグを誤って（javadocsを生成していたとき）誤読し、目的の結果が得られない場合が少なくとも1つあります。cmdWindows PowershellでEnterと入力すると、代わりにコマンドプロンプトを使用して、このような問題を克服できます。

最も簡単な方法は、Windowsエクスプローラーのアドレスバーに移動してcmdと入力することです。コマンドプロンプトをその場所からすぐに開きます。

@Ashwin のメソッドを使用してコマンドプロンプトを開くAutoHotKeyスクリプト

使用してPowershellコンソールを開きます Win P

#P::
{
    Send !D
    Send powershell
    Send {Enter}    
    return
}

使用してコマンドプロンプトを開く Win C

#C::
{
    Send !D
    Send CMD
    Send {Enter}    
    return
}

選択した質問のスクリプトよりも単純なAHKスクリプト

#c::cmdHere()

cmdHere() {
    If WinActive("ahk_class CabinetWClass") || WinActive("ahk_class ExploreWClass") {
        WinHWND := WinActive()
        For win in ComObjCreate("Shell.Application").Windows
            If (win.HWND = WinHWND) {
                dir := SubStr(win.LocationURL, 9) ; remove "file:///"
                dir := RegExReplace(dir, "%20", " ")
                Break
            }
    }
    Run, cmd, % dir ? dir : A_Desktop
}

ここからソース：https : //autohotkey.com/boards/viewtopic.php?t=5796

ドイツ語版のWindowsバージョンを使用している場合、これを行うことができます。

プレスAlt+ D、E

Alt+ Dcmd以外のいくつかの項目を選択できるメニューを開きます

AHKの場合、以下が私の拘束力です。

#c::
Run, C:\Windows\system32\cmd.exe
return

これは現在のフォルダーを開きませんが、便利です。