Vimで元に戻す粒度を変更するにはどうすればよいですか？

ある時点で、Vimはを押すと単語全体を元に戻しuます。

[i]typing some words[C-c][u]

結果として

typing some

ただし、取り消しの細分性は、一度に1文字ずつ削除するように変更されたようです。

[i]typing some words[C-c][u]

結果

typing some word

Practical Vimで元に戻す粒度をカスタマイズすることについて何か読んだことを覚えていますが、それを制御する方法を思い出せません。助けてくれてありがとう！

元に戻すシーケンスを手動で解除する

を使用すると、挿入モードで元に戻すシーケンスを手動で解除できます<C-G>u。ヘルプから：

CTRL-G u        break undo sequence, start new change

例

iHello<C-G>u world!<Esc>u

これでテキストが残ります

Hello

コマンドの内訳

i                           " Enter Insert mode
 Hello                      " Type 'Hello'
      <C-G>u                " Break the undo sequence
             world!         " Type ' world!'
                   <Esc>    " Return to Normal mode
                        u   " Undo

自動ソリューション

よりきめの細かいundoレベルの制御

以下は、テキストの削除を開始したとき、および削除後にテキストの再入力を開始したときに、元に戻すブレークを作成するために使用するVimScriptの小さなスニペットです<C-G>u。

function! s:start_delete(key)
    let l:result = a:key
    if !s:deleting
        let l:result = "\<C-G>u".l:result
    endif
    let s:deleting = 1
    return l:result
endfunction

function! s:check_undo_break(char)
    if s:deleting
        let s:deleting = 0
        call feedkeys("\<BS>\<C-G>u".a:char, 'n')
    endif
endfunction

augroup smartundo
    autocmd!
    autocmd InsertEnter * let s:deleting = 0
    autocmd InsertCharPre * call s:check_undo_break(v:char)
augroup END

inoremap <expr> <BS> <SID>start_delete("\<BS>")
inoremap <expr> <C-W> <SID>start_delete("\<C-W>")
inoremap <expr> <C-U> <SID>start_delete("\<C-U>")

ノート

これは<BS>、<C-W>（単語の削除）、および<C-U>（行頭まで削除）で機能します。挿入モードで削除する方法が他にもある場合inoremapは、最後に追加の呼び出しを追加することでサポートできます。