だから…私はできる小さなVBScriptに取り組んできました。
- 永続的なVSSスナップショットを撮ります
- それらをフォルダにマウントします（そこからファイルをバックアップできます）
- VSSスナップショットのマウント解除
Microsoftから入手可能なVolume Shadow Copy Service SDK 7.2の一部vshadow.exe（documentation）に依存しています。私はこのバージョンで作業してきました： " VSHADOW.EXE 2.2-ボリュームシャドウコピーサンプルクライアント、Copyright（C）2005 Microsoft Corporation。 "
基本的には、これらの4つのvshadowコマンドに対するきちんとした小さなラッパーです。
vshadow.exe -q-システム内のすべてのシャドウコピーを一覧表示します
vshadow.exe -p {ボリュームリスト}-永続的なシャドウコピーを管理します
vshadow.exe -el = {SnapID}、dir-シャドウコピーをマウントポイントとして公開する
vshadow.exe -ds = {SnapID}-このシャドウコピーを削除します
ヘルプ画面は次のとおりです。
VSSスナップショット作成/マウントツール
使用法：
cscript / nologo VssSnapshot.vbs / target：path {/ volume：X | / unmount} [/ debug]
/ volume-スナップショットするボリュームのドライブ文字
/ target-スナップショットをマウントするパス（絶対または相対）
/ debug-デバッグ出力の切り替え
例：
cscript / nologo VssSnapshot.vbs / target：C：\ Backup \ DriveD / volume：D
cscript / nologo VssSnapshot.vbs / target：C：\ Backup \ DriveD / unmount
ヒント：新しいスナップショットを作成する前にアンマウントする必要はありません。
ここにいくつかのサンプル出力：
C：\ VssSnapshot> cscript / nologo VssSnapshot.vbs / target：MountPoints \ E / volume：E
05/03/2010 17:13:04 VSSマウントポイントの準備...
05/03/2010 17:13:04マウントポイントはC：\ VssSnapshot \ MountPoints \ Eに準備されています
05/03/2010 17:13:04ボリュームのVSSスナップショットの作成：E
05/03/2010 17:13:08 IDで作成されたスナップショット：{4ed3a907-c66f-4b20-bda0-9dcda3b667ec}
05/03/2010 17:13:08 VSSスナップショットが正常にマウントされました
05/03/2010 17:13:08終了
C：\ VssSnapshot> cscript / nologo VssSnapshot.vbs / target：MountPoints \ E / unmount
05/03/2010 17:13:35 VSSマウントポイントの準備...
05/03/2010 17:13:36他にやることはありません
05/03/2010 17:13:36終了
そして、ここにスクリプト自体があります。通常の免責事項が適用されます。ソフトウェアは現状のまま提供されます。責任を負わないのは自分自身である場合は、自己責任で使用してください。しかし、私はそれを非常に徹底的にテストしました。以下のコメントを使用して、バグをいつでもお知らせください。
''# VssSnapshot.vbs
''# http://serverfault.com/questions/119120/how-to-use-a-volume-shadow-copy-to-make-backups/119592#119592
Option Explicit
Dim fso: Set fso = CreateObject("Scripting.FileSystemObject")
''# -- MAIN SCRIPT -------------------------------------------
Dim args, snapshotId, targetPath, success
Set args = WScript.Arguments.Named
CheckEnvironment
Log "preparing VSS mount point..."
targetPath = PrepareVssMountPoint(args("target"))
If args.Exists("unmount") Then
Log "nothing else to do"
ElseIf targetPath <> vbEmpty Then
Log "mount point prepared at: " & targetPath
Log "creating VSS snapshot for volume: " & args("volume")
snapshotId = CreateVssSnapshot(args("volume"))
If snapshotId <> vbEmpty Then
Log "snapshot created with ID: " & snapshotId
success = MountVssSnapshot(snapshotId, targetPath)
If success Then
Log "VSS snapshot mounted sucessfully"
Else
Die "failed to mount snapshot"
End If
Else
Die "failed to create snapshot"
End If
Else
Die "failed to prepare mount point"
End If
Log "finished"
''# -- FUNCTIONS ---------------------------------------------
Function PrepareVssMountPoint(target) ''# As String
Dim cmd, result, outArray
Dim path, snapshot, snapshotId
Dim re, matches, match
PrepareVssMountPoint = VbEmpty
target = fso.GetAbsolutePathName(target)
If Not fso.FolderExists(fso.GetParentFolderName(target)) Then
Die "Invalid mount point: " & target
End If
''# create or unmount (=delete existing snapshot) mountpoint
If Not fso.FolderExists(target) Then
If Not args.Exists("unmount") Then fso.CreateFolder target
Else
Set re = New RegExp
re.MultiLine = False
re.Pattern = "- Exposed locally as: ([^\r\n]*)"
cmd = "vshadow -q"
result = RunCommand(cmd, false)
outarray = Split(result, "*")
For Each snapshot In outArray
snapshotId = ParseSnapshotId(snapshot)
If snapshotId <> vbEmpty Then
Set matches = re.Execute(snapshot)
If matches.Count = 1 Then
path = Trim(matches(0).SubMatches(0))
If fso.GetAbsolutePathName(path) = target Then
cmd = "vshadow -ds=" & snapshotId
RunCommand cmd, true
Exit For
End If
End If
End If
Next
If args.Exists("unmount") Then fso.DeleteFolder target
End If
PrepareVssMountPoint = target
End Function
Function CreateVssSnapshot(volume) ''# As String
Dim cmd, result
If Not fso.DriveExists(volume) Then
Die "Drive " & volume & " does not exist."
End If
cmd = "vshadow -p " & Replace(UCase(volume), ":", "") & ":"
result = RunCommand(cmd, false)
CreateVssSnapshot = ParseSnapshotId(result)
End Function
Function MountVssSnapshot(snapshotId, target) ''# As Boolean
Dim cmd, result
If fso.FolderExists(targetPath) Then
cmd = "vshadow -el=" & snapshotId & "," & targetPath
result = RunCommand(cmd, true)
Else
Die "Mountpoint does not exist: " & target
End If
MountVssSnapshot = (result = "0")
End Function
Function ParseSnapshotId(output) ''# As String
Dim re, matches, match
Set re = New RegExp
re.Pattern = "SNAPSHOT ID = (\{[^}]{36}\})"
Set matches = re.Execute(output)
If matches.Count = 1 Then
ParseSnapshotId = matches(0).SubMatches(0)
Else
ParseSnapshotId = vbEmpty
End If
End Function
Function RunCommand(cmd, exitCodeOnly) ''# As String
Dim shell, process, output
Dbg "Running: " & cmd
Set shell = CreateObject("WScript.Shell")
On Error Resume Next
Set process = Shell.Exec(cmd)
If Err.Number <> 0 Then
Die Hex(Err.Number) & " - " & Err.Description
End If
On Error GoTo 0
Do While process.Status = 0
WScript.Sleep 100
Loop
output = Process.StdOut.ReadAll
If process.ExitCode = 0 Then
Dbg "OK"
Dbg output
Else
Dbg "Failed with ERRORLEVEL " & process.ExitCode
Dbg output
If Not process.StdErr.AtEndOfStream Then
Dbg process.StdErr.ReadAll
End If
End If
If exitCodeOnly Then
Runcommand = process.ExitCode
Else
RunCommand = output
End If
End Function
Sub CheckEnvironment
Dim argsOk
If LCase(fso.GetFileName(WScript.FullName)) <> "cscript.exe" Then
Say "Please execute me on the command line via cscript.exe!"
Die ""
End If
argsOk = args.Exists("target")
argsOk = argsOk And (args.Exists("volume") Or args.Exists("unmount"))
If Not argsOk Then
Say "VSS Snapshot Create/Mount Tool" & vbNewLine & _
vbNewLine & _
"Usage: " & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:path { /volume:X | /unmount } [/debug]" & _
vbNewLine & vbNewLine & _
"/volume - drive letter of the volume to snapshot" & _
vbNewLine & _
"/target - the path (absolute or relative) to mount the snapshot to" & _
vbNewLine & _
"/debug - swich on debug output" & _
vbNewLine & vbNewLine & _
"Examples: " & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:C:\Backup\DriveD /volume:D" & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:C:\Backup\DriveD /unmount" & _
vbNewLine & vbNewLine & _
"Hint: No need to unmount before taking a new snapshot." & vbNewLine
Die ""
End If
End Sub
Sub Say(message)
If message <> "" Then WScript.Echo message
End Sub
Sub Log(message)
Say FormatDateTime(Now()) & " " & message
End Sub
Sub Dbg(message)
If args.Exists("debug") Then
Say String(75, "-")
Say "DEBUG: " & message
End If
End Sub
Sub Die(message)
If message <> "" Then Say "FATAL ERROR: " & message
WScript.Quit 1
End Sub
これが誰かの助けになることを願っています。cc-by-saに従って自由に使用してください。ここでポイントしているリンクはそのままにしておいてください。