Pythonクラス名の強調表示を変更するにはどうすればよいですか？

MyClassvimでPythonクラス名を強調表示する構文を定義するにはどうすればよいですか？

class MyClass(object):
    ......

Vimはすでにクラス名を強調表示しています。ただし、関数名で同じように強調表示されているようです。2つのカテゴリを強調するより良い方法がありますか？

それは正しい方法syn match ...ですか？デフォルトでsyntax/python.vim、私はこれを見つけました：

syn match   pythonFunction  "\h\w*" display contained

私は試しましたが、私のsyn定義は間違っているはずです、それは機能しません。

syn match pythonClassName "^class \(*\):" display contained
call HI('pythonClassName',         124, '', 'bold', 'bold')

HI()は自己定義関数であり、pythonStatement正常に変更するために使用しました。

実際のところ、それが本当に何をしているのかはわかりません。それはただの試みです。誰かが私にいくつかのヒントをくれますか？ありがとう！

ただし、関数名で同じように強調表示されているようです。

これ:echo synIDattr(synID(line('.'), col('.'), 1), 'name')で、構文グループの名前を取得できますpythonFunction。

これを見ると、次のよう/usr/share/vim/vim80/syntax/python.vimに強調表示されています。

syn keyword pythonStatement     class def nextgroup=pythonFunction skipwhite
syn match   pythonFunction  "\h\w*" display contained
hi def link pythonFunction      Function

クラスを個別に強調表示する機能はありません。これを追加したい場合は、次のようなものを使用できます。

" Clear default
syn clear pythonStatement

" Set it to what's in the Python file, minus the class.
syn keyword pythonStatement    False None True
syn keyword pythonStatement    as assert break continue del exec global
syn keyword pythonStatement    lambda nonlocal pass print return with yield
syn keyword pythonStatement    def nextgroup=pythonFunction skipwhite

" Now make seperate syntax groups for the class.
syn keyword pythonClassStmt class nextgroup=pythonClass skipwhite
syn match   pythonClass "\h\w*" display contained

" Avoid highlighting attributes as builtins – just added "pythonClass" here.
syn clear pythonAttribute
syn match   pythonAttribute /\.\h\w*/hs=s+1
    \ contains=ALLBUT,pythonBuiltin,pythonFunction,pythonClass,pythonAsync
    \ transparent

" Highlight the class statement and the class name.
hi def link pythonClassStmt Statement
hi pythonClass ctermfg=darkgreen guifg=darkgreen

Rubyが使用するのでダークグリーンを使用しましたが、好きな色を自由に使用してください。classキーワードは好きなように強調できます。

組み込みのPython構文ファイルの後にこれをロードするには、これをに追加し ~/.vim/after/syntax/python.vimます。

構文の強調表示に関する 一般的な入門書およびその他の詳細については、Pythonの「欠落している」構文の強調表示の修正も参照してください。