Excelでシートを切り替えるキーボードショートカット

Excel 2007には、ワークシートを切り替えるキーボードショートカットがありますか？

Ctrl+ PgUpを押して左に移動します。

Ctrl+ PgDnを右に移動します。

最初または最後のシートをアクティブにするVBAマクロとカスタムキーボードショートカット

実際のキーボードショートカットを最初または最後のワークシートにジャンプする場合は、次のコードを「個人用」ワークブックのモジュールに配置します。

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

[開発]タブ> [マクロ]に移動します。これらのマクロ（ToFirstSheetおよびToLastSheet）を参照します。いずれかを選択し、[オプション]をクリックして、キーボードショートカットを割り当てます。他にも同じことを行います。

これを「個人用」ワークブックに保存すると、Excelファイルで使用できるようになります。

前または次のシートをアクティブにするためのキーボードショートカットを内蔵

1つのワークシートを左または右にジャンプするには、次のデフォルトのキーボードショートカットを使用できます。

Ctrl+PgUp

Ctrl+PgDn

前または次のシートをアクティブにするVBAマクロ

VBAを使用して同じことを実現する方法は次のとおりです。

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

前または次のシートを返すVBA関数

前または次のワークシートオブジェクトを取得する場合は、この関数を使用します。

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

次のような関数を使用します。

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

アクセラレータキーを使用して、Goダイアログボックスを表示することもできます。次にfoo!A1、「foo」という名前のシートの左上のセルに移動するように入力します。一般に、ページアップとページダウンの方が高速です。適切な名前のシートが多数（たとえば20個以上）ある場合は、これが速くなる場合があります。シートに名前付きテーブルがある場合、Goもうまく機能します。

F5を押すと、通常、Goダイアログボックスが開きます。