参照セルが更新されたときにExcel 2007の新しい隣接セル値を更新

参照セル値が更新されるたびに、新しい隣接セルにセル値をコピーまたは更新する必要があります。

CellにA1は数式があり、値を頻繁に更新します。私がする必要があるのは、値A1が更新されるたびに、その値を新しい隣接セルにコピーする必要があることです。

場合A1で20、その後B1でなければなりません20。

場合は、再度A1IDが新しい値に更新され23、その後B1でなければなりません20が、C1はする必要があります23ように、。

update 1: A1=20  B1=20
update 2: A1=23  B1=20   C1=23
update 3: A1=25  B1=20   C1=23  D1=25

この小さなイベントマクロは、最初の行の最後に最新のA1値を配置します。

Private Sub Worksheet_Calculate()
    Dim v As Variant, N As Long

    v = Range("A1").Value
    Application.EnableEvents = False
    If Range("B1").Value = "" Then
        Range("B1").Value = v
        Application.EnableEvents = True
        Exit Sub
    End If

    N = Cells(1, Columns.Count).End(xlToLeft).Column
    If Cells(1, N).Value = v Then
        Application.EnableEvents = True
        Exit Sub
    End If

    Cells(1, N + 1).Value = v
    Application.EnableEvents = True
End Sub

ワークシートコードであるため、インストールが非常に簡単で、自動的に使用できます。

1. Excelウィンドウの下部にあるタブ名を右クリックします
2. [コードの表示]を選択-VBEウィンドウが表示されます
3. ものを貼り付けて、VBEウィンドウを閉じます

懸念がある場合は、まず試用ワークシートで試してください。

ブックを保存すると、マクロも一緒に保存されます。2003年以降のバージョンのExcelを使用している場合、.xlsxではなく.xlsmとしてファイルを保存する必要があります。

マクロを削除するには：

1. 上記のようにVBEウィンドウを表示します
2. コードをクリアする
3. VBEウィンドウを閉じます

一般的なマクロの詳細については、以下を参照してください。

http://www.mvps.org/dmcritchie/excel/getstarted.htm

そして

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

イベントマクロ（ワークシートコード）の詳細については、以下を参照してください。

http://www.mvps.org/dmcritchie/excel/event.htm

これを機能させるには、マクロを有効にする必要があります！