単一のUbuntu SDKがタッチとデスクトップを別々のレイアウトでターゲットにできますか？

タッチアプリが同じUIでデスクトップ上で実行されることは知っていますが、デスクトップモードで実行しているときに、単一のUbuntu SDKアプリがデスクトップスタイルのUI要素を備えたマルチウィンドウUIを持つことができるかどうか疑問に思っていました。タッチプラットフォームで実行するときに、個別のタッチUIを提供します。

ウィンドウのサイズに応じてレイアウトのアスペクトを変更するには、いくつかの方法があります。最も基本的なレベルでは、ディメンションに基づいてプロパティをさまざまな値に設定できます。ウィンドウを大きくするとオレンジ色に変わる灰色の四角形を描画する最小限の例を次に示します。

で実行 qmlscene path/to/file.qml

import QtQuick 2.0
import Ubuntu.Components 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(50)

    Rectangle {
        id: hello
        color: parent.width > units.gu(60) ? UbuntuColors.orange : UbuntuColors.warmGrey
        anchors.fill: parent
    }
}

もちろん、アプリケーションにもっと複雑な要素がある場合、これは少し面倒になる可能性があります。これを支援するために、Ubuntu ToolkitにはConditionalLayoutコンポーネントが用意されており、条件が満たされたときにアクティブ化されるさまざまなレイアウトを定義できます。これは動的に発生し、ウィンドウのサイズを変更すると、変更を確認できます。

以下は、より複雑な例ConditionalLayoutです。

import QtQuick 2.0
import Ubuntu.Components 0.1
import Ubuntu.Components.ListItems 0.1 as ListItem
import Ubuntu.Layouts 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(75)

    Page {
        anchors.fill: parent

        Layouts {
            id: layouts
            anchors.fill: parent
            layouts: [

                ConditionalLayout {
                    name: "flow"
                    when: layouts.width > units.gu(60)

                    Flow {
                        anchors.fill: parent
                        flow: Flow.LeftToRight

                        ItemLayout {
                            item: "sidebar"
                            id: sidebar
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                            }
                            width: parent.width / 3
                        }

                        ItemLayout {
                            item: "colors"
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                                right: parent.right
                                left: sidebar.right
                            }
                        }
                    }
                }
            ]

            Column {
                id: sidebar
                anchors {
                    left: parent.left
                    top: parent.top
                    right: parent.right
                }
                Layouts.item: "sidebar"

                ListItem.Header {
                    text: "Ubuntu Color Palette"
                }

                ListItem.Standard {
                    id: orangeBtn
                    text: "Ubuntu Orange"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.orange
                        }
                    }
                }

                ListItem.Standard {
                    id: auberBtn
                    text: "Canonical Aubergine"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.lightAubergine
                        }
                    }
                }

                ListItem.Standard {
                    id: grayBtn
                    text: "Warm Grey"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.warmGrey
                        }
                    }
                }
            } // Column

            Rectangle {
                id: hello
                Layouts.item: "colors"
                color: UbuntuColors.warmGrey
                anchors {
                    top: sidebar.bottom
                    bottom: parent.bottom
                    left: parent.left
                    right: parent.right
                }

                Label {
                    anchors.centerIn: parent
                    text: "Hello (ConditionalLayout) World!"
                    color: "black"
                    fontSize: "large"
                }
            }
        } // Layouts
    } // Page
} // Main View

デフォルトの電話のようなサイズの場合、次のようになります。

タブレットまたはデスクトップのようなサイズに展開すると、次のようになります。

条件付きレイアウトを使用すると、この結果が得られると思います。