日付をチェックするGoogleスプレッドシートでクエリを作成する方法

からの範囲がありますB4:H124。列Bのすべてのセルは日付です。行（B:H）からデータを取得したいのですが、DATEは特定のセルの内容と同じです。Q4としましょう。

適切なクエリを作成するにはどうすればよいですか？

これまでのところ、私がこれで思いついたこと：

=QUERY(B2:G124; "select * where B = date '2012-02-28'")

Bのセルの形式がDD / MM / YYYYであっても機能します。

どのように私は変更することができます2012-02-28に$Q4？試行すると、次のエラーが発生します。

=QUERY(B2:G124; "select * where B = date '"&Q4&"'")

Invalid query: Invalid date literal [10/02/2012]. Date literals should be of form yyyy-MM-dd.

セルを見ると形式はですがyyyy-mm-dd、ダブルクリックすると形式がに変わりますDD-MM-YYYY。

私は何をすべきか？

また、列Bを含めずに、クエリの値をどのように合計できますか？

私はまだ仕事に実際の日付セルのためのトリックを見つけることができませんでしたが、何もない場合は、単一引用符（追加することによって、周りの仕事を持っている可能性が'形式で日付の前）を：YYYY-MM-DDでQ4セル。

その単一引用符は、それが文字列として解析されることを意味します。

次のように日付をフォーマットできます。

=QUERY(B2:G124; "select * where B = date '" & text(Q4,"yyyy-MM-dd") & "'")

列Cの値を合計するには、次のようにします。

=QUERY(B2:G124; "select sum(C) where B = date '" & text(Q4,"yyyy-MM-dd") & "'")

ただし、複数の列を合計する方法がわからない-まだこれはかなり新しいです

これはうまくいくはずです：

=QUERY(B2:G124; "select * where B = date '"&text(Q4;"yyyy-MM-dd")&"'")

とにかく、私は同じ問題を抱えていて、最終的にそれは私のために働いた。

事はあなたがメッセージに混乱することです

Invalid query: Invalid date literal [10/02/2012]. Date literals should be of form yyyy-MM-dd.

これは、Q4セルの日付形式がdd / MM / yyyyのように見えるためです。私は同じことを持っています。これがdd / MM / yyyyのように見えても、上記の私の返信の2行目に示されているように入力する必要があります。

Q3次の形式のように、希望する日付を新しいセルに入力します。2/28/2012

次に、Q4セルタイプで=YEAR(Q3) & "-" & DEC2OCT(MONTH(Q3), 2) & "-" & DAY(Q3)

これにより、Q3セルから日付が取得され、Q4セル内の文字列に変換されます。

これは、現在の日付が必要な場合により役立ちます。から日付を取得する代わりに、次のようにして今日の日付を取得Q3できますnow()。=YEAR(now()) & "-" & DEC2OCT(MONTH(now()), 2) & "-" & DAY(now())

最終は次のようになります。

=QUERY(B2:G124; "select * where B = date ' "  & text( Q4 ,"yyyy-MM-dd") & "'")

Q4は、日付を入力できる通常の日付形式のセルです。

上記をメモ帳にコピーし、フォントサイズを大きくします。

ここで'ダブルの中のシングルを見るのは難しい"です。

文字列の外で日付を計算し、をドロップすることもできます。dateたとえば、

=QUERY(B2:G124; "select * where B = '" & Q4)

Q4は効果的に整数として渡されます。これは、QUERYが日付を裏側に変換するものです。

GoogleのQUERY関数を使用する：

sum 複数の列、それは含めることが重要だlabelクエリの最後にパラメータを

=QUERY(B2:G124; "select sum(C) + sum(D) + sum(E) + sum(F) + sum(G) label sum(C) + sum(D) + sum(E) + sum(F) + sum(G) '' ") 

注：列参照では大文字と小文字が区別され、クエリの最後に2つの単一引用符が必要です。

whereセルの日付値を参照する句を追加するには：s6mikesソリューションから

=QUERY(B2:G124; "select * where B = date '" & text(Q4,"yyyy-MM-dd") & "') 

2つのクエリを組み合わせた ...

=QUERY(B2:G124; "select sum(C) + sum(D) + sum(E) + sum(F) + sum(G) where B = date '" & text(Q4,"yyyy-MM-dd") & "' label sum(C) + sum(D) + sum(E) + sum(F) + sum(G) '' ")

参照セルのデータの種類をテキストに変更する必要があります。そして、それはスムーズに動作します。