OS Xで特定のアプリを表示/非表示にするグローバルホットキー？[重複]

重複の可能性：
キーボードショートカットでOS Xアプリを起動する

OS Xで特定のアプリを表示/非表示にするグローバルホットキーを定義することは可能ですか？

たとえば、Cmd+を使用してSafariを表示/非表示にしたいとしますSpace。

Automatorを開き、サービスの作成を選択し、どのアプリケーションでも入力を受け取らないように構成します。

ライブラリで、[ ユーティリティ ] » [ AppleScriptを実行 ]をダブルクリックし、大きなテキスト領域に次のように入力します。

on run {input, parameters}

    tell application "System Events"
        set names to name of application processes
        if names contains "Safari" then
            tell application process "Safari"
                if visible then
                    set visible to false
                else
                    # use the following to simply have it reappear:
                    set visible to true
                    # use the following to focus Safari:
                    tell application "Safari" to activate
                end if
            end tell
        else
            display dialog "Safari is not running"
        end if
    end tell

    return input
end run

任意の名前で保存します。システム環境設定»キーボード»キーボードショートカット»サービスでキーボードショートカットを割り当てます。Spotlightショートカットを無効にしてくださいCmd-Space。

AppleScriptエディターで保存し、OS Xでスクリプトを実行するためのショートカットを割り当てる

tell application (path to frontmost application as text)
    if name is "TextEdit" then
        set bid to id
        tell application "System Events" to tell (process 1 where bundle identifier is bid)
            set visible to false
        end tell
    else
        tell application "TextEdit"
            reopen
            activate
        end tell
    end if
end tell

• ターゲットアプリケーションが現在最前面にある場合は、非表示にします
• それ以外の場合はそれをアクティブにします

CMD + Wはウィンドウを非表示にします。これはグローバルに機能します。ただし、それらに戻るには、ドックアイコンをクリックする必要があります。ただし、ブラウザではタブが閉じます。