Windows 7でVimdiff（7.4）を実行できません

最近、Windows 7マシンにgVimの7.4バージョンをインストールしました。Windowsエクスプローラーの状況依存メニューから2つのファイルを比較しようとすると、エラーメッセージが表示され続けます。

E810：一時ファイルの読み取りまたは書き込みが
できませんE97：差分を作成できません

選択した2つのファイルは2ペインのgVimビューで開かれ、エディターはdiffモードになっているようですが、実際の違いは強調表示されていません。

%TEMP%そして%TMP%環境変数が有効なディレクトリ名が移入されています。

通常のgVimセッションでファイルを開い:diffthisてコマンドプロンプトに入力するときに、同じ応答が返されます。

これはVim 7.3で正常に機能していましたが、v7.4で何かが変更されたように見えました。

2つのファイルを比較するにはどうすればよいですか？

この問題は、Windowsのインストーラーによって作成されたデフォルトの_vimrcファイルが原因で発生する可能性があります。まだそのデフォルトファイルを使用している場合、またはある時点でコピーした場合は、割り当てた機能をチェックしますdiffexprオプションに。Vim 7.3と7.4の間のパッチの1つは、Windowsのcmd.exeシェルに新しいデフォルトの引用ルールを導入しました。このパッチは、パッチによって解決された同じ問題を修正するために設計されたMyDiff（）関数の回避策を破りました。

MyDiff（）関数は、インストーラーを修正することにより、バージョン7.4.103で修正されました。以下は、_vimrcにコピーするだけの場合に最新のインストーラーが作成するMyDiff（）関数です。

 function MyDiff()
   let opt = '-a --binary '
   if &diffopt =~ 'icase' | let opt = opt . '-i ' | endif
   if &diffopt =~ 'iwhite' | let opt = opt . '-b ' | endif
   let arg1 = v:fname_in
   if arg1 =~ ' ' | let arg1 = '"' . arg1 . '"' | endif
   let arg2 = v:fname_new
   if arg2 =~ ' ' | let arg2 = '"' . arg2 . '"' | endif
   let arg3 = v:fname_out
   if arg3 =~ ' ' | let arg3 = '"' . arg3 . '"' | endif
   if $VIMRUNTIME =~ ' '
     if &sh =~ '\<cmd'
       if empty(&shellxquote)
         let l:shxq_sav = ''
         set shellxquote&
       endif
       let cmd = '"' . $VIMRUNTIME . '\diff"'
     else
       let cmd = substitute($VIMRUNTIME, ' ', '" ', '') . '\diff"'
     endif
   else
     let cmd = $VIMRUNTIME . '\diff'
   endif
   silent execute '!' . cmd . ' ' . opt . arg1 . ' ' . arg2 . ' > ' . arg3
   if exists('l:shxq_sav')
     let &shellxquote=l:shxq_sav
   endif
 endfunction

Vimでフルバージョンを表示するには、:versionまたは:introコマンドを使用するか、起動時のスプラッシュスクリーンで確認できます。

残念ながら、公式インストーラーが必要な場合は、8.0まで待つか、ナイトリービルドをインストールする必要があります。それにもかかわらず、あなたができる他の場所からVimをインストールしたり、独自のVimを構築します。

スタックオーバーフローで重複（通常、両方のサイトでトピック）、この回答が更新された場合、他のサイトも更新されます。