空行のzshタブ補完

12

見つけられなかったtcsh'ismが欲しい：内容のない空白行で、タブキーを押してlsに相当するものを見たい。それは私が欲しいと言うことです

$ <tab>

他のことをしてから\ tをくれ。コマンド補完のための素晴らしいリソースは見つかりましたが、この基本的なケースでは見つかりませんでした。これに関するどんな助けも素晴らしいです！ありがとう。

shell configuration zsh

— キリスト教徒
ソース

8

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

— ジョン・エイケンベリー
ソース

とてもきちんとしています。リストをどうにかして再び非表示にすることは可能でしょうか？タブで表示してからタブで非表示にすると便利です。

— パーカーコーツ

ジョンのおかげで、私はあなたの解決策を見つけてここに適応しましたstackoverflow.com/questions/28729851/…–

— lolesque

7

Tab行頭のの動作は、スタイルによって制御されます。ただし、サポートされている動作は2つだけです。insert-tab

通常どおり、下で完了 zstyle ':completion:*' insert-tab false
下にタブを挿入する zstyle ':completion:*' insert-tab true
どちらか一方 zstyle ':completion:*' insert-tab pending[=N]

その位置でコマンドを完成させたいだけなら、そうしますzstyle ':completion:*' insert-tab true。現在のディレクトリのファイルを一覧表示するなど、別のものが必要な場合は、を変更する必要があります_main_complete。

zshの研究者リストの最近のスレッドが議論しましたinsert-tab。

— ジル「SO-悪であるのをやめる」
ソース

素晴らしい！_main_completeによって、Cコードのどこかで参照しているように見えますか？ばかげた質問で申し訳ありませんが、それはどこにありますか？

1

@ user535759：いいえ、_main_complete補完を実装するzshコードの一部です。これCompletion/Base/Core/_main_completeはソースツリーにあり、通常のような場所にインストールされ/usr/share/zsh/functions/Completion/Base/_main_completeます。

— Gilles「SO-邪悪なことをやめる」

@lluaに関連付けられたスタイルを変更し-command-ても、<Tab>は現在のディレクトリ内のファイルを一覧表示しません。これで、コマンド名を省略するように一致を制限するだけです。しかし、この位置に完成されるだろう唯一のものが列挙されているので、現在のディレクトリ（に応じてのみ、ディレクトリと実行可能ファイル内のファイルではないautocdとPATH）。

— Gilles 'SO-悪をやめる'

3

空の行でタブを押すと、zshでのtcshのオートリストの完全な実装がここにあります

% <TAB>

ここにあります：

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

tcshをより厳密にエミュレートする場合は、これも.zshrcに追加します。

unsetopt always_last_prompt       # print completion suggestions above prompt

— イラクサ
ソース

2

私が書いた本だけでなく、空の行に、TABの使用を強化するzshのウィジェットを、だけでなく、次のコマンドを入力している間。

空のコマンドライン上、およびコマンドの途中にファイルをリストします。
空のコマンドラインでディレクトリをリストします。
空のコマンドラインに実行可能ファイルをリストします。

これらの場合、グローバル変数を付加して「cd」または「./」を付加するように構成できます。

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA

— ナチョパーカー
ソース