Windows 7で左/右だけでなく、上/下を「スナップ」できますか？

Windows 7では、Windows+ Leftを実行して、画面の左半分にウィンドウを配置できることを知っています。トップとボトムを行う機能はありますか？

いいえ。使用できるスナップオプションは次のとおりです。

• 左半分のスナップ（Windows+ left）
• 右半分のスナップ（Windows+ right）
• 全画面高さのスナップ（Windows+ shift+ up）
• 最大化スナップ（Windows+ up）
• 「スナップ解除」（Windows+ down）
• 次のモニター/ディスプレイにスナップ（Windows+ shift+（leftまたはright））

編集：あなたが好きかもしれない他の素晴らしい組み合わせ：

• すべて最小化（Windows+ m）
• アクティブウィンドウ以外のすべてを最小化（Windows+ Home）
• Aeroピーク（デスクトップを表示、すべてのWindowsが透明になる）（Windows+ space）

これを実現するには、次の手順を使用します。

1. Windows+ D（すべてのウィンドウを最小化するため）
2. 次に、マウスを使用して、スタックしたいウィンドウを各モニターの一般的な配置に配置します（サイズ変更を気にしないでください）
3. 次に、タスクバーを右クリックして、コンテキストメニューから[ウィンドウを重ねて表示]を選択し、必要な他のウィンドウを復元します。

注：積み重ねたくないウィンドウは最小化する必要があります。これが、ステップ1の目的です。

私もこれにイライラしていたので、ウィンドウを上下にスナップするための小さなAutoHotKeyスクリプトを書きました。あなたは私のウェブサイトからダウンロードできます：http : //www.pixelchef.net/how-snap-windows-horizo​​ntally-windows-7

; Move window up (Windows + Shift + UP ... NOTE must maximize window first)
+#Up::
  WinGetPos,X,Y,W,H,A,,,
  WinMaximize
  WinGetPos,TX,TY,TW,TH,ahk_class Shell_TrayWnd,,,

  ; if this is greater than 1, we're on the secondary (right) monitor. This
  ;   means the center of the active window is a positive X coordinate
  if ( X + W/2 > 0 ) {
  SysGet, MonitorWorkArea, MonitorWorkArea, 1
  WinMove,A,,X,0 , , (MonitorWorkAreaBottom/2)
  }
  else {
  SysGet, MonitorWorkArea, MonitorWorkArea, 2
  WinMove,A,,X,0 , , (MonitorWorkAreaBottom/2)
  }
return

; Move window down (Windows + Shift + DOWN ... NOTE must maximize window first)
+#Down::
  WinGetPos,X,Y,W,H,A,,,
  WinMaximize
  WinGetPos,TX,TY,TW,TH,ahk_class Shell_TrayWnd,,,

  ; if this is greater than 1, we're on the secondary (right) monitor. This
  ;   means the center of the active window is a positive X coordinate
  if ( X + W/2 > 0 ) {
  SysGet, MonitorWorkArea, MonitorWorkArea, 1
  WinMove,A,,X,MonitorWorkAreaBottom/2 , , (MonitorWorkAreaBottom/2)
  }
  else {
  SysGet, MonitorWorkArea, MonitorWorkArea, 2
  WinMove,A,,X,MonitorWorkAreaBottom/2 , , (MonitorWorkAreaBottom/2)
  }
return

WindowSpaceはこの機能を提供します。あなたが求めていることをするには：

• [移動とサイズ変更]タブに移動します Settings
• 「上端」：「上端に移動」を選択します
• 「下端」：「下側に移動」を選択します

スクリーンショット：

現在、私の目の前にwindows 7マシンはありませんが、Windows 95以来（または場合によってはそれ以前）、ウィンドウを水平に並べるオプションがありました。上下に表示する2つのウィンドウを除くすべてを最小化し、タスクバーを右クリックして、[ウィンドウを水平に並べて表示]を選択します。垂直画面領域の半分を占めるように各ウィンドウのサイズを調整します。これは、単一のウィンドウに対して行うのには役に立たず、別の回答にあるように、キーボードショートカットはありませんが、時々便利です。

修正：Windows 7では、これは「ウィンドウを積み重ねて表示」と呼ばれます。

northbenと同様に、私はAutoHotKeyスクリプトも作成しましたが、少し異なりますが、独自の答えに値すると思いました。このスクリプトは、任意の数のモニターまたはモニターの向きで動作するはずです。

コマンドは、既存の+ + に干渉しないように、代わりにWindows+ Ctrl+にバインドされます。UpDownShiftWindowsShiftUp

これは、ウィンドウが水平位置と幅を保持するという点で、全画面高さのスナップ（Windows+ Shift+ Up）と同様に機能します。これは、行のコメントを外すことで、左半分または右半分のスナップ（Windows+ LeftまたはRight）と同様に機能するように簡単に変更できます; WinMaximize, A。デフォルトの動作を維持したいが、場合によってはハーフスナップ動作を使用する場合は、スナップする前にウィンドウを最大化します。

Windows 7 64ビットおよびAutoHotKey v1.1.14.03で動作します。

;-------------------------------------------------------------------;
; Returns the maximum or minimum value for any number of inputs
; i.e. Max(5,4,7,10) will return 10
;-------------------------------------------------------------------;
Min(params*)
{
  r := params[1]
  for index, param in params
    if (param < r)
      r := param
  return r
}
Max(params*)
{
  r := params[1]
  for index, param in params
    if (param > r)
      r := param
  return r
}

;-------------------------------------------------------------------;
; WindowsKey+Ctrl+Up / WindowsKey+Ctrl+Down
; Resizes window to half the screen height and moves it to the top
; or bottom of whichever screen has the largest overlap.
; By default, the window retains its horizontal (x) position and
; width.  To change this, uncomment the WinMaximize line.
;-------------------------------------------------------------------;
UpDownSnap(Direction)
{
  ; WinMaximize, A
  WinGetPos, x, y, w, h, a, , ,
  SysGet , Count, MonitorCount
  refArea := 0
  Loop, %count%
  {
    SysGet, m, MonitorWorkArea, %A_Index%
    xo := Max(0, Min(x + w, mRight) - Max(x, mLeft))
    yo := Max(0, Min(y + h, mBottom) - Max(y, mTop))
    area := xo * yo
    if (area > refArea)
    {
      monTop := mTop
      monBottom := mBottom
      refArea := area
    }
  }

  ; If the refArea is still equal to 0, the window does
  ; not overlap with any monitors. Wat?
  if (refArea > 0)
  {
    if (direction = 1)
      newY := monTop
    Else
      newY := (monBottom - monTop) / 2 + monTop
    WinMove , a, , x, newY, w, (monBottom - monTop) / 2
  }
}
^#Up::UpDownSnap(1)
^#Down::UpDownSnap(0)

まさにこれ以上を達成した、私が今まで使用した中で最高のプログラムは、WinSplit Revolutionです：http ://winsplit-revolution.com/

非常に使いやすく、複数のモニターでもうまく機能するので、私はそれを強くお勧めします。

デモビデオ：http : //winsplit-revolution.com/screenshots/videos-demos

このアプリケーションはフリーウェアであり、Creative Commons Attribution-Non Commercial-No Derivative Works 3.0の下でリリースされています。

編集：

ウェブサイトがこの種のソフトウェアの独自のバージョンを持っているデジタルクリエーションAS、によって引き継がれてきた、WinSplitが使用できなくなった表示されない、とされ、もはや無料

希望どおりにウィンドウを配置します->タスクバーを右クリックします-> "ウィンドウを積み重ねて表示します"->利益！

Rainがここで提案したように、PowerResizerはうまく機能します。あまりカスタマイズできない-キーボードショートカットを変更することはできませんが、少なくともオープンソースです。JoeBが指摘しているように、ウィンドウをドラッグするときにこれらを押すことができます。Wは上に移動し、Zは下に移動します。Aは左に移動し、Sは右に移動します。または、ウィンドウを端までドラッグします。ドラッグ中に1、2、3、4を押すと、コーナーに1/4スナップします。私はそれで満足です、試してみてください。

AMDグラフィックカードをお持ちの場合は、「Hydravision」を使用できます。

（1）Catalyst Control Centerを開きます（2）「デスクトップとディスプレイ」の下で「その他...」をクリックします（3）「Hydravision」の下で「HydraGrid」をクリックします（4）「Enable HydraGrid」をチェックします（5）「Edit HydraGridそして、例えば、縦長のモニターの半分上にグリッド線を配置します（6）適用

これで、ウィンドウを操作しているときに、タイトルバーを右クリックして[グリッドにアタッチ]を選択し、場所から場所へドラッグすると、グリッドにスナップします。

このセットアップでは、ポートレートモードで3x1 24インチモニターを実行します。これは、各モニターの上半分と下半分にウィンドウをスナップするのに最も簡単な方法です。

AquaSnapをご覧ください。期待どおりにマウスをドラッグし、Ctrl +マウスを使用して、他の多くの機能に加えて、2つのタイルウィンドウを同時にサイズ変更できます。

さまざまなホットキーを使用することもできます。このプログラムは、ドックのWin + UpおよびWin + Downをtop / bottomに変更することに加えて、すでに使用しているいくつかのWindowsのデフォルトをオーバーライドします。

WindowSpaceは機能しますが、あまり良いものではなく、applyを押すとしばらくハングアップすることがあります。同様に、Aquasnap Proの無料/試用版は非常にスムーズな体験です。

Windowsには、スタック、サイドバイサイド、カスケードなど、多くのオプションがあります。これらは、タスクバー（通常は画面の下部）の空の領域を右クリックして選択することで実行されます。ええ、それはキーボードのショートカットではありませんが、かなり近いです。

私を信用してはいけません。馬の口から直接入手してください。

また、このWebサイトには他にもたくさんの素敵な情報があります。ご存知のように、いくつかは新しいものかもしれません。お役に立てれば。

この機能を実現するサードパーティフリーの方法がありますが、知る限り：

• マウスを使用する必要があります
• 2つのウィンドウでのみ機能します。

レシピは次のとおりです。

1. 通常の方法でウィンドウを並べてスナップします。
2. を押しWin+Downて、ウィンドウの1つを画面の4分の1にする
3. 他のウィンドウを選択し、を押しWin+Upて、他のウィンドウが画面の反対側の4分の1を占めるようにします
4. マウスを使用してウィンドウの端をつかみ、画面の端に合わせてサイズを変更することで、高さを変更せずに各ウィンドウの幅を最大化します。

Jason Clementのソリューションのバグを修正しました。ウィンドウが垂直にスナップすると、以前はモニターの幅を占有しませんでした。現在のウィンドウ幅にとどまりますが、垂直に1/2モニターにスナップします。この修正により、モニターの上下の高さが50％、水平の幅が100％になります。

また、AHKを知らない人のために...

1. AutoHotKeyをダウンロード
2. メモ帳でテキストファイルを作成します。コードを貼り付けます。AutoHotKeyの正しい拡張子、たとえば「VerticalSnap.ahk」で保存します
3. エクスプローラからファイルを右クリックし、「スクリプトをコンパイル」を選択します
4. コンパイルにより、そのディレクトリに「VerticalSnap.exe」ファイルが作成されます。
5. run.exeを開き、「shell：startup」と入力してEnterキーを押します。
6. 新しいエクスプローラウィンドウが起動フォルダまで開きます。
7. .exeファイルをこのスタートアップフォルダーにコピーして貼り付けます。
8. 次回の起動時に、このスクリプトが実行されているはずです。CRTL + WINDOWS + UPARROWまたは+ DOWNARROWを使用して、モニターの下半分の上部にスナップできます。これを機能させるには、ウィンドウを最大化しないでください。

それがお役に立てば幸いです、そしてジェイソンに感謝します！

;-------------------------------------------------------------------;
; Returns the maximum or minimum value for any number of inputs
; i.e. Max(5,4,7,10) will return 10
;-------------------------------------------------------------------;
Min(params*)
{
  r := params[1]
  for index, param in params
    if (param < r)
      r := param
  return r
}
Max(params*)
{
  r := params[1]
  for index, param in params
    if (param > r)
      r := param
  return r
}

;-------------------------------------------------------------------;
; WindowsKey+Ctrl+Up / WindowsKey+Ctrl+Down
; Resizes window to half the screen height and moves it to the top
; or bottom of whichever screen has the largest overlap.
; By default, the window retains its horizontal (x) position and
; width.  To change this, uncomment the WinMaximize line.
;-------------------------------------------------------------------;
UpDownSnap(Direction)
{
  ; WinMaximize, A
  WinGetPos, x, y, w, h, a, , ,
  SysGet , Count, MonitorCount
  refArea := 0
  Loop, %count%
  {
    SysGet, m, MonitorWorkArea, %A_Index%
    xo := Max(0, Min(x + w, mRight) - Max(x, mLeft))
    yo := Max(0, Min(y + h, mBottom) - Max(y, mTop))
    area := xo * yo
    if (area > refArea)
    {
      monTop := mTop
      monBottom := mBottom
      monLeft := mLeft
      monRight := mRight
      refArea := area
    }
  }

  ; If the refArea is still equal to 0, the window does
  ; not overlap with any monitors. Wat?
  if (refArea > 0)
  {
    if (direction = 1)
      newY := monTop
    Else
      newY := (monBottom - monTop) / 2 + monTop
    WinMove , a, , monLeft, newY, (monRight - monLeft), (monBottom - monTop) / 2
  }
}
^#Up::UpDownSnap(1)
^#Down::UpDownSnap(0)

私が便利だと思ったオプションは、DisplayFusionを使用してモニターを仮想半分に細分化することです。これを設定するには、次を実行します。

• 通知領域にあるDisplayFusionアイコンを右クリックして、に進みMonitor Configurationます。
• 構成するモニターを選択します。
• をvertical splitモニターに追加します。（これで遊んで、モニターをさらに分割することもできます。）

これを有効にすると、Windows+ Arrowキーを使用してウィンドウをナビゲートし、モニターの新しい垂直分割領域に最大化できるようになります。30インチが入ったら、2つの1920x1200モニターをポートレートモードで実行しようとしています。ウィンドウを垂直にスナップする必要があります。

Windows 10では、他の多くのウィンドウが既に開いているマルチモニターセットアップで、2つのブラウザーウィンドウを上下に繰り返し分割する必要がありました。手動で行うことはできましたが、より良いソリューションが必要でした。

Chrome拡張機能の「タブのサイズ変更-画面レイアウトの分割」拡張機能により、これが非常に簡単になりました。

新しいChromeウィンドウを開き、Tab Resize拡張機能アイコンをクリックして、2x1オプションを選択します。素敵で簡単になりました。

Dellモニターを使用している場合は、ディスプレイをグリッドに分割するオプションがあるDell Display Managerをインストールできます。

次に、Shiftキーを押しながらウィンドウをセルにドラッグできます。