ここからXバイト移動

現在のカーソル位置（改行を含む）からXバイト先に移動するにはどうすればよいですか？

[count]goバッファの先頭からXバイト先に移動するために使用できます。私は試してみましたShift + V, G, [count]go（それ[count]goが私の選択の最初からカウントを開始すると仮定しました）が、残念ながらgo、バッファの最初からカウントを開始するだけなので、それも機能しませんでした。

また:set rulerformat=%o、現在のバイトオフセットを表示しようとしました（バイトオフセットにジャンプしてバイトオフセットとして位置を表示することで提案されています）[count]go。頭に数字を追加して、最後にを発行しました。これは機能しますが、あまり実用的ではありません...

この検索動く40 文字（バイトではない、けれども）前進：

/\_.\{40}/e

\{40}改行（\_.）を含むあらゆる種類の40文字（）を検索し、検索の最後にカーソルを置きます（/e）。参照：http : //vimregex.com/#Non-Greedy、:help search-offsetおよび:help \_

また、:h 23.4バイナリ編集についても参照してください。

更新：この回答に基づいて、バイトオフセットにジャンプする関数を次に示します。

let s:last_jump_bytes = 0

function! JumpTo(byte_nr)
    let crt_byte = line2byte(line('.')) + col('.')
    if (a:byte_nr == 0)
        let dst_byte = crt_byte + s:last_jump_bytes
    else
        let dst_byte = crt_byte + a:byte_nr
        let s:last_jump_bytes = a:byte_nr
    endif
    let dst_line = byte2line(dst_byte)
    let dst_col = dst_byte -line2byte(dst_line)
    "remove next line if you don't want to record this for `Ctrl-O`
    execute "normal " . dst_line . "G"
    call setpos('.', [0, dst_line, dst_col])
endfunction

command! -nargs=1 JumpToOffset :call JumpTo(<f-args>)

" silly mapping to Ctrl-C (demo)
nnoremap <expr> <silent> <c-c> ":<c-u>call JumpTo(" . v:count . ")<cr>"

このように使用できます：

:JumpToOffset 400

または、マッピングされたキーボードマッピングをカウント付きで入力します。

40CTRL-C

カウントを使用しない場合、以前のカウント数が再利用されます。つまり40CTRL-C CTRL-C CTRL-C 30CTRL-C CTRL-C、40、40、40、30、30バイトなどをジャンプすることができます。

ヒットCtrl-Oバックジャンプする（関数内のコメントを参照してください）。

私の質問のロジックを実装する次のソリューションを使用してしまいました。

• [count]GO[count]バイトを前方に移動します。
• [count]Go[count]バイトを逆方向に移動します。

これをあなたに追加してください.vimrc：

function! JumpToByte(byte_nr)
    " See https://vi.stackexchange.com/a/3911/2720 for the byte counting bug
    let crt_byte = line2byte(line('.')) + col('.') - 1
    if version < 781 && &l:binary == 1 && &l:eol == 0
        let crt_byte += 1
        let crt_byte += line('.') == 1
    endif
    let dst_byte = crt_byte + a:byte_nr
    execute "normal " . dst_byte . "go"
endfunction
nnoremap <expr> <silent> GO ":<c-u>call JumpToByte(" . v:count . ")<cr>"
nnoremap <expr> <silent> Go ":<c-u>call JumpToByte(-" . v:count . ")<cr>"

VanLaserの最初の実装に感謝しました。