Windows 7でOutlookの予定表アラームを常に最新の状態に保つ方法

Windows 7を使い始めたばかりで、Outlookのリマインダーをポップアップして目立つように表示する方法を知りたい。タスクバーのOutlookスタックの別のウィンドウのように、それらは慎重に開き続けます。その結果、他のすべての背後に表示されるため、私はそれらを見落とし続けます。

どうすれば見逃しにくくなりますか？

（明らかに、自分自身を最前線に追いやる不快なアプリは通常望まないでしょう。しかし、そのような振る舞いが望ましいいくつかの場所があり、Outlookカレンダーリマインダーはそれらの1つです。）

Outlook 2010でも同じ問題が発生しました。以下の手順を使用すると、まるで魔法のように機能します。すべてのマクロを有効にすることを忘れないでください：[セキュリティセンター]> [マクロの設定]。

• 後で使用するためにデジタル証明書を作成します。「スタート」をクリックして「証明書」と入力し、「VBAプロジェクトのデジタル証明書」を選択します
• 証明書の名前を入力します。OKをクリックします。Outlookを開き、Alt+ F11を押してVBAエディターを起動します。
• 左側のツリーで、「Microsoft Office Outlook Objects」を展開し、「ThisOutlookSession」をダブルクリックします

• このコードを貼り付けます：

  Private Declare PtrSafe Function FindWindowA Lib "user32" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
  
  Private Declare PtrSafe Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long
  
  Private Const SWP_NOSIZE = &H1
  Private Const SWP_NOMOVE = &H2
  Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
  Private Const HWND_TOPMOST = -1
  
  Private Sub Application_Reminder(ByVal Item As Object)
  Dim ReminderWindowHWnd As Variant
  On Error Resume Next
  ReminderWindowHWnd = FindWindowA(vbNullString, "1 Reminder")
  SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
  
  End Sub
  

• マクロが実行されるように署名します：[ツール]> [デジタル署名...]で、前に作成した証明書を選択します

• VBAウィンドウを閉じます
• [ファイル]> [オプション]> [セキュリティセンター]> [セキュリティセンターの設定]> [マクロの設定]ですべてのマクロを有効にします。

AutoHotKeyを使用してこれを解決することもできます。このスクリプトは、フォーカスを盗むことなくリマインダーウィンドウを一番上に配置します（Win10 / Outlook 2013でテスト済み）

TrayTip Script, Looking for Reminder window to put on top, , 16
SetTitleMatchMode  2 ; windows contains
loop {
  WinWait, Reminder(s), 
  WinSet, AlwaysOnTop, on, Reminder(s)
  WinRestore, Reminder(s)
  TrayTip Outlook Reminder, You have an outlook reminder open, , 16
  WinWaitClose, Reminder(s), ,30
}

AHKスクリプト - コンパイル済みEXE

私が見つけた最良の答えはこちらです：簡単なVBAを使用して、Outlookの予定のリマインダーを他のウィンドウの前に再びポップアップさせる方法。

「ThisOutlookSession」に数行の単純なVBAコードを追加する必要があります。現在、毎回ウィンドウがポップアップします。ずっといい。

• 後で使用するためにデジタル証明書を作成する
• スタートをクリックして「証明書」と入力し、「VBAプロジェクトのデジタル証明書」を選択します
• 証明書の名前を入力してください
• 完了
• Outlookを開き、Alt + F11を押してVBAエディターを起動します。
• 左側のツリーで、「Microsoft Office Outlook Objects」を展開し、「ThisOutlookSession」をダブルクリックします

• このコードを貼り付け、好みに合わせて引用符で囲んだテキストを変更します。引用符を残します。

  Private Sub Application_Reminder(ByVal Item As Object)
  
  
      If TypeOf Item Is AppointmentItem Then
      MsgBox "Message text", vbSystemModal, "Message title"
      End If
  
  
  End Sub
  

• [ツール]> [デジタル署名]に移動し、先ほど作成した証明書を選択してマクロが実行されるように署名します

• VBAウィンドウを閉じます

バージョン1803（2018年2月）の時点で、「他のウィンドウの上にリマインダーを表示する」オプションが利用可能になりました。デフォルトでは有効になっていないようです。

道はない。当社は、マイクロソフトに直接エスカレートしようとしました。ここで人々が行うことの1つは、気づきやすいように、より不快な音を割り当てることです。しかし、Microsoftはそれが仕様によるものだと言っています。

上記のGulluの答えと同じですが、異なるウィンドウタイトルに対応するように変更されています。

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

'// TO ACCOUNT FOR WINDOW TITLE CHANGING WITH NOTIFICATION COUNT:
Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    'On Error Resume Next
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder(s)"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

これも私を悩ませていました。激しい検索の後、部分的な答えが見つかりました：http : //www.pcreview.co.uk/forums/hidden-outlook-reminders-t3972914.html

[タスクバーとスタートメニューのプロパティ]の[タスクバーボタン]設定を[結合しない]に変更すると、グループ化が分離し、開いている他のアイテムの前にリマインダーがポップアップ表示されます。

私はそれをテストしようとしましたが、矛盾していることがわかりました。あるときは私が取り組んでいたものの後ろに隠れたままであり、別の時にはそれは前面に現れました。どちらの場合も、Outlook自体とは異なるアイコンがタスクバーに表示されていたため、少なくとも気付く可能性がありました。

Filebox eXtenderを使用し、最初のリマインダーが表示されたら、それを開いてキャプションバーの右上にある新しい「ピン」アイコンをクリックします。次に、次のリマインダーが来ると、フォアグラウンドになります...

ShowReminders（http://www.sagelamp.com/pages/showreminders.aspx）というアドインを見つけました。これは、リマインダーウィンドウを一番上に表示します。リマインダーウィンドウを最小化しても機能します。

最終的に、Outlook VBAと単純なEXEを使用した簡単なソリューションを見つけました。

今後の見通し会議の予定を見逃すことはありません。

なぜこの目的のためにスタンドアロンのexeアプリケーションを使用するのですか？VBAに大きな赤いボックスを埋め込んでいましたが、その解決策には問題がいっぱいでした（大きな赤いボックスを上に保つにはhwndやその他の異常なシステムプロパティを使用する必要があるためだと思います）。だから物事を簡単にするために、なぜ一つのことをする基本的なEXEではないのか。Microsoftの無料ツールを使用できます（Visual Studio Community 2015は無料です）。

これはEXEコードです。1つのフォームを持つ単純なWindowsフォームアプリケーション。このコードをコンパイルします。

Imports System.Timers
Public Class Form1
    Dim tTimer As New Timer
    Public Sub New()
        InitializeComponent()
        Me.StartPosition = Windows.Forms.FormStartPosition.CenterScreen
        Me.TopMost = True
        Me.TopLevel = True
    End Sub
    Private Sub Form1_DoubleClick(sender As Object, e As EventArgs) Handles Me.DoubleClick
        Application.Exit()
    End Sub 
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        flashingQuick()
    End Sub
    Sub flashingQuick()
        tTimer.Start()
        AddHandler tTimer.Elapsed, New ElapsedEventHandler(AddressOf TimerTick)
    End Sub
    Sub TimerTick(ByVal source As [Object], ByVal e As ElapsedEventArgs)
        Dim theTimer As System.Timers.Timer = DirectCast(source, System.Timers.Timer)
        theTimer.Interval = 500
        theTimer.Enabled = True
        If Me.BackColor = System.Drawing.SystemColors.Control Then
            Me.BackColor = Color.Red
        Else
            Me.BackColor = System.Drawing.SystemColors.Control
        End If
    End Sub
End Class

そして、これが私がOutlook VBAで必要とするすべてです。ThisOutlookSessionにこれを入れてください

Private Sub Application_Reminder(ByVal Item As Object)
    On Error Resume Next
    If Item.MessageClass <> "IPM.Appointment" Then
      Exit Sub
    End If
    Dim sAPPData As String
    Dim sFileName As String
    sAPPData = Environ("AppData")
    sFileName = "\Microsoft\Windows\Start Menu\Programs\BigRedBox\BigRedBox.exe"
    If Dir(sAPPData & sFileName) <> "" Then
        Call Shell(sAPPData & sFileName)
    End If
End Sub

これは、ドイツ語版で動作するtboneの回答の拡張版です。

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare PtrSafe Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop (ReminderWindowHWnd)
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung(en)")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop ReminderWindowHWnd
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

ドイツ語のウィンドウタイトルといくつかの新しい関数（BringWindowToTop、SetForegroundWindowおよびSetFocus）を追加しました。

Outlook 2016と共にドイツ語版のWindows 10で動作します。

新しい証明書を生成することはできませんでした（[スタート]を押し​​て「証明書」を入力しても何も表示されませんでした）が、署名時にリストで別の証明書を選択しただけです。