awkを使用して2つのファイルを処理する

UnixとAwkを使用した2つのファイルの比較を読みました。本当に面白いです。私はそれを読んでテストしましたが、完全に理解することはできず、他の場合にそれを使用します。

2つのファイルがあります。file11つのフィールドがあり、もう1つのフィールドには16フィールドがあります。1の要素を読み取りfile、それらをの3番目のフィールドと比較したいfile2。各要素が一致した場合、フィールド5の値を合計しますfile2。例として：

ファイル1

1
2
3

ファイル2

2 2 2 1 2
3 6 1 2 4 
4 1 1 2 3
6 3 3 3 4 

要素1の場合、フィールド3の値が1 file1であるフィールド5に値を追加しますfile2。そして、要素2と3にも同じことを行いfile1ます。1の出力は（3 + 4 = 7）で、2の出力は2、3の出力は4です。

どのようにawkで書けばよいかわかりません。

ここに一つの方法があります。コメントを追加できるように、これをawkスクリプトとして記述しました。

#!/usr/local/bin/awk -f

{
    ## FNR is the line number of the current file, NR is the number of 
    ## lines that have been processed. If you only give one file to
    ## awk, FNR will always equal NR. If you give more than one file,
    ## FNR will go back to 1 when the next file is reached but NR
    ## will continue incrementing. Therefore, NR == FNR only while
    ## the first file is being processed.
    if(NR == FNR){
      ## If this is the first file, save the values of $1
      ## in the array n.
      n[$1] = 0
    }
    ## If we have moved on to the 2nd file
    else{
      ## If the 3rd field of the second file exists in
      ## the first file.
      if($3 in n){
        ## Add the value of the 5th field to the corresponding value
        ## of the n array.
        n[$3]+=$5
      }
    }
}
## The END{} block is executed after all files have been processed.
## This is useful since you may have more than one line whose 3rd
## field was specified in the first file so you don't want to print
## as you process the files.
END{
    ## For each element in the n array
    for (i in n){
    ## print the element itself and then its value
    print i,":",n[i];
    }
}

これをファイルとして保存し、実行可能にして、次のように実行できます。

$ chmod a+x foo.awk
$ ./foo.awk file1 file2
1 : 7
2 : 2
3 : 4

または、それを1行にまとめることもできます。

awk '
     (NR == FNR){n[$1] = 0; next}
     {if($3 in n){n[$3]+=$5}}
     END{for (i in n){print i,":",n[i]} }' file1 file2

awk '
  NR == FNR {n[$3] += $5; next}
  {print $1 ": " n[$1]}' file2 file1