隣接するセルの値に基づいて、Googleスプレッドシートのセルの値を変更しようとしています。この隣接セルは、この Quoraの回答の式を使用して、隣接セルの色から値を取得します。したがって、セルの値は、最初のセルの色から取得される16進コードに基づいて変更する必要があります。現時点では4つの16進数値があるため、同じセルに4つの異なるIFステートメントを配置しようとしていたので、その値はこれに基づいて変更されます。

私の最初の試みは、式の解析エラーにつながりました：

=if((J2="#00ff00","Read"), if(j2="#ff0000", "Unread"), if(j2="#ff9900","In Progress"), if(j2="#000000", "Not Applicable"))

単純にifステートメントをカンマで区切ることはできないことは明らかです。このスタックオーバーフローの質問に基づいて、ネストされたIFステートメントでこのコードを試しました。

=if((J2="#00ff00","Read", if(j2="#ff0000", "Unread", if(j2="#ff9900","In Progress",if(j2="#000000", "Not Applicable")))))

これは、式の解析エラーにもつながります。

私のコードで機能する複数のIFステートメントを同じセルに単純に含める方法はありますか？

のlookup代わりに使用if：

=lookup(B7,
       {"#000000","#00ff00","#ff0000","#ff9900"},
       {"Not applicable", "Read","Unread","In Progress"}
  ) 

2番目のパラメーターはソートされたリストでなければならないことに注意してください。

短い答え

提供されている例の問題は括弧です。それらを適切に適用してください。

説明

IF() 関数には2つのパラメーターと、オプションで3番目のパラメーターが必要です。

IF(logical_expression, value_if_true, value_if_false)

特定の問題

• 提供されている最初の例は、外部のIF()パラメーターが多すぎることです。
• 第二の例は、ということであるlogical_expression外側のはIF()戻りませんTRUEかFALSE

Googleスプレッドシートでは、関数のパラメーターはカンマ（またはスプレッドシートで小数点記号としてコンマを使用する場合はセミコロン）で区切られます。括弧を使用して関数内のいくつかの操作と関数を囲む場合、それらを含む関数のパラメーターと見なされます。

一般的な方法は、インナーをIF()として置くvalue_if_falseことですが、多くの方法で行うことができます。追加IF()として、他の他の内側value_if_trueとvalue_if_false呼ばれているIF() logical test nestingかだけIF() nesting。

以下は3つを持っている公式の例です、IF()それらの2つはvalue_if_false親の決定に使用されましたIF()。読みやすくするために、括弧スタイルの複数行および垂直方向の配置が適用されます

 =IF(logical_expression, value_if_true, 
     IF(logical_expression, value_if_true, 
        IF(logical_expression, value_if_true, value_if_false
          )
       )
    )

上記のスタイルは、Googleスプレッドシートの数式作成で使用できます。数式のデバッグに役立ちました。

参照

• IF-Googleドキュメントエディターヘルプ

ifとorを組み合わせる方法を見つけました。

例：

=IF(OR(B3>49,C3>49,D3>49),”Passed”,”Failed”)
=IF(AND(B3>49,C3>49,D3>49),”Passed”,”Failed”)
=IF(OR(AND(B3>49,C3>49),AND(B3>49,D3>49),AND(C3>49,D3>49)),”Won”,”Failed”)

あなたの例では：

= if(OR(J2="#00ff00",j2="#ff0000",j2="#ff9900"),"True","False")

出典：Google Doc SpreadsheetでのIF、AND、OR論理関数の併用。

たとえば、IFステートメントをネストできます

If(if(if(when all 3 equal true)))

うまくいく

または

たとえば、ネストされたIFANDを使用できます

IF(AND(AND()))

また動作します。

あなたは理論とより良いアプローチを提供されましたが、具体的に答えるために：

私のコードで機能する複数のIFステートメントを同じセルに単純に含める方法はありますか？

してみてください：

=if(J2="#00ff00","Read", if(J2="#ff0000", "Unread", if(J2="#ff9900","In Progress",if(J2="#000000", "Not Applicable"))))

つまり、最初の開き括弧と最後の閉じ括弧がない2回目の試行です。