注：lsofここで説明する両方のアプローチを組み合わせたラッパーを維持し、https：//github.com/stephane-chazelas/misc-scripts/blob/master/lsofcでループバックTCP接続のピアの情報も追加します
Linux-3.3以降。
Linuxでは、カーネルバージョン3.3（およびUNIX_DIAG機能がカーネルに組み込まれている場合）以降、新しいnetlinkベースのAPI を使用して、特定のUNIXドメインソケット（ソケットペアを含む）のピアを取得できます。
lsof バージョン4.89がそのAPIを利用できるため：
lsof +E -aUc Xorg
次のXorgような形式で、いずれかの末尾で名前が始まるプロセスを持つすべてのUnixドメインソケットをリストします。
Xorg 2777 root 56u unix 0xffff8802419a7c00 0t0 34036 @/tmp/.X11-unix/X0 type=STREAM ->INO=33273 4120,xterm,3u
のバージョンがlsof古すぎる場合は、さらにいくつかのオプションがあります。
ssユーティリティ（からはiproute2）ピア情報を含むシステム上のUNIXドメインソケットのリストについての情報を取得し、表示するために、その同じAPIを利用します。
ソケットは、iノード番号によって識別されます。ソケットファイルのファイルシステムのiノードとは関係がないことに注意してください。
例えば：
$ ss -x
[...]
u_str ESTAB 0 0 @/tmp/.X11-unix/X0 3435997 * 3435996
ソケット3435997（それはABSTRACTソケットにバインドされていた/tmp/.X11-unix/X0）がソケット3435996に接続されていると-p言います。オプションは、どのプロセスがそのソケットを開いているかを伝えることができます。いくつかreadlinkのsを/proc/$pid/fd/*実行することでそれを行いますので、所有しているプロセスでのみ実行できます（を使用している場合を除くroot）。例えばここに：
$ sudo ss -xp
[...]
u_str ESTAB 0 0 @/tmp/.X11-unix/X0 3435997 * 3435996 users:(("Xorg",pid=3080,fd=83))
[...]
$ sudo ls -l /proc/3080/fd/23
lrwx------ 1 root root 64 Mar 12 16:34 /proc/3080/fd/83 -> socket:[3435997]
3435996のプロセスを調べるには、次の出力で独自のエントリを検索できますss -xp。
$ ss -xp | awk '$6 == 3435996'
u_str ESTAB 0 0 * 3435996 * 3435997 users:(("xterm",pid=29215,fd=3))
このスクリプトをラッパーとして使用してlsof、関連する情報を簡単に表示することもできます。
#! /usr/bin/perl
# lsof wrapper to add peer information for unix domain socket.
# Needs Linux 3.3 or above and CONFIG_UNIX_DIAG enabled.
# retrieve peer and direction information from ss
my (%peer, %dir);
open SS, '-|', 'ss', '-nexa';
while (<SS>) {
if (/\s(\d+)\s+\*\s+(\d+) ([<-]-[->])$/) {
$peer{$1} = $2;
$dir{$1} = $3;
}
}
close SS;
# Now get info about processes tied to sockets using lsof
my (%fields, %proc);
open LSOF, '-|', 'lsof', '-nPUFpcfin';
while (<LSOF>) {
if (/(.)(.*)/) {
$fields{$1} = $2;
if ($1 eq 'n') {
$proc{$fields{i}}->{"$fields{c},$fields{p}" .
($fields{n} =~ m{^([@/].*?)( type=\w+)?$} ? ",$1" : "")} = "";
}
}
}
close LSOF;
# and finally process the lsof output
open LSOF, '-|', 'lsof', @ARGV;
while (<LSOF>) {
chomp;
if (/\sunix\s+\S+\s+\S+\s+(\d+)\s/) {
my $peer = $peer{$1};
if (defined($peer)) {
$_ .= $peer ?
" ${dir{$1}} $peer\[" . (join("|", keys%{$proc{$peer}})||"?") . "]" :
"[LISTENING]";
}
}
print "$_\n";
}
close LSOF or exit(1);
例えば：
$ sudo that-lsof-wrapper -ad3 -p 29215
コマンドPIDユーザーFDタイプデバイスサイズ/オフノード名
xterm 29215 stephane 3u unix 0xffff8800a07da4c0 0t0 3435996 type = STREAM <-> 3435997 [Xorg、3080、@ / tmp / .X11-unix / X0]
linux-3.3より前
UNIXソケット情報を取得する古いLinux APIは、/proc/net/unixテキストファイル経由です。すべてのUnixドメインソケット（ソケットペアを含む）をリストします。そこの最初のフィールド（kernel.kptr_restrictsysctlパラメーターで非スーパーユーザーに隠されていない場合）は、@ Totorによって既に説明されているように、対応するpeerを指すフィールドunix_sockを含む構造のカーネルアドレスを含みます。また、Unixソケットの列に出力するものでもあります。peer unix_socklsofDEVICE
現在、そのpeerフィールドの値を取得するということは、カーネルメモリを読み取っpeerて、unix_sockアドレスに関するそのフィールドのオフセットを知ることができることを意味します。
いくつかのgdbベースおよびsystemtapベースのソリューションがすでに提供されていますが、それらはインストールされている実行中のカーネルにgdb/ systemtapおよびLinuxカーネルデバッグシンボルを必要とします。
オフセットのハードコーディングは、カーネルバージョンによって異なるため、実際にはオプションではありません。
これで、オフセットの決定にヒューリスティックなアプローチを使用できます：ツールにダミーを作成させsocketpair（両方のピアのアドレスを知っている）、オフセットを決定するために相手側のメモリの周りのピアのアドレスを検索します。
以下は、まさにそれを使用する概念実証スクリプトですperl（i386ではカーネル2.4.27および2.6.32、amd64では3.13および3.16でテストが成功しました）。上記のように、それは周りのラッパーとして機能しますlsof：
例えば：
$ that-lsof-wrapper -aUc nm-applet
コマンドPIDユーザーFDタイプデバイスサイズ/オフノード名
NM-アプレット4183ステファンの4U UNIX 0xffff8800a055eb40 0t0 36888タイプ= STREAM - > 0xffff8800a055e7c0 [DBUSデーモン、4190、@ / TMP / DBUS-AiBCXOnuP6]
NM-アプレット4183ステファンの7U UNIX 0xffff8800a055e440 0t0 36890タイプ= STREAM - > 0xffff8800a055e0c0 [Xorgの、 3080、@ / tmp / .X11-unix / X0]
nm-applet 4183 stephane 8u unix 0xffff8800a05c1040 0t0 36201 type = STREAM-> 0xffff8800a05c13c0 [dbus-daemon、4118、@ / tmp / dbus-yxxNr1NkYC]
nm-applet 4183 unix 0xffff8800a055d080 0t0 36219 type = STREAM- > 0xffff8800a055d400 [dbus-daemon、4118、@ / tmp / dbus-yxxNr1NkYC]
nm-applet 4183 stephane 12u unix 0xffff88022e0df036268type = STREAM > / run / dbus / system_bus_socket]
nm-applet 4183 stephane 13u unix 0xffff88022e0f80c0 0t0 37025 type = STREAM-> 0xffff88022e29ec00 [dbus-daemon、2268、/ var / run / dbus / system_bus_socket]
スクリプトは次のとおりです。
#! /usr/bin/perl
# wrapper around lsof to add peer information for Unix
# domain sockets. needs lsof, and superuser privileges.
# Copyright Stephane Chazelas 2015, public domain.
# example: sudo this-lsof-wrapper -aUc Xorg
use Socket;
open K, "<", "/proc/kcore" or die "open kcore: $!";
read K, $h, 8192 # should be more than enough
or die "read kcore: $!";
# parse ELF header
my ($t,$o,$n) = unpack("x4Cx[C19L!]L!x[L!C8]S", $h);
$t = $t == 1 ? "L3x4Lx12" : "Lx4QQx8Qx16"; # program header ELF32 or ELF64
my @headers = unpack("x$o($t)$n",$h);
# read data from kcore at given address (obtaining file offset from ELF
# @headers)
sub readaddr {
my @h = @headers;
my ($addr, $length) = @_;
my $offset;
while (my ($t, $o, $v, $s) = splice @h, 0, 4) {
if ($addr >= $v && $addr < $v + $s) {
$offset = $o + $addr - $v;
if ($addr + $length - $v > $s) {
$length = $s - ($addr - $v);
}
last;
}
}
return undef unless defined($offset);
seek K, $offset, 0 or die "seek kcore: $!";
my $ret;
read K, $ret, $length or die "read($length) kcore \@$offset: $!";
return $ret;
}
# create a dummy socketpair to try find the offset in the
# kernel structure
socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC)
or die "socketpair: $!";
$r = readlink("/proc/self/fd/" . fileno(Rdr)) or die "readlink Rdr: $!";
$r =~ /\[(\d+)/; $r = $1;
$w = readlink("/proc/self/fd/" . fileno(Wtr)) or die "readlink Wtr: $!";
$w =~ /\[(\d+)/; $w = $1;
# now $r and $w contain the socket inodes of both ends of the socketpair
die "Can't determine peer offset" unless $r && $w;
# get the inode->address mapping
open U, "<", "/proc/net/unix" or die "open unix: $!";
while (<U>) {
if (/^([0-9a-f]+):(?:\s+\S+){5}\s+(\d+)/) {
$addr{$2} = hex $1;
}
}
close U;
die "Can't determine peer offset" unless $addr{$r} && $addr{$w};
# read 2048 bytes starting at the address of Rdr and hope to find
# the address of Wtr referenced somewhere in there.
$around = readaddr $addr{$r}, 2048;
my $offset = 0;
my $ptr_size = length(pack("L!",0));
my $found;
for (unpack("L!*", $around)) {
if ($_ == $addr{$w}) {
$found = 1;
last;
}
$offset += $ptr_size;
}
die "Can't determine peer offset" unless $found;
my %peer;
# now retrieve peer for each socket
for my $inode (keys %addr) {
$peer{$addr{$inode}} = unpack("L!", readaddr($addr{$inode}+$offset,$ptr_size));
}
close K;
# Now get info about processes tied to sockets using lsof
my (%fields, %proc);
open LSOF, '-|', 'lsof', '-nPUFpcfdn';
while (<LSOF>) {
if (/(.)(.*)/) {
$fields{$1} = $2;
if ($1 eq 'n') {
$proc{hex($fields{d})}->{"$fields{c},$fields{p}" .
($fields{n} =~ m{^([@/].*?)( type=\w+)?$} ? ",$1" : "")} = "";
}
}
}
close LSOF;
# and finally process the lsof output
open LSOF, '-|', 'lsof', @ARGV;
while (<LSOF>) {
chomp;
for my $addr (/0x[0-9a-f]+/g) {
$addr = hex $addr;
my $peer = $peer{$addr};
if (defined($peer)) {
$_ .= $peer ?
sprintf(" -> 0x%x[", $peer) . join("|", keys%{$proc{$peer}}) . "]" :
"[LISTENING]";
last;
}
}
print "$_\n";
}
close LSOF or exit(1);