一部のマシンをWindows 10にアップグレードし、必要に応じて更新される更新があることを認識しました。ただし、Windows 7および8.1の場合と同様に、ダウンロードを停止するためのオプションがないことに気付きました。ダウンロードを停止できる唯一の方法は、Windows Updateサービスを停止することでした。

私の質問は、自動更新を停止する方法を知っている人がいますか、またはサービスを停止することが唯一の解決策ですか？

Pro Editionをお持ちの場合は、グループポリシーエディター（gpedit.msc）を開いてConfigure automatic updates、次の場所にあるエントリを検索します。

computer configuration → administrative templates → windows components → windows update

を選択しますNotify for download and notify for install。

Windowsが新しい更新を検出すると、トースト通知が表示されます。

また、更新KB3073930のトラブルシューティングツールを使用して、問題のある更新プログラムを無効にして、再度インストールされないようにすることもできます。

これは、不要な更新プログラムとドライバーのセットアップを防ぐためのMicrosoftの公式な方法です。

ただし、Windows Update MiniToolと呼ばれるサードパーティ製ツールがあり、これを使用して、インストールできる更新プログラムを選択したり、以前のWindowsバージョンのように更新プログラムをブロックしたりできます。

あなたは何ができるか、標準のWindows Updateへの代替：
•アップデートの確認
•ダウンロードのアップデート
•アップデートのインストール
•削除、更新をインストール
• 不要な更新を非表示
* .cabファイル/ *の.Exe / * .Psf更新ファイルへの直接リンクを取得します。•
•更新履歴を表示する
• 自動更新を構成する
•このツールは、外部PowerShellモジュールPSWindowsUpdateに似ていますが、はるかに高度で使いやすい機能です
•ツールは同じWUインフラストラクチャに依存し、使用します。すべてのダウンロードはダウンローダーではなくWU

ユーザーslavanapは、更新プログラムを選択的にインストールできるようにする2番目のツールをコメントで投稿しました。Windows10 Manual Updateと呼ばれ、githubで入手できます。

。

Windows 10クリエイターの更新、オプションがあります 35日間のWindowsアップデートを停止するには：

Windows Updateオプションがある設定アプリの下。

Windows 10で最も物議をかもす側面の1つは、更新を義務付けるというマイクロソフトの決定です。Windows 10 Pro、Enterprise、またはEducationのエディションをお持ちの場合、更新を延期できますが、それらを完全に拒否することはできません。

マイクロソフトがユーザーの発言なしにシステムに強制的に更新プログラムをインストールすることに不満がある場合は、W10Privacyを使用してこの機能をブロックできます。

ソフトウェアがWindows 10の多くのプライバシー機能を制御できるので、チェックする価値が十分にある前にこのプログラムを聞いたことがない場合は、OSが何をしているのかを盗むことを防ぐことができます。オプションは色分けされているため、変更/無効化しても安全かどうかが一目でわかります。

でW10Privacy 2、あなたは今のWindows 10の独自の更新メカニズムを無効にし、独自でそれを置き換えるためにプログラムを設定することができます。ユーザーは、インストールする更新プログラムと無視する更新プログラムを選択できます。これは誰もがすべきことではありませんが、必要に応じて簡単に元に戻すことができます。

この機能を使用する前に、いくつかの追加コンポーネントをダウンロードする必要があります。次の手順を実行します：

• W10Privacy 2をダウンロードし、ハードドライブのフォルダーに解凍します。
• PsExec（PsToolsパッケージの一部）をダウンロードし、W10Privacyフォルダーにコピーします。
• TechnetからWindows Update PowerShellモジュールをダウンロードし、W10Privacyフォルダーのサブフォルダーに解凍します。
• 右クリックW10Privacy.exeして、コンテキストメニューから[ 管理者として実行] を選択します。システムの復元ポイントを作成することを選択します。（念のため）システム全体のバックアップを作成する価値もあります。
• オプションを管理するには、[エクストラ]> [Windows Updates]に移動します。6つの異なるチェックボックスがあります。デフォルトではどれも有効になっていません。彼らです：
• PSWindows Updateモジュールが存在します（ユーザーが事前にW10Privacyフォルダーに提供する必要があります）。
• W10PrivacyフォルダーのPsExec.exe（ユーザーが提供する必要があります）。PSWindows-UpdateモジュールのW10Privacy適応。

• 偽のWSUSサーバーを構成します。

• W10Privacyは、スペースのないパス/フォルダーにあります。更新検索ではドライバーを考慮しないでください。

• 更新を手動で管理する場合は、最初の5つのオプションを確認してください。6番目のオプションでは、更新プログラムと共にドライバーをリストするかどうかを決定できます。これはあなた次第です。
• [変更された設定を設定]をクリックし、[更新プログラムの確認を開始]ボタンをクリックすると、まだインストールされていない新しい更新プログラムが表示され、実行するアクションを選択できます。

更新を担当したら、定期的にソフトウェアを実行し、重要な更新を見逃さないことを確認してください。

クレジット：

1. Windows 10の自動更新を完全に制御する方法

@Ramhoundの助けを借りて、Windows 10で自動更新を停止する方法を見つけました。

私が実行しているバージョンであるため、これはWindows 10 Proに適用されることに注意してください。

自動更新を停止するには、次を実行できます。

1. 設定を開く
2. [更新とセキュリティ]をクリックします
3. クリック Advanced options
4. Defer upgradesオプションがチェックされていることを確認
5. 設定ウィンドウを閉じて、それで完了です！

更新

@Vinayakのコメントで述べたように、延期オプションはホームユーザーも利用できるようになりました。詳細はこちら

以前のバッチファイルを大幅に修正し、スイートを単一のスクリプトに切り替えて、ベストプラクティスでブロックします！
実際に見てください

すべてを切り替えることができるデスクトップの右クリックコンテキストメニューの動的UI！
すべてのブロックのオン/オフの切り替え、（pastebinからの）更新、またはスクリプトオプションのアンインストール

カウンターで更新リストを非表示/再表示/インストールします！
リストは、WindowsがMusNotificationを介してあなたにうなずくたびに自動的に更新されます！

所有権の破壊的な変更、ファイルの削除、タスクの削除を伴わないビルドアップグレード、自動インストール、ダウンロード、サービスIFEOの安全なブロックを独立してブロック

独立して
動作するDefenderの更新に焦点を当てる他の-DIY-更新 "管理"とは異なり、Windowsの混乱の自動更新の切り替えは、組み込みの保護レイヤーを犠牲にしません

windows_update_toggle.bat

@set @version=10.0 /* &title Windows Update Toggle
@echo off &set "verbose="
echo.
echo      ---------------------------------------------------------------------
echo     :                  Windows Update Toggle v10.0 final                  :
echo     :---------------------------------------------------------------------:
echo     :      Block/Enable Upgrades, Installs, Downloads(!), Service(!)      :
echo     :         Disable/Enable Reporting, Speech, SearchUI, Defender        :
echo     :        Hide/Unhide/Apply update lists with count and max size       :
echo     :       Preset for Defender updates and Store downloads working       :
echo     :                                                                     :
echo     :     Toggle from the comfort of Desktop right-click context menu     :
echo      ---------------------------------------------------------------------
echo.
:: AveYo, 2018-05-13

if %1.==. timeout /t 10 &call wscript /e:JScript "%~f0" runas setup &exit/b &rem : no arguments, run setup elevated
if %1.==shift. shift &shift &rem : if loaded by WScript, shift args to prevent loop and restore %0
if %1.==. echo ERROR! &timeout /t 5 &exit/b : must have at least one arg

:: Setup executable blocking via ifeo
set notifier=EOSNotify MusNotification
set upgrader=Windows10UpgraderApp Windows10Upgrade WindowsUpdateBox SetupHost setupprep
set installer=wuauclt
set reporter=wermgr wsqmcons DiagTrackRunner DiagnosticsHub.StandardCollector.Service CompatTelRunner
set speecher=SpeechRuntime SpeechModelDownload
set searcher=SearchUI

set "exe=%notifier% %upgrader% %installer% %reporter%"
set "noop=%SystemRoot%\system32\systray.exe"
set "ifeo=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options"
set "menu=HKCR\DesktopBackground\shell\WUT"
set "f0=%SystemRoot%\windows_update_toggle.bat"
set "task=wscript.exe /e:JScript \"%f0%\" schtasks WUT"
set "DefMUS={MicrosoftUpdateServer|MMPC|InternalDefinitionUpdateServer}"
set "DefMMPC={MMPC|MicrosoftUpdateServer|InternalDefinitionUpdateServer}"
set ".=>nul 2>nul"
for /f "tokens=2 delims=1234567890" %%# in ('shutdown /?^|findstr /bc:"E"') do set "[T]=%%#" &rem : cosmetic usage in menus
if defined verbose (echo on &set ".=" &set "window=") else set "window=hide"
call :%~1 %2 %3 %4 %5 %6 %7 %8 %9 &rem : launch secondary functions below dinamically, passing next args
echo.
echo Done! Use the Desktop right-click context menu to toggle, renew or uninstall
if "%~1"=="setup" (pause) else if defined verbose timeout /t 5
exit/b : End of main script, functions below

:refresh context menu
echo %0 %*
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoBlock noblock
if "%noblock%"=="Enable" exit/b
call :reg_query "%menu%0pending" MUIVerb pending
if defined pending exit/b
for %%# in ("1hide" "2unhide" "3apply") do reg delete "%menu%%%~#" /f %.%
reg add "%menu%0pending" /v MUIVerb /d "Pending.." /f %.%
reg add "%menu%0pending" /v SubCommands /d "" /f %.%
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoRefresh norefresh
if "%norefresh%"=="Disable" start "WUT" wscript /e:JScript "%f0%" WUTRefresh
call :status SetupHost
reg add "%menu%\shell\3Upgrades"   /v MUIVerb /d "Upgrades %[T]% [setuphost]    %toggle%" /f %.%
reg add "%menu%\shell\3Upgrades\command" /ve /d "%task%\upgrades" /f %.%
call :status wuauclt
reg add "%menu%\shell\4Installs"   /v MUIVerb /d "Installs %[T]% [wuauclt]    %toggle%" /f %.%
reg add "%menu%\shell\4Installs\command" /ve /d "%task%\installs" /f %.%
for /f "tokens=3" %%# in ('sc qc TrustedInstaller ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="[WUTblocked]" (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\5Downloads"  /v MUIVerb /d "Downloads ( ! ) %[T]% [trustedinstaller]    %toggle%" /f %.%
reg add "%menu%\shell\5Downloads\command" /ve /d "%task%\downloads" /f %.%
for /f "tokens=3" %%# in ('sc qc wuauserv ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="rpcss[WUTblocked]" (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\6Service"    /v MUIVerb /d "Service ( ! ) %[T]% [wuauserv]    %toggle%" /f %.%
reg add "%menu%\shell\6Service\command" /ve /d "%task%\service" /f %.%
call :status wermgr
reg add "%menu%\shell\81Report"    /v MUIVerb /d "Report    %[T]% %toggle%" /f %.%
reg add "%menu%\shell\81Report\command" /ve /d "%task%\report" /f %.%
call :status SpeechRuntime
reg add "%menu%\shell\82Speech"    /v MUIVerb /d "Speech    %[T]% %toggle%" /f %.%
reg add "%menu%\shell\82Speech\command" /ve /d "%task%\speech" /f %.%
call :status SearchUI
reg add "%menu%\shell\83Search"    /v MUIVerb /d "SearchUI  %[T]% %toggle%" /f %.%
reg add "%menu%\shell\83Search\command" /ve /d "%task%\search" /f %.%
set "defstatus=if((Get-MpPreference).DisableRealtimeMonitoring){write-host stopped}else{write-host enabled}"
for /f "delims=" %%# in ('call powershell.exe -c "%defstatus%;"') do set "toggle=%%#"
reg add "%menu%\shell\84Defender"  /v MUIVerb /d "Defender  %[T]% %toggle%" /f %.%
reg add "%menu%\shell\84Defender\command" /ve /d "%task%\defender" /f %.%
if "%norefresh%"=="Enable" reg delete "%menu%0pending" /f %.%
exit/b

:toggle WUT
echo %0 %*
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoBlock noblock
if "%noblock%"=="Disable" (set "toggle=Enable") else set "toggle=Disable"
for %%# in (NoBlock NoRefresh) do reg add "HKLM\SOFTWARE\WUT.bat" /v %%# /d "%toggle%" /f %.%
:: Generate WUT main context menu
for %%# in ("" "0pending" "1hide" "2unhide" "3apply") do reg delete "%menu%%%~#" /f %.%
reg add "%menu%" /v MUIVerb /d "Windows Update Toggle" /f %.%
reg add "%menu%" /v Icon /d "appwiz.cpl,5" /f %.%
reg add "%menu%" /v SubCommands /d "" /f %.%
reg add "%menu%\shell\9Setup" /v MUIVerb /d "windows_update_toggle.bat v10.0" /f %.%
reg add "%menu%\shell\9Setup" /v SubCommands /d "" /f %.%
reg add "%menu%\shell\9Setup\shell\1Toggle" /v MUIVerb /d "%toggle%" /f %.%
reg add "%menu%\shell\9Setup\shell\2Renew"  /v MUIVerb /d "Renew" /f %.%
reg add "%menu%\shell\9Setup\shell\3Remove" /v MUIVerb /d "Remove" /f %.%
reg add "%menu%\shell\9Setup\shell\1Toggle\command" /ve /d "%task%\toggle" /f %.%
reg add "%menu%\shell\9Setup\shell\2Renew\command"  /ve /d "%task%\renew" /f %.%
reg add "%menu%\shell\9Setup\shell\3Remove\command" /ve /d "%task%\remove" /f %.%
if "%toggle%"=="Disable" (
 reg add "%menu%\shell\1Refresh" /v MUIVerb /d "Refresh" /f %.%
 reg add "%menu%\shell\1Refresh\command" /ve /d "%task%\refresh" /f %.%
 reg add "%menu%\shell\2Lists" /v MUIVerb /d "Hide / Unhide / Apply %[T]% enabled" /f %.%
 reg add "%menu%\shell\2Lists\command" /ve /d "%task%\lists" /f %.%
 reg add "%menu%\shell\7Repair"     /v MUIVerb /d "Troubleshooter" /f %.%
 reg add "%menu%\shell\7Repair\command" /ve /d "%task%\repair" /f %.%
)
:: Disabling automatic updates hinders Defender, so get definitions from MMPC first
if "%toggle%"=="Enable" ( set "DefSig=%DefMUS%" ) else set "DefSig=%DefMMPC%"
start "WUT:MpPref" wscript /e:JScript "%~f0" cmd "powershell.exe -c `Set-MpPreference -SignatureFallbackOrder %DefSig%;`"
:: Default services
sc config wuauserv type= share depend= rpcss %.%
sc config TrustedInstaller type= own depend= / %.%
:: Toggle ifeo exe blocking
for %%# in (%exe% %speech% %search%) do reg delete "%ifeo%\%%#.exe" /f %.%
if "%toggle%"=="Enable" exit/b WUT disabled, so skip the code below
for %%# in (%exe%) do reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
:: WUTRefresh hijacking
for %%# in (MusNotification EOSNotify) do reg add "%ifeo%\%%#.exe" /v Debugger /d "%SystemRoot%\WUTRefresh.bat" /f %.%
call :refresh menu
exit/b

:hide update
echo %0 %*
call :reg_query "%menu%1hide\shell\%~1" MUIVerb updatefound
echo -%updatefound%
if not defined updatefound exit/b
call wscript /e:JScript "%f0%" hide "%updatefound%"
exit/b

:unhide update
echo %0 %*
call :reg_query "%menu%2unhide\shell\%~1" MUIVerb updatefound
echo -%updatefound%
if not defined updatefound exit/b
call wscript /e:JScript "%f0%" unhide "%updatefound%"
exit/b

:apply update
echo %0 %*
call :reg_query "%menu%3apply\shell\%~1" MUIVerb updatefound
echo -%updatefound%
if not defined updatefound exit/b
:: Temporarily unblock downloads and installs
call :reg_query "%ifeo%\wuauclt.exe" Debugger installs_blocked
for /f "tokens=3" %%# in ('sc qc TrustedInstaller ^| find /I "WUTblocked"') do set "downloads_blocked=%%#"
call wscript /e:JScript "%f0%" apply "%updatefound%"
:: Restore block
if defined installs_blocked reg add "%ifeo%\wuauclt.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "wuauclt.exe" /t /f %.%
if defined downloads_blocked sc config TrustedInstaller type= own depend= [WUTblocked] %.%
exit/b

:lists
echo %0 %*
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoRefresh norefresh
if "%norefresh%"=="Disable" ( set "norefresh=Enable" &set "toggle=disabled") else set "norefresh=Disable" &set "toggle=enabled"
reg add "HKLM\SOFTWARE\WUT.bat" /v NoRefresh /d "%norefresh%" /f %.%
reg add "%menu%\shell\2Lists" /v MUIVerb /d "Hide / Unhide / Apply %[T]% %toggle%" /f %.%
reg add "%menu%\shell\1Refresh" /v MUIVerb /d "Refresh" /f %.%
reg add "%menu%\shell\1Refresh\command" /ve /d "%task%\refresh" /f %.%
if "%norefresh%"=="Enable" (
 reg delete "%menu%0pending" /f %.% &reg delete "%menu%1hide" /f %.% &reg delete "%menu%2unhide" /f %.%
 reg delete "%menu%3apply" /f %.% &reg delete "%menu%\shell\1Refresh" /f %.%
)
call :refresh lists
exit/b

:upgrades
echo %0 %*
call :flip SetupHost
reg add "%menu%\shell\3Upgrades"   /v MUIVerb /d "Upgrades %[T]% [setuphost]    %toggle%" /f %.%
for %%# in (%upgrader%) do if defined block (
 reg delete "%ifeo%\%%#.exe" /f %.%
) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:installs
echo %0 %*
call :flip wuauclt
reg add "%menu%\shell\4Installs"   /v MUIVerb /d "Installs %[T]% [wuauclt]    %toggle%" /f %.%
for %%# in (%installer%) do if defined block (
 do reg delete "%ifeo%\%%#.exe" /f %.% &start "wt" wscript /e:JScript "%f0%" WUTRefresh
) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%SystemRoot%\WUTRefresh.bat" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:downloads
echo %0 %*
call :reg_query "%menu%3apply" MUIVerb pending
set "reboot=%pending:reboot=%"
if defined pending if "%pending%"=="%reboot%" set "pending="
if defined pending (
 sc config TrustedInstaller type= own depend= / %.%
 reg add "%menu%\shell\5Downloads" /v MUIVerb /d "Downloads ( ! ) %[T]% [trustedinstaller]    reboot?" /f %.%
 exit/b
)
for /f "tokens=3" %%# in ('sc qc TrustedInstaller ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="[WUTblocked]" (set "blocked=/") else set "blocked=[WUTblocked]"
net stop TrustedInstaller /y %.%
for /f "tokens=3" %%# in ('sc queryex TrustedInstaller ^| find /i "PID"') do set "pid=%#"
if not "%pid%"=="0" taskkill /pid %pid% /f %.%
sc config TrustedInstaller type= own depend= %blocked% %.%
tasklist /svc | find /i "TrustedInstaller" %.%
if errorlevel 1 net start TrustedInstaller /y %.%
if errorlevel 1 (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\5Downloads" /v MUIVerb /d "Downloads ( ! ) %[T]% [trustedinstaller]    %toggle%" /f %.%
if "%toggle%"=="enabled" start "WUT" wscript /e:JScript "%f0%" WUTRefresh
exit/b

:service
echo %0 %*
for /f "tokens=3" %%# in ('sc qc wuauserv ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="rpcss[WUTblocked]" (set "blocked=rpcss") else set "blocked=rpcss[WUTblocked]"
net stop wuauserv /y %.%
for /f "tokens=3" %%# in ('sc queryex wuauserv ^| find /i "PID"') do set "pid=%#"
if not "%pid%"=="0" taskkill /pid %pid% /f %.%
sc config wuauserv type= share depend= %blocked% %.%
tasklist /svc | find /i "wuauserv" %.%
if errorlevel 1 net start wuauserv /y %.%
if errorlevel 1 (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\6Service" /v MUIVerb /d "Service ( ! ) %[T]% [wuauserv]    %toggle%" /f %.%
if "%toggle%"=="enabled" start "WUT" wscript /e:JScript "%f0%" WUTRefresh
exit/b

:repair
echo %0 %*
:: Restore services (undo only the changes made by this script, not whatever blocking was done by other means)
sc config wuauserv type= share depend= rpcss %.%
sc config TrustedInstaller type= own depend= / %.%
:: Remove any IFEO blocking done by past scripts
set eo=DiagnosticsHub.StandardCollector.Service WindowsUpdateElevatedInstaller LocationNotificationWindows InstallAgentUserBroker
set eo=%eo% UpdateNotificationMgr DataUsageLiveTileTask Windows10UpgraderApp WindowsActionDialog SpeechModelDownload WerFaultSecure
set eo=%eo% GetCurrentRollback WindowsUpdateBox Windows10Upgrade TrustedInstaller MusNotification DiagTrackRunner CompatTelRunner
set eo=%eo% WinREBootApp64 WinREBootApp32 UNPUXLauncher SpeechRuntime MusNotifyIcon PilotshubApp InstallAgent dstokenclean wsqmcons
set eo=%eo% disksnapshot osrssupdate wuapihost WaaSMedic UsoClient UNPUXHost SIHClient setupprep SetupHost osrssinst EOSNotify wusa
set eo=%eo% WerFault TiWorker SearchUI DWTRIG20 dusmtask dmclient appidtel wuauclt wermgr DFDWiz remsh reach HxTsr DWWIN DW20 GWX
for %%# in (%eo%) do reg delete "%ifeo%\%%#.exe" /f %.%
:: Restore notification hijacking
>"%SystemRoot%\WUTRefresh.bat" echo/@start "WUTRefresh" /min wscript.exe /e:JScript "%f0%" WUTRefresh
for %%# in (MusNotification EOSNotify) do reg add "%ifeo%\%%#.exe" /v Debugger /d "%SystemRoot%\WUTRefresh.bat" /f %.%
:: Remove pending instance safeguard
reg delete "HKLM\SOFTWARE\WUT.bat" /v Pending /f %.%
:: Refresh menu
call :refresh repair
:: Open Update Diagnostic
start "wud" msdt.exe /id WindowsUpdateDiagnostic %.%
:: Open official update troubleshooter page
start https://support.microsoft.com/en-us/help/4027322/windows-update-troubleshooter %.%
exit/b

:report
echo %0 %*
call :flip wermgr
reg add "%menu%\shell\81Report"    /v MUIVerb /d "Report    %[T]% %toggle%" /f %.%
for %%# in (%reporter%) do if defined block ( reg delete "%ifeo%\%%#.exe" /f %.% ) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:speech
echo %0 %*
call :flip SpeechRuntime
reg add "%menu%\shell\82Speech"    /v MUIVerb /d "Speech    %[T]% %toggle%" /f %.%
for %%# in (%speecher%) do if defined block ( reg delete "%ifeo%\%%#.exe" /f %.% ) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:search
echo %0 %*
call :flip SearchUI
reg add "%menu%\shell\83Search"    /v MUIVerb /d "SearchUI  %[T]% %toggle%" /f %.%
for %%# in (%searcher%) do if defined block ( reg delete "%ifeo%\%%#.exe" /f %.% ) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:defender
echo %0 %*
set "s10=$t=1;$toggle='stopped'; if((Get-MpPreference).DisableRealtimeMonitoring){$t=0;$toggle='enabled';}"
set "s11=Set-MpPreference -DisableRealtimeMonitoring $t"
set "s12=Set-MpPreference -DisableBehaviorMonitoring $t"
set "s13=Set-MpPreference -DisableIOAVProtection $t"
set "s14=write-host $toggle"
for /f "delims=" %%# in ('call powershell.exe -c "%s10%;%s11%;%s12%;%s13%;%s14%;"') do set "toggle=%%#"
reg add "%menu%\shell\84Defender"  /v MUIVerb /d "Defender  %[T]% %toggle%" /f %.%
exit/b

:update_defender - triggered from WScript to get definitions from MMPC, regardless of updates being blocked
tasklist /FI "IMAGENAME eq MpCmdRun.exe" | find ".exe" %.%
if not errorlevel 1 exit/b
pushd %ProgramFiles%\Windows Defender
call MpCmdRun.exe -removedefinitions -dynamicsignatures
call MpCmdRun.exe -SignatureUpdate -MMPC
exit/b

:setup
echo %0 %*
pushd %SystemRoot%
if /i "%~f0"=="%f0%" (set "initial_setup=") else copy /y "%~f0" "%f0%" %.%
:: Create WUTUndo for emergencies
 >WUTUndo.bat echo/pushd %%~dp0system32\config
>>WUTUndo.bat echo/reg load HKLM\WUTUndo1 SOFTWARE
>>WUTUndo.bat echo/set "koff=HKLM\WUTUndo1\Microsoft\Windows NT\CurrentVersion\Image File Execution Options" ^&set "kon=%ifeo%"
>>WUTUndo.bat echo/for %%%%B in (%exe%) do for %%%%K in ("%%koff%%" "%%kon%%") do reg delete "%%%%~K\%%%%B.exe" /f 2^>nul
>>WUTUndo.bat echo/reg unload HKLM\WUTUndo1
>>WUTUndo.bat echo/reg load HKLM\WUTUndo2 SYSTEM
>>WUTUndo.bat echo/for %%%%K in (WUTUndo2 SYSTEM) do (
>>WUTUndo.bat echo/ reg delete "HKLM\%%%%~K\ControlSet001\Services\TrustedInstaller" /v DependOnService /f 2^>nul
>>WUTUndo.bat echo/ reg delete "HKLM\%%%%~K\CurrentControlSet\Services\TrustedInstaller" /v DependOnService /f 2^>nul
>>WUTUndo.bat echo/)
>>WUTUndo.bat echo/reg unload HKLM\WUTUndo2
:: Create WUTRefresh to hijack update notifications and refresh context menu in addition to preventing forced reboots
>WUTRefresh.bat echo/@start "WUTRefresh" /min wscript.exe /e:JScript "%f0%" WUTRefresh
:: Create tasks to run context menu entries with proper access and no output window
start "WUT" wscript /e:JScript "%~f0" cmd "call `%~f0` setup_schtasks"
:: WUT options
for %%# in (NoBlock NoRefresh) do reg add "HKLM\SOFTWARE\WUT.bat" /v %%# /d "Enable" /f %.%
call :toggle blocking
exit/b

:setup_schtasks - no stalling separate process
set "strun=wscript.exe /e:JScript \"%f0%\" run%window%"
for %%t in (refresh lists upgrades installs downloads service repair report speech search defender toggle renew remove) do (
 schtasks /create /ru "%username%" /sc once /tn "WUT\%%t" /tr "%strun% %%t" /st "00:00:00" /it /rl highest /f %.%
)
for %%t in (hide unhide apply) do for /l %%n in (101,1,116) do (
 schtasks /create /ru "%username%" /sc once /tn "WUT\%%t\%%n" /tr "%strun% %%t %%n" /st "00:00:00" /it /rl highest /f %.%
)
exit/b

:renew
echo %0 %*
echo Renewing from internet - old version saved as %SystemRoot%\WUT.old
pushd %SystemRoot%
if exist WUT.new del /f /q WUT.new %.%
call wscript /e:JScript "%~f0" renew "https://pastebin.com/raw/gNsLEWJe" "%SystemRoot%\WUT.new"
if exist WUT.new copy /y "%f0%" WUT.old %.% &copy /y WUT.new "%f0%" %.% &del /f /q WUT.new %.%
start "WUT" "%f0%" setup renew %.%
exit/b

:remove
echo %0 %*
for %%# in (NoBlock NoRefresh) do reg add "HKLM\SOFTWARE\WUT.bat" /v %%# /d "Disable" /f %.%
call :toggle off
reg delete "HKLM\SOFTWARE\WUT.bat" /f %.%
for %%# in ("" "0pending" "1hide" "2unhide" "3apply") do reg delete "%menu%%%~#" /f %.%
for %%t in (refresh lists upgrades installs downloads service repair report speech search defender toggle renew remove) do (
 schtasks /delete /tn "WUT\%%t" /f %.%
)
for %%t in (hide unhide apply) do for /l %%n in (101,1,116) do schtasks /delete /tn "WUT\%%t\%%n" /f %.%
for %%t in (hide unhide apply) do schtasks /delete /tn "WUT\%%t" /f %.%
schtasks /delete /tn "WUT" /f %.%
sc config wuauserv type= share depend= rpcss %.%
sc config TrustedInstaller type= own depend= / %.%
pushd %SystemRoot%
del /f /q WUT.bat WUT.old DefenderManualUpdate.bat WUTRefresh.bat WUTUndo.bat "%f0%" %.%
exit/b

:flip %1:exe
call :reg_query "%ifeo%\%~1.exe" Debugger block
if defined block (set "toggle=enabled") else set "toggle=blocked"
exit/b

:status %1:exe
call :reg_query "%ifeo%\%~1.exe" Debugger block
if defined block (set "toggle=blocked") else set "toggle=enabled"
exit/b

:reg_query %1:KeyName %2:ValueName %3:OutputVariable %4:other_options[example: "/t REG_DWORD"]
setlocal & for /f "skip=2 delims=" %%s in ('reg query "%~1" /v "%~2" /z 2^>nul') do set "rq=%%s" & call set "rv=%%rq:*)    =%%"
endlocal & set "%~3=%rv%" & exit/b &rem                                         AveYo: call :reg_query "HKCU\MyKey" "MyValue" MyVar

::---------------------------------------------------------------------------------------------------------------------------------
:JScript_functions                                                                 AveYo: Switch syntax highlighter to 'javascript'
::-------------------------------------------------------------------------------------------------------------------------------*/
f0=WSH.ScriptFullName; run=WSH.Arguments(0); args=''; for(i=1;i<WSH.Arguments.length;i++) args+=' "'+WSH.Arguments(i)+'"';
function sex(exe,args){WSH.CreateObject('Shell.Application').ShellExecute(exe,args,'','',0);}; function reg(s){ sex('reg.exe',s); }

// Open external commands in new hidden cmd instance - backquotes replaced to quotes
if (run=='cmd') sex('cmd','/c '+args.replace(/`/g,'"'));

// Context menu entries trigger - elevated with no popups
if (run=='schtasks') sex('SCHTASKS.EXE','/Run /TN '+args);

// Shift to CMD if loaded by WScript - pass arguments, prevent loop, run as admin at setup, hide window at context-menu
function cmd(adm,win){WSH.CreateObject('Shell.Application').ShellExecute('cmd','/c call "'+f0+'" shift "'+f0+'"'+args,'',adm,win);}
if (run=='run') cmd('',1); if (run=='runhide') cmd('',0); if (run=='runas') cmd('runas',1); if (run=='runashide') cmd('runas',0);

if (run=='renew') {
  // renew script over internet
  try{
  downloader=WSH.CreateObject("WinHttp.WinHttpRequest.5.1");
  if (downloader===null) downloader=WSH.CreateObject("WinHttp.WinHttpRequest");
  if (downloader===null) downloader=WSH.CreateObject("MSXML2.ServerXMLHTTP");
  if (downloader===null) downloader=WSH.CreateObject("Microsoft.XMLHTTP");
  downloader.Open("GET",WSH.Arguments(1),false); downloader.Send(); oASI=downloader.ResponseBody(); downloader=undefined;
  oASO=WSH.CreateObject("ADODB.Stream"); oASO.type=1; oASO.Mode=3; oASO.Open; oASO.Write(oASI); oASI=undefined;
  oASO.SaveToFile(WSH.Arguments(2)); oASO.Close();
  }catch(e){} // supress all errors since we're working with com objects
}

// WUT Hide/Unhide/Apply lists
if (run=='WUTRefresh' || run=='hide' || run=='unhide' || run=='apply') {
  SRP=GetObject("winmgmts:StdRegProv"); pending=SRP.GetStringValue(2147483650,'SOFTWARE\\WUT.bat','Pending');
  if (pending===0) WSH.quit(); else SRP.SetStringValue(2147483650,'SOFTWARE\\WUT.bat','Pending','yes'); // prevent instances
  k='HKCR\\DesktopBackground\\shell\\WUT'; hk=k+'1hide'; uk=k+'2unhide'; ik=k+'3apply'; pk=k+'0pending';           // set list keys
  reg('delete "'+hk+'" /f'); reg('delete "'+uk+'" /f'); reg('delete "'+ik+'" /f');                               // delete previous
  reg('add "'+pk+'" /v MUIVerb /d "Pending.." /f'); reg('add "'+pk+'" /v SubCommands /d "" /f');             // add Pending.. entry
  // Check for updates
  count=0; wuthide=[]; wutunhide=[];
  try{
  session=WSH.CreateObject("Microsoft.Update.Session"); reboot=WSH.CreateObject("Microsoft.Update.SystemInfo").RebootRequired;
  searcher=session.CreateUpdateSearcher();
  sresult=searcher.Search("IsInstalled=0"); Updatelist=sresult.Updates; count=sresult.Updates.Count;
  for(i=0;i<count;i++) {
    itemTitle=Updatelist.Item(i).Title;
    minsize=Updatelist.Item(i).MinDownloadSize; maxsize=Updatelist.Item(i).MaxDownloadSize; wutsize='';
    if (maxsize > 1073741824) wutsize=' ['+Math.round(minsize/10737418.24)/100+' - '+Math.round(maxsize/10737418.24)/100+'GB]';
    else if (maxsize > 1048576) wutsize=' ['+Math.round(minsize/10485.76)/100+' - '+Math.round(maxsize/10485.76)/100+'MB]';
    else if (maxsize > 1024) wutsize=' ['+Math.round(minsize/10.24)/100+' - '+Math.round(maxsize/10.24)/100+'KB]';
    else if (maxsize > 0) wutsize=' ['+(minsize)+' - '+(maxsize)+'B]';
    wutTitle=Updatelist.Item(i).Title + wutsize;
    if (run=='apply' && WSH.Arguments(1).indexOf(itemTitle) > -1) {
      // Add matching entry to UpdateColl
      UpdateColl=WSH.CreateObject("Microsoft.Update.UpdateColl"); UpdateColl.Add(Updatelist.Item(i));
      // Download update
      downloader=session.CreateUpdateDownloader(); downloader.Updates=UpdateColl; dresult=downloader.Download();
      if (dresult.ResultCode==2) {
        // Unblock apply
        sex('sc','config TrustedInstaller type= own depend= /');
        KeyPath='SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Image File Execution Options\\wuauclt.exe';
        SRP.DeleteKey(2147483650,KeyPath);
        WSH.Sleep(1000);
        //Apply update
        installer=session.CreateUpdateInstaller(); installer.Updates=UpdateColl; iresult=installer.Install();
        if (iresult.ResultCode==2) continue;
      }
    }
    // hide and unhide are very simple bool flip compared to apply
    if (run=='hide' && WSH.Arguments(1).indexOf(itemTitle) > -1) {
      Updatelist.Item(i).IsHidden=true; wutunhide.push(wutTitle); continue;
    }
    if (run=='unhide' && WSH.Arguments(1).indexOf(itemTitle) > -1) {
      Updatelist.Item(i).IsHidden=false; wuthide.push(wutTitle); continue;
    }
    // Trigger :update_defender to manually refresh definitions from MMPC
    if (Updatelist.Item(i).IsHidden===false && itemTitle.indexOf('(Definition') > -1) {
      sex('cmd','/c call "'+f0+'" update_defender');
    }
    // Sorting lists
    if (Updatelist.Item(i).IsHidden) wutunhide.push(wutTitle); else wuthide.push(wutTitle);
  }
  // Generate Hide context menu
  if (wuthide.length>0){
    for(i=101,n=wuthide.length+101;i<n;i++) {
      reg('add "'+hk+'\\shell\\'+i+'" /v MUIVerb /d "'+wuthide[i-101]+'" /f');
      reg('add "'+hk+'\\shell\\'+i+'\\command" /ve /d "wscript.exe /e:JScript \\"'+f0+'\\" schtasks WUT\\hide\\'+i+'" /f');
    }
    reg('add "'+hk+'" /v SubCommands /d "" /f');
    reg('add "'+hk+'" /v MUIVerb /d "Hide '+"\t"+wuthide.length+'" /f');
  }
  // Generate Unhide context menu
  if (wutunhide.length>0){
    for(i=101,n=wutunhide.length+101;i<n;i++) {
      reg('add "'+uk+'\\shell\\'+i+'" /v MUIVerb /d "'+wutunhide[i-101]+'" /f');
      reg('add "'+uk+'\\shell\\'+i+'\\command" /ve /d "wscript.exe /e:JScript \\"'+f0+'\\" schtasks WUT\\unhide\\'+i+'" /f');
    }
    reg('add "'+uk+'" /v SubCommands /d "" /f');
    reg('add "'+uk+'" /v MUIVerb /d "Unhide '+"\t"+wutunhide.length+'" /f');
  }
  // Generate Apply context menu
  if (wuthide.length>0){
    for(i=101,n=wuthide.length+101;i<n;i++) {
      reg('add "'+ik+'\\shell\\'+i+'" /v MUIVerb /d "'+wuthide[i-101]+'" /f');
      reg('add "'+ik+'\\shell\\'+i+'\\command" /ve /d "wscript.exe /e:JScript \\"'+f0+'\\" schtasks WUT\\apply\\'+i+'" /f');
    }
    reg('add "'+ik+'" /v SubCommands /d "" /f');
    reg('add "'+ik+'" /v MUIVerb /d "Apply '+"\t"+((reboot) ? 'must reboot' : wuthide.length)+'" /f');
  }
  }catch(e){} // supress all errors since we're working with com objects
  reg('delete "'+pk+'" /f'); SRP.DeleteValue(2147483650,'SOFTWARE\\WUT.bat','Pending'); // Remove Pending.. temporary entry
}
//

v10.0最終版の最終更新。上記のpastebinリンクの最新コード。

Windows 10のホームユーザー向け

Windows Centralから次の方法を試してください。基本的に、更新サービスではなく、再起動サービスを無効にします。その後、いつでも再起動できます。管理者権限が必要ですが、Windows Home Editionを使用しているため、既に持っていると思います。

1. Windowsエクスプローラーウィンドウから、ファイルの名前を変更しますC:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator\Reboot（あなたの%windir%がであると仮定C:\）、Reboot.old に変更します。 ここで、管理者アクセスを求められます。
2. 名前のディレクトリを作成Reboot中にC:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator\。これにより、ウィンドウが同じ名前のファイルを再作成できなくなります。ここで、管理者アクセスを求められます。
3. マシンを再起動します。これにより、すべてのサービスがリセットされ、再起動サービスが開始されなくなります。

これはマイクロソフトによって宣伝されていないことに注意してください。しかし、再び、どちらもあなた自身のブートスケジュールを制御していませんので、そのMSを取る！真剣に、あなたが何をしているのかわからない場合は、インターネットからの指示に従うことによってあなたが取っているリスクを理解してください。これは確かに単純で、Windows 95を理解すると、ここで何が起こっているのかを説明するのに役立ちます。

Windows Updateの状態-2019年以降

マイクロソフトは、Windows Updateを不可避にするために多大な苦労をしてきました。そのため、従来の方法はもはや機能しないか、限られた時間しか機能しません。

Microsoftは、Windowsの更新を目的とする、無効にできないシステムサービスを追加しています。これらの中で最も重要なのは、 更新のダウンロード、インストール、および検証を担当するUpdate Orchestratorサービスです。停止すると、コンピューターは更新プログラムをダウンロードおよびインストールできなくなります。そのため、現在のセッションでのみ無効にでき、次回の再起動時に再び有効になります。

Windows Updateを停止できないようにすることを担当するサービスは、Windows Updateの機能を維持することを目的とした新しい Windows Update Medic Serviceです。Windows Updateをブロックする従来の方法をすべて取り消すのはこのサービスであるため、定期的かつ予期せずに、Windows Updateの設定が元の値にリセットされ、Windowsがユーザーに更新を強制するようになっていることがわかります。

Windows Update Medic Service自体は無効にできません。これを試みると、「アクセスが拒否されました」というメッセージが表示されて終了します。

それでも、Windows Updateを完全にブロックできるサードパーティ製品が存在します： Windows Update Blockerです。この無料製品は移植性があり、ワンクリックでWindows Updateを無効/有効にできます。実際、他のブロックできないWindowsサービスもブロックできます。2018年もまだ機能していると報告されています

サードパーティ製品を使用すると、予告なしに変更される可能性のあるWindowsの半文書化された機能に頼るよりも、長期的にはより確実になる可能性があります。 私のこの答えには、さらに無料の製品がいくつか あります。これは、Windows APIを使用して、あらゆるプログラムが差し迫ったシャットダウンを拒否することを可能にします。

最後に、ちょうど永久修正見つかった作品を

本の文字通りすべてのトリックを試した後、私は常にWindows Updateに負けていました。ここですべてのソリューションに加えて、他の多くのソースを試しましたが、Windowsは常に私の計画を妨害する方法を見つけました。

約6か月前まで...

サービスまたは他の何かが実行されているかどうかに関係なく、すべてのウィンドウの更新を永久に無効にする永続的なソリューションを見つけました。私は、多くの異なることに関係している多くの異なるソースの助けを借りてこの方法を見つけました。全体的に、私はこの方法に自分自身を見出し、他の情報の断片を使用して、これにすべて関連するわけではないが、それは機能します。そして、それは絶対に美しく機能します。

1. ここからアクリルDNSプロキシをインストールします

基本的には、windows hostsファイルのスープアップバージョンであり、ワイルドカードなどの機能を追加できます。これは、windowsが更新を取得するソースが多いため、この場合に必要です。

2. こちらの指示に従って、アクリルがWin 10で仕事を始めます。

3. スタートメニューに移動し、ここに示す[すべてのプログラム]の下の[アクリルホストファイルの編集 ]をクリックします。

4. これらの行をhostsファイルの最後に追加し、前に＃記号を付けません。

0.0.0.0 windowsupdate.microsoft.com
0.0.0.0 * .windowsupdate.microsoft.com
0.0.0.0 * .update.microsoft.com
0.0.0.0 windowsupdate.com
0.0.0.0 * .windowsupdate.com
0.0.0.0 download.windowsupdate.com
0.0.0.0 download.microsoft.com
0.0.0.0 * .download.windowsupdate.com
0.0.0.0 wustat.windows.com
0.0.0.0 ntservicepack.microsoft.com
0.0.0.0 stats.microsoft.com

今、ファイルの下部には次のようになります。これ。ファイルを保存して閉じます。

5. タスクマネージャーを開き、[サービス]タブに移動して、下部の[サービスを開く]をクリックし、[ アクリルDNSプロキシ ]を選択し、赤い丸の付いたこのボタンをクリックしてサービスを再起動します。

終了しました

今、あなたのAcrylicバディはあなたの背中を持っており、Microsoftのビッグブラザーの戦術に絶えず目を光らせて、彼らが少なくとも4分の1の時間を持っているPCを完全に台無しにするアップデートをインストールすることを貧しい老人に強制することができないことを確認します自宅のPCとWindows用のPC BUILTになるはずのSurface Proの 両方でそれをしましたか？Cmon、Microsoft！

7. 上記のコードのいずれかのWebサイトにpingを実行して、機能することを確認してください。cmdを開いて入力します

ping windowsupdate.microsoft.com

これらがあなたの結果であるならば、あなたはこれから黄金になります!!

注：私の経験では、これは私のPCをまったく遅くしていません。また、Windowsが更新または更新の確認に使用するソースへのリクエスト以外のインターネットトラフィックを再ルーティングしないため、hostsファイルに非常に似ています。また、hostsファイルと基本的に同じ形式を使用します。これにより、Windowsが私のコンピューターに配置し続ける「迷惑メールの再インストール」が正常に無効になり、巨大な色付きの画面に「更新する必要があります。（6か月ほど前にブロックが完全に成功したために）長い間、警告が何を言ったか覚えていませんが、これは私が今まで見た中で最も厄介なものでした。

更新サービスを無効にする

1. Win+R > services.msc
2. [Windows Update]をダブルクリックし、[スタートアップの種類]を[無効]に変更します。再度有効にするには、サービスに戻って自動に変更します。

ソース：Windows 10の更新を制御する方法

私の場合、Windows Updateの実行を制御するだけでなく、インストールされているすべてのアプリケーションをオンライン更新で制御できないように制限したいと考えています。

したがって、私の簡単なワンストップソリューションは次のとおりです。1.ルーター側のホストのインターネットアクセスをブロックします。ホストにインストールされているプログラムやサービスはどれもインターネットにアクセスできません。原因のWindows Updateもブロックされます。

2. ローカルネットワークにSquidプロキシサーバーをインストールし、インターネットへの接続を許可するアプリケーションにプロキシを提供します。コントロールパネルでプロキシを設定しないでください| インターネットオプション、原因は、手順1をまったく無効にするグローバルOSワイドプロキシです。

ほとんどのアプリケーションは、Chrome、Firefox、あらゆる種類のゲームなど、アプリケーションごとのプロキシ設定をサポートしています。

3. ローカルプロキシ設定をサポートしないアプリケーションの場合、NASクラウドフォールドをクラウドプロキシとして使用します。たとえば、Office 365スーツはプログラムごとのプロキシをサポートしていません。次に、NASクラウド同期をセットアップして（たとえば、Synology NASはOneDriveを同期するクラウド同期）、NASフォールド内のコンテンツを同期し、そのフォールドをOffice 365のローカルフォールドとして使用できます。この方法の追加の利点は、大きなファイルに対して非常に高速な応答が得られることです。これにより、ローカルネットワークの速度を使用してOneDriveにアクセスできます。

これらを実行することにより、コンピューターのインターネットアクセスが自分で大幅に制御され、誰もあなたを台無しにできません。

Windowsを更新する場合は、[コントロールパネル]を設定します| ローカルプロキシを使用するためのインターネットオプション。したがって、WindowsはOSを更新できます。その後、すぐにグローバルプロキシをオフにして、コンピュータを平和な状態に戻します。

2年後、Microsoftの更新メカニズムによって保存されていない何十億もの作品が失われ、ついに問題を解決するメジャーアップデートがあります。

Windows 10 Creators Updateが利用可能になりました（直接ダウンロード）

更新プログラムをインストールした後、ユーザーは最終的に（20年以上前の重要でないユーザーのように）更新プログラムを適用するかどうかを尋ねます。

時々、誰がそれらの決定の背後にいるのだろうか...

更新後、更新時間に関するオプションが増えます。それらを停止するには、[Windows Update設定]> [詳細オプション]> [更新の一時停止]> [オン]に移動します。

[再起動オプション]には、更新通知の新しいオプションもあります。

PowerShellによるすべてのWindows更新を無効にする

（管理者としてPowerShellを実行）

Clear-Host

$WindowsUpdatePath = "HKLM:SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\"
$AutoUpdatePath = "HKLM:SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU"

If(Test-Path -Path $WindowsUpdatePath) {
    Remove-Item -Path $WindowsUpdatePath -Recurse
}

New-Item $WindowsUpdatePath -Force
New-Item $AutoUpdatePath -Force

Set-ItemProperty -Path $AutoUpdatePath -Name NoAutoUpdate -Value 1

Get-ScheduledTask -TaskPath "\Microsoft\Windows\WindowsUpdate\" | Disable-ScheduledTask

takeown /F C:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator /A /R
icacls C:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator /grant Administrators:F /T

Get-ScheduledTask -TaskPath "\Microsoft\Windows\UpdateOrchestrator\" | Disable-ScheduledTask

Stop-Service wuauserv
Set-Service wuauserv -StartupType Disabled

Write-Output "All Windows Updates were disabled"

サービスとグループポリシーエディターで更新を無効にしたが、それでも時々オンになります。次に、サービスでそれらを手動でオフにする必要があります。GUI経由でこれを行うのは面倒なので、バッチスクリプトを作成しました。停止し、無効にBackground Intelligent Transfer ServiceしWindows Updateます。

@echo off

net stop wuauserv
net stop BITS

sc config wuauserv start= disabled
sc config BITS start= disabled

pause

私は（特にこの目的ではなく）ライトネットワークモニターツール（帯域幅モニター）も使用しているので、アクティビティ（システムトレイのアイコン）がいつあるかがわかります。アクティビティがないはずのときにアクティビティが表示された場合、Windows Updateが再び有効になっていることがわかります。次に、スクリプトを実行すると、オフになります。