スクリプトを使用してFirefoxを構成するにはどうすればよいですか？

スクリプト（VBSまたはバッチ）を使用して次のFirefox設定を構成しようとしています

• デフォルトのホームページ
• デフォルトの検索エンジン
• 自動更新を無効にする

これは可能ですか？

これを行うには、Mozilla設定ファイルを好みのスクリプト言語で作成または操作します。

これらのファイルを介して設定できる設定のリストについては、Mozillaの設定とabout：configのドキュメントを参照してください。ただし、リストに対応する設定は次のようです。

• browser.startup.homepage （デフォルトのホームページ）
• browser.search.defaultenginename （デフォルトの検索エンジン）
• app.update.auto （自動更新を有効/無効にする）

ただし、環境によっては、カスタムアドオン（Mozilla設定の概要ガイドの XPIコメントを参照）またはFirefoxADMまたは同様のGPOを使用して設定をプッシュした方がよい場合があります。

ユーザープロファイルフォルダーのファイルuser.jsでプライベートブラウザーオプションを上書きできます。パイプラインなどの一部のオプションをオーバーライドするためによく使用します。user.jsを更新した後、Firefoxを再起動する必要があります。ファイルuser.jsが存在しない場合は、作成する必要があります。

私が探していた答えの一部を文字通りコピー/貼り付けする（win env。）

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

追加

user_pref("browser.startup.homepage", "http://www.URL");

Get-Content / cat string.txt / "String" >>パスを使用してリモートマシンにコピーしようとしprefs.jsましたが、文字列のエスケープ文字が原因でゴミがファイルに挿入されて終了しました。

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

スレッドは少し古いですが、とにかく私の解決策を共有したいと思います。これが誰かを助けることを願っています。同様の問題があり、WindowsストアからFirefoxに証明書を追加したいと考えていました。そのため、そのためのスクリプトを作成しました。とにかく、あなたはそれをあなたのニーズに変更することができます::: create cfg_file_name.cfg [...]で行を追加または削除して、たとえばスタートホームページなどに必要なものを挿入してください。最後の）の前に^を設定することを忘れないでください。そうしないと機能しません。 echo pref("browser.startup.homepage", "http://superuser.com"^);

バージョン49以降、次のように実行できます。

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit