これが私が最終的に使用したプロセスです。私が使用した主なツールは、テキストを問題なく変換できるInkscapeでした。
- JavaScriptでAdobe Acrobat Proアクションを使用してPDFシートを分割
- Windows CmdからInkscape Portable 0.48.5を実行してSVGに変換しました
- Windows CmdとWindows PowerShellを使用して問題が発生していた特定のSVG XML属性を手動で編集した
別のページ：JavaScriptを使用したAdobe Acrobat Pro
Adobe Acrobat Proアクション（以前のバッチ処理）を使用して、PDFページを個別のファイルに分割するカスタムアクションを作成します。または、GhostScriptを使用してPDFを分割できる場合があります。
ページを分割するAcrobat JavaScriptアクション
/* Extract Pages to Folder */
var re = /.*\/|\.pdf$/ig;
var filename = this.path.replace(re,"");
{
for ( var i = 0; i < this.numPages; i++ )
this.extractPages
({
nStart: i,
nEnd: i,
cPath : filename + "_s" + ("000000" + (i+1)).slice (-3) + ".pdf"
});
};
PDFからSVGへの変換：Windows CMDバッチファイルを使用したInkscape
Windows Cmdで作成されたバッチファイルを使用して、フォルダー内のすべてのPDFファイルをループし、SVGに変換する
現在のフォルダーでPDFをSVGに変換するバッチファイル
:: ===== SETUP =====
@echo off
CLS
echo Starting SVG conversion...
echo.
:: setup working directory (if different)
REM set "_work_dir=%~dp0"
set "_work_dir=%CD%"
:: setup counter
set "count=1"
:: setup file search and save string
set "_work_x1=pdf"
set "_work_x2=svg"
set "_work_file_str=*.%_work_x1%"
:: setup inkscape commands
set "_inkscape_path=D:\InkscapePortable\App\Inkscape\"
set "_inkscape_cmd=%_inkscape_path%inkscape.exe"
:: ===== FIND FILES IN WORKING DIRECTORY =====
:: Output from DIR last element is single carriage return character.
:: Carriage return characters are directly removed after percent expansion,
:: but not with delayed expansion.
pushd "%_work_dir%"
FOR /f "tokens=*" %%A IN ('DIR /A:-D /O:N /B %_work_file_str%') DO (
CALL :subroutine "%%A"
)
popd
:: ===== CONVERT PDF TO SVG WITH INKSCAPE =====
:subroutine
echo.
IF NOT [%1]==[] (
echo %count%:%1
set /A count+=1
start "" /D "%_work_dir%" /W "%_inkscape_cmd%" --without-gui --file="%~n1.%_work_x1%" --export-dpi=300 --export-plain-svg="%~n1.%_work_x2%"
) ELSE (
echo End of output
)
echo.
GOTO :eof
:: ===== INKSCAPE REFERENCE =====
:: print inkscape help
REM "%_inkscape_cmd%" --help > "%~dp0\inkscape_help.txt"
REM "%_inkscape_cmd%" --verb-list > "%~dp0\inkscape_verb_list.txt"
クリーンアップ属性：Windows CmdおよびPowerShell
バリエーションの可能性があるため、手動でSVGタグまたはXMLタグまたは属性をブルートフォース編集することはベストプラクティスではなく、代わりにXMLパーサーを使用する必要があることを理解しています。ただし、1つの図面のストローク幅が非常に小さく、別のフォントファミリーが誤って識別されるという単純な問題があったため、基本的に以前のWindows Cmdバッチスクリプトを変更して、単純な検索と置換を行いました。唯一の変更は、検索文字列の定義とPowerShellコマンドを呼び出すように変更されたことです。PowerShellコマンドは、検索を実行し、変更されたファイルを追加されたサフィックスで置き換えて保存します。他のマイナーなクリーンアップを実行する必要がある場合、結果のSVGファイルを解析または変更するために使用できる他の参照をいくつか見つけました。
SVG XMLデータを手動で検索および置換するための変更
:: setup file search and save string
set "_work_x1=svg"
set "_work_x2=svg"
set "_work_s2=_mod"
set "_work_file_str=*.%_work_x1%"
powershell -Command "(Get-Content '%~n1.%_work_x1%') | ForEach-Object {$_ -replace 'stroke-width:0.06', 'stroke-width:1'} | ForEach-Object {$_ -replace 'font-family:Times Roman','font-family:Times New Roman'} | Set-Content '%~n1%_work_s2%.%_work_x2%'"
これが誰かを助けることを願っています
参考文献
Adobe Acrobat Proアクションおよび別のページへのJavaScript参照
別のページへのGhostScript参照
PDFからSVGへの変換のためのInkscapeコマンドラインリファレンス
Windows Cmdバッチファイルスクリプトのリファレンス
XMLタグ/属性置換研究