Mac OS X Finderでシンボリックリンクを作成する

ln -sMac OS X Finder（OS 10.5）のunixコマンドと同じ機能を使用する方法はありますか？ターミナルを開かずにFinderウィンドウで作業しながら、シンボリックリンクを作成できるようにしたいと思います。

Make Aliasこれらのエイリアスはターミナルでナビゲートできないため、Finder のコマンドは必要なものではありません（ただし、作成されたリンクln -sはターミナルとFinderの両方でナビゲートできます）。

AppleScript経由でFinderにシンボリックリンクを作成することはどう ですか？

そのリンクで最も関連性の高いスクリプトは次のとおりです。

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

AppleScript Editorに貼り付けて、アプリケーションとして保存します。次に、それをファインダーのツールバーにドラッグするか、ドックにリンクします。

SymbolicLinkerは、まさにあなたが探しているものを実行し、無料です。

で、アップルスクリプトリンクのユーザによって提供さNUCは、私の質問に答えました。リンクが消えた場合に備えて複製されたapplescriptは次のとおりです。

私はコメンターjonn8nが提供するスクリプトを好みました。これはMacworldの記事としても再現されました。

on run
    open {choose file with prompt ¬
        "Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path ¬
                & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

これをスクリプトエディターを使用してアプリケーションとして保存し、アプリケーションをFinderサイドバーにドラッグしたので、ファイルまたはフォルダーをアプリケーションアイコンにドラッグしてシンボリックリンクを作成できるようになりました。

Path FinderはこれをFinderに追加し、さらに多くの機能を追加します。

Automator.appを使用して、bashスクリプトを実行するサービスを作成します。これは、AppleScriptよりも簡単で、サードパーティのソフトウェアをインストールするよりも信頼性があります。

for f in "$@"
do
    ln -s "$f" "$f.symlink"
done

次に、[ サービス ]メニューの[ シンボリックリンクの作成]コマンドにアクセスできます。

結果：

このスクリプトで可能な改善点は、実行ハンドラーを変更して、Finderから現在選択されているファイルを使用することです。

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files as alias)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            try
                do shell script "ln -s " & quoted form of posix_path ¬
                    & " " & quoted form of (posix_path & ".sym")
            on error
                try
                    do shell script "ln -s " & quoted form of posix_path ¬
                        & " " & quoted form of (posix_path & ".sym") with administrator privileges

                end try
            end try
        end try
    end repeat
end open

[application] /Contents/Info.plistを編集して追加することもできます

<key>LSUIElement</key>
<true/>

最後の</ dict>の直前。これは、アプリがバックグラウンドで実行され、クリックしても前面に表示されないことを意味します。

また、SymbolicLinkerが機能しないSnow Leopardでは、Automatorを使用してサービスを作成し、TerminalコマンドまたはAppleScriptを実行してシンボリックリンクを作成できます。

もう1つのAS：

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell

ここを見てみてください：http : //www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

これは、何かをクリックしたときにコントロールキーを押すと、OSXに既に組み込まれています。