Outlook2010では、現在スヌーズしているリマインダーを表示する方法はありますか？

Outlook 2010で現在スヌーズされているアイテムのリストを取得する方法はありますか？たとえば、次の月曜日の重要な昼食会のために金曜日にポップアップするようにリマインダーを設定した2週間としましょう（週末の前に月曜日のタスクを思い出したいです）。金曜日にリマインダーが表示されたら、3日間スヌーズし、月曜日の昼食直前に再び表示されるようにします。それから月曜日が動き回り、私の記憶は曖昧になり、私は金曜日にリマインダーを正しくスヌーズするのではなく、誤ってリマインダーを却下したことを少し妄想しています。カレンダーに元の予定を表示することはできますが、会議を見逃さないように、予定どおりにリマインダがポップアップするようにする必要があります。

Outlook 2010で、現在スヌーズされているアラームのリストを取得する方法はありますか？これは、後でリマインダーをスヌーズしたタスクを完了し、スヌーズしたリマインダーを引き上げてキャンセルしたい場合にも役立ちます。

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

VBAに慣れていない場合は、Slipstickの説明ページを参照してください。以下に関する情報があります。

• マクロセキュリティ設定。
• コードを配置する場所（通常のモジュールはInsert | Moduleで使用できます）; そして
• ボタンの作成方法。

このスヌーズアイテムの表示フォーラムの投稿によると、スヌーズアイテムのリストを表示することはできません。投稿では、リマインダーフィールドの一部を表示するカスタムビューを作成することにより、限られた量の有用な情報を表示できる可能性があることが示唆されています。

[カレンダー]タブをクリックして、[表示と表示の変更]を選択します。次にリストを選択します。これにより、すべてのリマインダーのリストが表示されます。