sedは4つのスペースを2に変換します

どのようにして4つのスペースを2つのスペースに変換しsedますか？出来ますか？

私はこれを見つけましたが、タブをスペースに変換します：

sed -r ':f; s|^(\t*)\s{4}|\1\t|g; t f' file

投稿したスクリプトは、4 * nスペースをnタブに変換します。ただし、それらのスペースの前にタブが付いている場合のみです。

インデントのみで4つのスペースを2つのスペースに置き換えたい場合は、sedで行うことができますが、代わりにPerlをお勧めします。

perl -pe 's{^((?: {4})*)}{" " x (2*length($1)/4)}e' file

sedで：

sed -e 's/^/~/' -e ': r' -e 's/^\( *\)~    /\1  ~/' -e 't r' -e 's/~//' file

indent代わりに使用することもできます。

簡単な方法では動作しません：

sed -r 's/ {4}/  /g'

そうでない場合は、失敗した箇所に入力を投稿してください。

先行スペースのみが変換される場合：

sed 'h;s/[^ ].*//;s/    /  /g;G;s/\n *//'

コメント付き：

sed '
  h; # save a copy of the pattern space (filled with the current line)
     # onto the hold space
  s/[^ ].*//; # remove everything starting with the first non-space
              # from the pattern space. That leaves the leading space
              # characters
  s/    /  /g; # substitute every sequence of 4 spaces with 2.
  G; # append a newline and the hold space (the saved original line) to
     # the pattern space.
  s/\n *//; # remove that newline and the indentation of the original
            # line that follows it'

vimの'ts'設定と:retabコマンドもご覧ください

sed 's/^\( \+\)\1\1\1/\1\1/' file

これは、先頭のスペースを同じグループの4つのインスタンスに分割し（それらがすべて等しい）、それらをグループの2つのインスタンスのみに置き換えることで機能します。

sed 's/    \{2,4\}\( \{0,1\}[^ ].*\)*/  \1/g' <input

これは、スペースの先頭シーケンスのみを圧縮する必要があります。