選択した回答は機能しますが、多少の改善が必要になる可能性があります。
- オプションはおそらくデフォルト値に初期化する必要があります。
- ％0と、必要な引数％1および％2を保持しておくと便利です。
- 特にオプションの数が増えるにつれて、すべてのオプションにIFブロックを設定するのは面倒になります。
- すべてのオプションとデフォルトを1か所ですばやく定義するためのシンプルで簡潔な方法があると便利です。
- フラグとして機能するスタンドアロンオプションをサポートするとよいでしょう（オプションの後に値はありません）。
- 引数が引用符で囲まれているかどうかはわかりません。また、引数値がエスケープ文字を使用して渡されたかどうかもわかりません。％〜1を使用して引数にアクセスし、割り当てを引用符で囲むことをお勧めします。その場合、バッチは引用符で囲まれていないことに依存できますが、特殊文字はエスケープせずに一般的に安全です。（これは防弾ではありませんが、ほとんどの状況を処理します）
私のソリューションは、すべてのオプションとそのデフォルトを定義するOPTIONS変数の作成に依存しています。OPTIONSは、指定されたオプションが有効かどうかをテストするためにも使用されます。オプションと同じ名前の変数にオプション値を格納するだけで、膨大な量のコードが節約されます。コードの量は、定義されているオプションの数に関係なく一定です。OPTIONS定義のみを変更する必要があります。
編集 -また、必須の位置引数の数が変更された場合は、：loopコードを変更する必要があります。たとえば、多くの場合、すべての引数に名前が付けられます。この場合、3ではなく位置1から始まる引数を解析する必要があります。したがって、：loop内では、3つすべてが1になり、4つが2になります。
@echo off
setlocal enableDelayedExpansion
:: Define the option names along with default values, using a <space>
:: delimiter between options. I'm using some generic option names, but
:: normally each option would have a meaningful name.
::
:: Each option has the format -name:[default]
::
:: The option names are NOT case sensitive.
::
:: Options that have a default value expect the subsequent command line
:: argument to contain the value. If the option is not provided then the
:: option is set to the default. If the default contains spaces, contains
:: special characters, or starts with a colon, then it should be enclosed
:: within double quotes. The default can be undefined by specifying the
:: default as empty quotes "".
:: NOTE - defaults cannot contain * or ? with this solution.
::
:: Options that are specified without any default value are simply flags
:: that are either defined or undefined. All flags start out undefined by
:: default and become defined if the option is supplied.
::
:: The order of the definitions is not important.
::
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
:: Set the default option values
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
:: Validate and store the options, one at a time, using a loop.
:: Options start at arg 3 in this example. Each SHIFT is done starting at
:: the first option so required args are preserved.
::
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
rem No substitution was made so this is an invalid option.
rem Error handling goes here.
rem I will simply echo an error message.
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
rem Set the flag option using the option name.
rem The value doesn't matter, it just needs to be defined.
set "%~3=1"
) else (
rem Set the option value using the option as the name.
rem and the next arg as the value
set "%~3=%~4"
shift /3
)
shift /3
goto :loop
)
:: Now all supplied options are stored in variables whose names are the
:: option names. Missing options have the default value, or are undefined if
:: there is no default.
:: The required args are still available in %1 and %2 (and %0 is also preserved)
:: For this example I will simply echo all the option values,
:: assuming any variable starting with - is an option.
::
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
本当にそれほど多くのコードはありません。上記のコードのほとんどはコメントです。これは、コメントなしのまったく同じコードです。
@echo off
setlocal enableDelayedExpansion
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
set "%~3=1"
) else (
set "%~3=%~4"
shift /3
)
shift /3
goto :loop
)
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
このソリューションは、Windowsバッチ内でUnixスタイルの引数を提供します。これはWindowsの標準ではありません。バッチには通常、必要な引数の前にオプションがあり、オプションの前には/。が付いています。
このソリューションで使用される手法は、Windowsスタイルのオプションに簡単に適合させることができます。
- 解析ループは常にでオプションを探し、
%1引数1がで始まらないまで続きます/
- 名前が。で始まる場合は、SET割り当てを引用符で囲む必要があることに注意してください
/。
SET /VAR=VALUE失敗し
SET "/VAR=VALUE"ます。とにかく、私はすでに私のソリューションでこれを行っています。
- 標準のWindowsスタイルでは、最初に必要な引数値が
/。で始まる可能性がありません。この制限は//、オプション解析ループを終了するためのシグナルとして機能する暗黙的に定義されたオプションを使用することで解消できます。//「オプション」には何も保存されません。
更新2015-12-28：!オプション値のサポート
上記のコードでは、遅延展開が有効になっているときに各引数が展開されます。これは、!おそらく削除されるか、またはそのようなもの!var!が展開されることを意味します。さらに、存在する^場合!は剥がすこともできます。コメントされていないコードに対する次の小さな変更により、!と^がオプション値に保持されるなどの制限がなくなります。
@echo off
setlocal enableDelayedExpansion
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
set "%~3=1"
) else (
setlocal disableDelayedExpansion
set "val=%~4"
call :escapeVal
setlocal enableDelayedExpansion
for /f delims^=^ eol^= %%A in ("!val!") do endlocal&endlocal&set "%~3=%%A" !
shift /3
)
shift /3
goto :loop
)
goto :endArgs
:escapeVal
set "val=%val:^=^^%"
set "val=%val:!=^!%"
exit /b
:endArgs
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
