HTMLメールの署名が常に表示されない

HTMLメールの署名があります。時々平文で返信するため、常に表示されませんでした。したがって、私の返信もプレーンテキストです。

それで、私はすべてのメールをHTMLで送信するマクロをインターネット上で見つけました。どうやらこれを行うべきではないようですが、すべての新しいメールをHTMLで送信するので、なぜそうなのかわかりません。

ただし、現在はプレーンテキストではなくHTMLですが、常にTimes New Romanであり、署名にはロゴが表示されず、テキストのみが表示され、フォーマットはされません。誰もがこの問題を解決する方法を知っていますか？

前もって感謝します

最終的にこの記事を使用してマクロを更新しました。

http://www.howto-outlook.com/howto/replyinhtml.htm

Sub ForceReplyInHTML()

    '=================================================================
    'Description: Outlook macro to reply to a message in HTML
    '             regardless of the current message format.
    '             The reply will use your HTML signature as well.
    '
    'author : Robert Sparnaaij
    'version: 1.0
    'website: http://www.howto-outlook.com/howto/replyinhtml.htm
    '=================================================================

        Dim objOL As Outlook.Application
        Dim objSelection As Outlook.Selection
        Dim objItem As Object
        Set objOL = Outlook.Application

        'Get the selected item
        Select Case TypeName(objOL.ActiveWindow)
            Case "Explorer"
                Set objSelection = objOL.ActiveExplorer.Selection
                If objSelection.Count > 0 Then
                    Set objItem = objSelection.Item(1)
                Else
                    Result = MsgBox("No item selected. " & _
                                "Please make a selection first.", _
                                vbCritical, "Reply in HTML")
                    Exit Sub
                End If

            Case "Inspector"
                Set objItem = objOL.ActiveInspector.CurrentItem

            Case Else
                Result = MsgBox("Unsupported Window type." & _
                            vbNewLine & "Please make a selection" & _
                            " or open an item first.", _
                            vbCritical, "Reply in HTML")
                Exit Sub
        End Select

        Dim olMsg As Outlook.MailItem
        Dim olMsgReply As Outlook.MailItem
        Dim IsPlainText As Boolean

        'Change the message format and reply
        If objItem.Class = olMail Then
            Set olMsg = objItem
            If olMsg.BodyFormat = olFormatPlain Then
                IsPlainText = True
            End If
            olMsg.BodyFormat = olFormatHTML
            Set olMsgReply = olMsg.Reply
            If IsPlainText = True Then
                olMsg.BodyFormat = olFormatPlain
            End If
            olMsg.Close (olSave)
            olMsgReply.Display

        'Selected item isn't a mail item
        Else
            Result = MsgBox("No message item selected. " & _
                        "Please make a selection first.", _
                        vbCritical, "Reply in HTML")
            Exit Sub
        End If

        'Cleanup
        Set objOL = Nothing
        Set objItem = Nothing
        Set objSelection = Nothing
        Set olMsg = Nothing
        Set olMsgReply = Nothing

    End Sub

マクロを3回再作成しました。1つは転送用、もう1つは返信用、もう1つは全返信用Sub ForceReplyInHTMLです。上部の名前を変更して、3つの異なるマクロを作成しました。

また、そのリンクの関連記事を使用して、自分でボタンを作成し、マクロに署名しました。最終段階では、[変更]ボタンを使用してマクロのアイコンを変更し、どのマクロがどのマクロを実行したかを簡単に思い出せるようにしました。