Vim：タブラインにタブのインデックスを表示します

私が開いたとしましょうfile1.txt、file2.txt、file3a.txtとfile3b.txtなるようにtabline（一番上のもの）のようになります。

file1.txt  file2.txt  2 file3a.txt

（file3b.txt.と同じタブに分割で表示されるため、欠落していることに注意してくださいfile3a.txt）

タブ間を（を使用して<Number>gt）よりすばやく移動するには、各タブにファイル名に沿ってインデックスを表示します。そのようです：

1:<file1.txt>  2:<file2.txt>  3:<2 file3a.txt>

フォーマット（特に山括弧）はオプションです。私は、インデックスが（そこに表示する1:、2:など）。

手掛かり:h tab-page-commandsやグーグルは一切ありません。

あなたは見る必要があります：

:help 'tabline'
:help setting-tabline

そして 'guioptions'設定に "e"がある場合：

:help 'guitablabel'

これをvimrcに入れます

" Rename tabs to show tab number.
" (Based on http://stackoverflow.com/questions/5927952/whats-implementation-of-vims-default-tabline-function)
if exists("+showtabline")
    function! MyTabLine()
        let s = ''
        let wn = ''
        let t = tabpagenr()
        let i = 1
        while i <= tabpagenr('$')
            let buflist = tabpagebuflist(i)
            let winnr = tabpagewinnr(i)
            let s .= '%' . i . 'T'
            let s .= (i == t ? '%1*' : '%2*')
            let s .= ' '
            let wn = tabpagewinnr(i,'$')

            let s .= '%#TabNum#'
            let s .= i
            " let s .= '%*'
            let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
            let bufnr = buflist[winnr - 1]
            let file = bufname(bufnr)
            let buftype = getbufvar(bufnr, 'buftype')
            if buftype == 'nofile'
                if file =~ '\/.'
                    let file = substitute(file, '.*\/\ze.', '', '')
                endif
            else
                let file = fnamemodify(file, ':p:t')
            endif
            if file == ''
                let file = '[No Name]'
            endif
            let s .= ' ' . file . ' '
            let i = i + 1
        endwhile
        let s .= '%T%#TabLineFill#%='
        let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
        return s
    endfunction
    set stal=2
    set tabline=%!MyTabLine()
    set showtabline=1
    highlight link TabNum Special
endif

上のウィキアのページに、あなたはあなたのタブインデックスを与える少なくとも2つ（私がテストしたもの）を見つけることができ、そのうちの一つは、編集内容を持っている各バッファ内のウィンドウの数を生成します。

これは、編集したバッファーの数を生成する変更の結果です。変更したのは、カウントのハイライト値をタブの他の部分と一致させるためです。

set tabline=%!MyTabLine()  " custom tab pages line
function MyTabLine()
        let s = '' " complete tabline goes here
        " loop through each tab page
        for t in range(tabpagenr('$'))
                " set highlight
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " set the tab page number (for mouse clicks)
                let s .= '%' . (t + 1) . 'T'
                let s .= ' '
                " set page number string
                let s .= t + 1 . ' '
                " get buffer names and statuses
                let n = ''      "temp string for buffer names while we loop and check buftype
                let m = 0       " &modified counter
                let bc = len(tabpagebuflist(t + 1))     "counter to avoid last ' '
                " loop through each buffer in a tab
                for b in tabpagebuflist(t + 1)
                        " buffer types: quickfix gets a [Q], help gets [H]{base fname}
                        " others get 1dir/2dir/3dir/fname shortened to 1/2/3/fname
                        if getbufvar( b, "&buftype" ) == 'help'
                                let n .= '[H]' . fnamemodify( bufname(b), ':t:s/.txt$//' )
                        elseif getbufvar( b, "&buftype" ) == 'quickfix'
                                let n .= '[Q]'
                        else
                                let n .= pathshorten(bufname(b))
                        endif
                        " check and ++ tab's &modified count
                        if getbufvar( b, "&modified" )
                                let m += 1
                        endif
                        " no final ' ' added...formatting looks better done later
                        if bc > 1
                                let n .= ' '
                        endif
                        let bc -= 1
                endfor
                " add modified label [n+] where n pages in tab are modified
                if m > 0
                        let s .= '[' . m . '+]'
                endif
                " select the highlighting for the buffer names
                " my default highlighting only underlines the active tab
                " buffer names.
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " add buffer names
                if n == ''
                        let s.= '[New]'
                else
                        let s .= n
                endif
                " switch to no underlining and add final space to buffer list
                let s .= ' '
        endfor
        " after the last tab fill with TabLineFill and reset tab page nr
        let s .= '%#TabLineFill#%T'
        " right-align the label to close the current tab page
        if tabpagenr('$') > 1
                let s .= '%=%#TabLineFill#%999Xclose'
        endif
        return s
endfunction

tablineプラグインは、実装が機能を要求し、あなたのvimrcを吹き消すしないことvimのプラグインです。単にインストールし、vimを再起動します。

インストールするには：

cd /usr/share/vim/vimfiles/plugin/
wget https://raw.githubusercontent.com/mkitt/tabline.vim/master/plugin/tabline.vim

またはプラグインマネージャーを使用します。

GUIベースのVim（LinuxではGvim、MacではMacVimなど）の場合は、次の場所に配置します.gvimrc。

set guitablabel=%N:%M%t " Show tab numbers

表示された数値を実際に使用するためのヒント：

• Ngtタブに切り替わりますN。たとえば、3gtタブ3 に移動します。
• :tabm2現在のタブをタブ2の後に表示するように移動します。
  • このタブを最初の位置に移動するには、次を使用します :tabm0
  • このタブを最後の位置に移動するには、次を使用します :tabm