gzipアーカイブの末尾データを取得する方法は？

末尾のデータを含むgzipアーカイブがあります。それを使用して解凍すると、gzip -d「解凍OK、後続のガベージは無視されました」gzip -tと表示されます（このようなデータがあることを検出する方法として使用することもできます）。

今、私はこのゴミを知りたいのですが、不思議なことに、それを抽出する方法を見つけることができませんでした。gzip -l --verboseアーカイブの「圧縮された」サイズはファイルのサイズ（つまり、末尾のデータを含む）であることを教えてくれますが、これは誤りであり、役に立ちません。fileも役に立たないので、どうすればよいですか？

末尾のデータを取得する方法を考え出した。

末尾のデータを含むファイルを作成するPerlスクリプトを作成しました。これは、https：//bugs.debian.org/cgi-bin/bugreport.cgi？bug = 604617＃10に大きく基づいています。

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}