シェル変数を/ pattern /としてawkに渡す

私のシェル関数の1つに次のものがある：

function _process () {
  awk -v l="$line" '
  BEGIN {p=0}
  /'"$1"'/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '
}

として呼び出されると_process $arg、として$arg渡され$1、検索パターンとして使用されます。$1awkパターンの代わりにシェルが展開するため、このように動作します！またl、awkプログラム内で使用することができますを使用して宣言されています-v l="$line"。大丈夫だ。

同じ方法で変数として検索するパターンを与えることは可能ですか？

以下は機能しませんが、

awk -v l="$line" -v search="$pattern" '
  BEGIN {p=0}
  /search/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '

awkが/search/変数として解釈するのではなく、文字通り解釈するため。

awkの~演算子を使用すると、右側にリテラル正規表現を指定する必要はありません。

function _process () {
    awk -v l="$line" -v pattern="$1" '
        $0 ~ pattern {p=1} 
        END {if(p) print l >> "outfile.txt"}
    '  
}

これはより効率的ですが（ファイル全体を読む必要はありません）

function _process () {
    grep -q "$1" && echo "$line"
}

パターンに応じて、 grep -Eq "$1"

awk  -v pattern="$1" '$0 ~ pattern'

でawkANSI Cエスケープシーケンス（\n改行、\fフォームフィード、\\バックスラッシュなど）を展開するという問題があります$1。そのため$1、正規表現で一般的なバックスラッシュ文字が含まれていると問題になります（GNU awk4.2以降では、で始まり、@/で終わる値/も問題になります）。その問題に悩まされない別のアプローチは、それを書くことです：

PATTERN=$1 awk '$0 ~ ENVIRON["PATTERN"]'

それがどれほど悪いかは、awk実装に依存します。

$ nawk -v 'a=\.' 'BEGIN {print a}'
.
$ mawk -v 'a=\.' 'BEGIN {print a}'
\.
$ gawk -v 'a=\.' 'BEGIN {print a}'
gawk: warning: escape sequence `\.' treated as plain `.'
.
$ gawk5.0.1 -v 'a=@/foo/' BEGIN {print a}'
foo

awkただし、すべてのsは有効なエスケープシーケンスに対して同じように機能します。

$ a='\\-\b' awk 'BEGIN {print ENVIRON["a"]}' | od -tc
0000000   \   \   -   \   b  \n
0000006

（$aそのまま渡された内容）

$ awk -v a='\\-\b' 'BEGIN {print a}' | od -tc
0000000   \   -  \b  \n
0000004

（\\に変更\し、\bバックスペース文字に変更）。

次のようなものを試してください：

awk -v l="$line" -v search="$pattern" 'BEGIN {p=0}; { if ( match( $0, search )) {p=1}}; END{ if(p) print l >> "outfile.txt" }'

いいえ。ただし、awkに渡す二重引用符で囲まれた文字列にパターンを単純に挿入できます。

awk -v l="$line" "BEGIN {p=0}; /$pattern/ {p=1}; END{ if(p) print l >> \"outfile.txt\" }"

二重引用符で囲まれたawkリテラルをエスケープする必要があることに注意してください。ただし、これはこれを達成する最も簡単な方法です。

この例では、awkが実行される前にnets変数を解決するeval関数を使用できます。

nets="searchtext"
eval "awk '/"${nets}"/'" file.txt