私はgitをWindowsシステムのバックアップとして使用していますが、非常に便利です。投稿の最後に、Windowsシステムで構成するために使用するスクリプトを示します。gitをシステムのバックアップとして使用すると、2つの大きな利点があります。
- 多くの場合、独自の独自形式を使用する商用ソリューションとは異なり、バックアップは広くサポートされ、十分に文書化されたオープンソース形式です。これにより、データを完全に制御できます。どのファイルがいつ変更されたかを確認するのは非常に簡単です。履歴を切り捨てる場合は、同様に行うことができます。あなたの歴史から何かを消したいですか？問題ない。ファイルのバージョンを取得するのは、gitコマンドと同じくらい簡単です。
- 必要な数のミラーを必要なだけ、またはすべてのミラーで、バックアップ時間をカスタマイズできます。低速のインターネットトラフィックの影響を受けないローカルミラーを取得します。これにより、（1）1日を通してより頻繁なバックアップを実行でき、（2）迅速な復元時間を実現できます。（頻繁にバックアップするのは大きなプラスです。なぜなら、ドキュメントを失うのはユーザーエラーが最も多いからです。たとえば、子供が誤って過去5時間作業中のドキュメントを上書きしてしまうなどです。）リモートミラー。ローカルの災害または盗難の場合にデータ保護の利点を提供します。また、インターネット帯域幅を節約するために、カスタマイズした時間にリモートミラーをバックアップしたいとしますか？問題ない。
結論：gitバックアップを使用すると、バックアップの実行方法を非常に強力に制御できます。
Windowsシステムでこれを構成しました。最初のステップは、すべてのローカルデータをコミットするローカルgitリポジトリを作成することです。ローカルの2台目のハードドライブを使用することをお勧めしますが、同じハードドライブを使用しても問題はありません（ただし、これをリモートのどこかにプッシュするか、ハードドライブが故障した場合はネジ止めすることが予想されます）。
最初にcygwin（rsyncを使用）をインストールし、Windows用のgitもインストールする必要があります：http : //git-scm.com/download/win
次に、ローカルgitリポジトリを作成します（一度だけ実行します）：
init-repo.bat：
@echo off
REM SCRIPT PURPOSE: CREATE YOUR LOCAL GIT-REPO (RUN ONLY ONCE)
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM Create the backup git repo.
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
mkdir %GBKUP_LOCAL_MIRROR_HOME%
git %GIT_PARAMS% init
git %GIT_PARAMS% config core.autocrlf false
git %GIT_PARAMS% config core.ignorecase false
git %GIT_PARAMS% config core.fileMode false
git %GIT_PARAMS% config user.email backup@yourComputerName
git %GIT_PARAMS% config user.name backup
REM add a remote to the git repo. Make sure you have set myRemoteServer in ~/.ssh/config
REM The path on the remote server will vary. Our remote server is a Windows machine running cygwin+ssh.
REM For better security, you could install gitolite on the remote server, and forbid any non-fast-forward merges, and thus stop a malicious user from overwriting your backups.
git %GIT_PARAMS% remote add origin myRemoteServer:/cygdrive/c/backup/yourComputerName.git
REM treat all files as binary; so you don't have to worry about autocrlf changing your line endings
SET ATTRIBUTES_FILE=%GBKUP_LOCAL_MIRROR_HOME%\.git\info\attributes
echo.>> %ATTRIBUTES_FILE%
echo *.gbkuptest text>> %ATTRIBUTES_FILE%
echo * binary>> %ATTRIBUTES_FILE%
REM compression is often a waste of time with binary files
echo * -delta>> %ATTRIBUTES_FILE%
REM You may need to get rid of windows new lines. We use cygwin's tool
C:\cygwin64\bin\dos2unix %ATTRIBUTES_FILE%
次に、Windowsスケジューラによって定期的に呼び出されるバックアップスクリプトラッパーがあります。
gbackup.vbs：
' A simple vbs wrapper to run your bat file in the background
Set oShell = CreateObject ("Wscript.Shell")
Dim strArgs
strArgs = "cmd /c C:\opt\gbackup\gbackup.bat"
oShell.Run strArgs, 0, false
次に、ラッパーが呼び出すバックアップスクリプト自体があります。
gbackup.bat：
@echo off
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM the user which runs the scheduler
SET GBKUP_RUN_AS_USER=yourWindowsUserName
REM exclude file
SET GBKUP_EXCLUDE_FILE=/cygdrive/c/opt/gbackup/exclude-from.txt
SET GBKUP_TMP_GIT_DIR_NAME=git-renamed
for /f "delims=" %%i in ('C:\cygwin64\bin\cygpath %GBKUP_LOCAL_MIRROR_HOME%') do set GBKUP_LOCAL_MIRROR_CYGWIN=%%i
REM rename any .git directories as they were (see below command)
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (%GBKUP_TMP_GIT_DIR_NAME%) do ren "%%i" ".git" 2> nul
SET RSYNC_CMD_BASE=C:\cygwin64\bin\rsync -ahv --progress --delete --exclude-from %GBKUP_EXCLUDE_FILE%
REM rsync all needed directories to local mirror
%RSYNC_CMD_BASE% /cygdrive/c/dev %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/asmith %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/bsmith %GBKUP_LOCAL_MIRROR_CYGWIN%
cacls %GBKUP_LOCAL_MIRROR_HOME% /t /e /p %GBKUP_RUN_AS_USER%:f
REM rename any .git directories as git will ignore the entire directory, except the main one
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (.git) do ren "%%i" "%GBKUP_TMP_GIT_DIR_NAME%" 2> nul
ren %GBKUP_LOCAL_MIRROR_HOME%\%GBKUP_TMP_GIT_DIR_NAME% .git
REM finally commit to git
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
SET BKUP_LOG_FILE=%TMP%\git-backup.log
SET TO_LOG=1^>^> %BKUP_LOG_FILE% 2^>^&1
echo ===========================BACKUP START=========================== %TO_LOG%
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime% %TO_LOG%
echo updating git index, committing, and then pushing to remote %TO_LOG%
REM Caution: The --ignore-errors directive tells git to continue even if it can't access a file.
git %GIT_PARAMS% add -Av --ignore-errors %TO_LOG%
git %GIT_PARAMS% commit -m "backup" %TO_LOG%
git %GIT_PARAMS% push -vv --progress origin master %TO_LOG%
echo ===========================BACKUP END=========================== %TO_LOG%
exclude-from.txtファイルには、無視するすべてのファイルが含まれています。
exclude-from.txt：
target/
logs/
AppData/
Downloads/
trash/
temp/
.idea/
.m2/
.IntelliJIdea14/
OLD/
Searches/
Videos/
NTUSER.DAT*
ntuser.dat*
リモートリポジトリに移動して、それらに対して 'git init --bare'を実行する必要があります。バックアップスクリプトを実行して、スクリプトをテストできます。すべてが機能していると仮定して、Windowsスケジューラに移動し、1時間ごとのバックアップをvbsファイルに向けます。その後、1時間ごとにコンピューターのgit履歴があります。それは非常に便利です-誤ってテキストのセクションを誤って削除して見逃してしまいますか？gitリポジトリを確認してください。