「o」を使用してdired / ibufferから別のフレームに開く方法

2つのウィンドウを開いて縦に分割しています（単一フレーム）。

A）自分の作品を含む
B）diredまたはibufferを含む

ペインBでファイル/バッファに移動し、ペインAでファイルを開いて「o」を押すことができるようにしたいのですが、これは可能ですか？現在、emacsはペインAの下部にファイルを開くための新しいペインを作成しています。

編集：ユーザーの法律家によれば、上記の動作はフレームが大きい場合に発生します。これは私には当てはまるように見えます。なぜなら、私は（外付けモニターではなく、より小さなフレームで）家にいるので、emacsが思い通りに動作しているからです。現在の質問は、現在のフレームが大きいときにemacsが新しいウィンドウを開かないようにすることはできますか？

ここでは4つ（4）サンプルのカスタムdisplay-bufferカスタムユーザーの特定のニーズに合うように調整することができる機能のファミリ- の上。以下 ; 左 ; 右 - バッファのinteractive現在の行のファイルまたはディレクトリを表示する4つの関数がありますdired-mode。条件は3つしかありません。 （a）ターゲットバッファを表示するウィンドウがすでにある場合は、それを選択します。（b）利用可能な望ましい方向にウィンドウがある場合は、それを使用します。（c）キャッチオールは、他の条件が満たされない場合に、目的の方向に新しいウィンドウを作成することです。

使用法：

M-x dired-display-above

M-x dired-display-below

M-x dired-display-left

M-x dired-display-right

そこ非常に多くのキーバインディングは、すでにビルトインへdired-modeとdired+、私は自分を作るしようとしないあえてこと。ユーザーは自分のキーボードショートカットを自由に選択できますが、これはこの限定的な例の範囲を超えています。

ユーザーはdisplay-buffer、関数のサンプルファミリーに条件を追加して、より多くの状況を処理することができます。

(defun my-display-buffer-below (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'below))
          (t
            (split-window (selected-window) nil 'below)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun my-display-buffer-above (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'above))
          (t
            (split-window (selected-window) nil 'above)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun my-display-buffer-left (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'left))
          (t
            (split-window (selected-window) nil 'left)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun my-display-buffer-right (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'right))
          (t
            (split-window (selected-window) nil 'right)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun dired-display-above ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-above buffer nil)))

(defun dired-display-below ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-below buffer nil)))

(defun dired-display-left ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-left buffer nil)))

(defun dired-display-right ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-right buffer nil)))

編集：上記のコンセプトの少し洗練された/楽しい実装を以下に示します。これにより、ユーザーはこれを非インタラクティブまたはインタラクティブに使用できます。例M-x dired-display-buffer--ユーザーがでファイルにdired-modeカーソルを合わせていない場合はディレクトリを選択し、表示方向（左、右、上、下）を選択するように求められます。

(defun my-display-buffer (buffer-or-name alist direction &optional size pixelwise)
"BUFFER:  The buffer that will be displayed.
ALIST:  See the doc-string of `display-buffer' for more information.
DIRECTION:  Must use one of these symbols:  'left 'right 'below 'above
SIZE:  See the doc-string for `split-window'.
PIXELWISE:  See the doc-string for `split-window'.
There are three possibilities:
-  (1) If a window on the frame already displays the target buffer,
then just reuse the same window.
-  (2) If there is already a window in the specified direction in relation
to the selected window, then display the target buffer in said window.
-  (3) If there is no window in the specified direction, then create one
in that direction and display the target buffer in said window."
  (let* ((buffer
           (if (bufferp buffer-or-name)
             buffer-or-name
             (get-buffer buffer-or-name)))
         (window
           (cond
             ((get-buffer-window buffer (selected-frame)))
             ((window-in-direction direction))
             (t
               (split-window (selected-window) size direction pixelwise)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun dired-display-buffer (&optional direction alist)
"Display a dired-mode buffer or a file underneath point in a dired-mode buffer."
(interactive)
  (let* ((file-or-dir (or (and (eq major-mode 'dired-mode) (dired-get-file-for-visit))
                               (read-directory-name "Directory:  ")))
         (buffer (find-file-noselect file-or-dir))
         (direction
           (if direction
             direction
             (let ((char (read-char-exclusive (concat
                      "["
                      (propertize "l" 'face '(:foreground "red"))
                      "]"
                      (propertize "eft" 'face '(:foreground "blue"))
                      " | ["
                      (propertize "r" 'face '(:foreground "red"))
                      "]"
                      (propertize "ight" 'face '(:foreground "blue"))
                      " | ["
                      (propertize "a" 'face '(:foreground "red"))
                      "]"
                      (propertize "bove" 'face '(:foreground "blue"))
                      " | ["
                      (propertize "b" 'face '(:foreground "red"))
                      "]"
                      (propertize "elow" 'face '(:foreground "blue"))))))
                (cond
                  ((eq char ?l)
                    'left)
                  ((eq char ?r)
                    'right)
                  ((eq char ?a)
                    'above)
                  ((eq char ?b)
                    'below)
                  ;;; FIXME:  @lawlist may add a loop similar to `org-capture'
                  ;;; whereby a new `read-char-exclusive' will be initiated if
                  ;;; a user did not initially choose a valid option (l/r/a/b).
                  (t
                    (let ((debug-on-quit nil)
                          (msg (concat "dired-display-buffer:  "
                                       "You did not select l/r/a/b "
                                       "-- exiting.")))
                      (signal 'quit `(,msg)))))))))
    (my-display-buffer buffer alist direction)))

あなたの質問は不明確なので、閉じられるリスクがあります。2つのフレームまたは2つのEmacsウィンドウを持つ単一のフレームがありますか？それらが何であれ、2つある場合、それぞれは垂直に分割されますか？「垂直分割」とはどういう意味ですか？「ペイン」とはどういう意味ですか？「ペインAで開いていますか」の「それ」はどういう意味ですか？

大まかな推測では、2つのEmacsウィンドウAとBに分割された単一のEmacsフレームがあり、ウィンドウAがウィンドウBの上にあり、ウィンドウBが選択されており、ウィンドウBがDiredバッファーを表示しています。

oデフォルトではにバインドされていますdired-find-file-other-window。上記のワイルドな推測が正しい場合、oBのファイル名はAで開くはずです。これは、initファイルなしでEmacsを起動したときに表示されるものですemacs -Q。見えませんか？

これがシナリオではない場合は、から始めて、ステップバイステップで何をしているのかを明確に説明してくださいemacs -Q。

注：次の変数はグローバルです。つまり、これらの変数は他の関数に影響を与えますdired-find-file-other-window。ユーザーは、他の機能にグローバルに影響を及ぼさないように、問題の機能に助言したい場合があります。[ただし、この作成者はそのオプションを別のフォーラム参加者に任せます。]または、この作成者が投稿した別の回答で、他に影響を与えないように使用できるカスタム関数が含まれています。

変数にsplit-width-thresholdは、次のようなdoc-stringがあります。

Minimum width for splitting windows sensibly.
If this is an integer, ‘split-window-sensibly’ may split a window
horizontally only if it has at least this many columns.  If this
is nil, ‘split-window-sensibly’ is not allowed to split a window
horizontally.

.emacsファイルに以下を設定すると、目的の効果が得られます。ユーザーは、値をより大きな値に設定することもできます。デフォルト値は160です。

(setq split-width-threshold nil)

マニュアルの関連セクションへのリンクは次のとおりです。

https://www.gnu.org/software/emacs/manual/html_node/emacs/Window-Choice.html

関連する変数も参照してください。split-height-thresholdデフォルト値は80です。

doc-stringは次のように述べています。

Minimum height for splitting windows sensibly.
If this is an integer, `split-window-sensibly' may split a window
vertically only if it has at least this many lines.  If this is
nil, `split-window-sensibly' is not allowed to split a window
vertically.  If, however, a window is the only window on its
frame, `split-window-sensibly' may split it vertically
disregarding the value of this variable.