行をまたがって隠す方法はありますか？

これが私のユースケースです：

私はたくさんのコードを持っていますが、スタイルの強制により、それぞれの開き括弧と閉じ括弧の前後に改行を書きます。

例：

function func(args) {

    statement 1;
    statement 2;

    if (condition) {

        statement 3; 

    }

}

これは素晴らしくて読みやすいですが、これはスペースの無駄な無駄だと思いますが、私のチームメイトは私に同意しません。基本的に、これはコードをチェックインする方法であり、それがそれです。

Vimの機能を使用して画面の不動産を節約しながら、詳細な方法でコードを書くことができるのではないかと考えていました。私はそれをタイプアウトすることを気にしません、ただスペースをより効率的に使用したいだけです。たぶん、Vimに不要な空行を自動で折りたたむことができると考えました。

構文規則を使用してこれを設定するのは少し難しいことに気づきます。何を書いても既存の構文規則と競合するように思えるためですが、最初の試みとして、衝突しないこれらの規則を書くことを決めました。

syntax match aaaaaaaaa "\vabcd" conceal cchar=A
syntax match bbbbbbbbb "\vef\ngh" conceal cchar=B

ここでの2番目のルールは、私が望むものに近いもので、開き角括弧の場合は次のようなものです/\v\{(\n\s*){2,}：開き角括弧に改行の2以上の任意の数を指定し、その後に空白のみを付けます。

ただし、vimの内部では次のことが起こります。

1. abcd行を入力すると、A期待どおりに非表示になります。

2. ef1つの行とgh次の行に入力すると、両方の行がで非表示になりBます。

ef\nghこの方法で垂直バッファスペースを節約できるように、2行が1行に隠されることを本当に望んでいました。

しかし、私は今、それがおそらくVimの実装の詳細な問題であることを理解しています。行の折りたたみは、コードの折りたたみが解決する問題であり、おそらく隠蔽に関する限り、範囲外です。

だから、やりたいことをやる方法がまだあるのかな。多分どういうわけか折りマーカーを使用していますか？問題は、空の空白だけを折りたたむ必要があることです。

折り目を悪用して余分な空行を隠すことができます。以下にその方法を示します。

function! SkipNewlineFoldExpr()
    let l:curline = getline(v:lnum)
    " fold begins at {$ or one line before }$
    if l:curline[-1:] == '{' || getline(v:lnum + 1)[-1:] == '}'
        return '>1'
    endif
    " fold ends one line after {$ or at }$
    if getline(v:lnum - 1)[-1:] == '{' || l:curline[-1:] == '}'
        return '<1'
    endif
    return 0
endfunction

function! SkipNewlineFoldText()
    " fold text matches non-empty line
    return getline(getline(v:foldstart)[-1:] == '{' ? v:foldstart : v:foldend)
endfunction

" customize how fold is defined
set foldexpr=SkipNewlineFoldExpr()
" customize how fold looks like
set foldtext=SkipNewlineFoldText()
" use 'foldexpr'
set foldmethod=expr

" Optional:
" drop highlighting of folds
" highlight clear Folded
" automatically close folds
" set foldclose=all
" automatically open folds on any actions on folded lines
" set foldopen=all

次のようになります。

ご覧のとおり、折りたたまれた行には構文の強調表示がありませんが、多くの不要な空行よりも耐えられます。またzi、邪魔になっている場合に備えて、ショートカットを使用して折り目をオン/オフに切り替えることもできます。

フォールドは小さなトピックではなく、Vimには個別のヘルプファイルがあります。関連オプションもそこでリンクされています。

カーソルと検索の詳細な動作は'foldopen'、を介して制御できます。これ'foldclose'は、折り目が自動的に開閉されるときの定義と組み合わせて使用します。

まず、それはくだらないスタイルの施行であり、あなたは私の同情を持っています。代わりに隠れて（下に示すように）編集して完了したら、それらを追加する前に、不要な行を削除するためのマッピングまたは関数を作成する方法についてどのように？線に沿って何か：

function! Clean()
    %s/{\n^$/{/
    %s/^$\n\(\s*}\)/\1/
endfunction

function! Pollute()
    %s/{$/{\r/
    %s/\(\s*}\)/\r\1/
endfunction

基本的なアイデアは始まります。読み取り時に空の行を削除し、書き込み時にそれらを置き換えます。試さなかったのですが、次のようにautocmdとして追加できるように感じます。

au BufReadPost *.cpp call Clean()
au BufWritePost *.cpp call Pollute()