vimdiff：行内の次の違いにジャンプしますか？

vimdiffファイルの比較に非常に便利です。ただし、長い行があり、行内の差異が比較的少ないファイルでよく使用します。

vimdiffは、行内の相違点を正しく強調表示します（行全体がピンクで、異なる文字が赤です）。これらの場合、行内の次の違いにジャンプできると便利です。

「次の違い」（]c）にジャンプできますが、これは違いがある次の行にジャンプします。

現在の行内の次の異なる文字に移動する方法はありますか？

2つの解決策があります。

1. 現在の構文の強調表示をテストして、行の赤い部分にジャンプする必要があります。
2. 両方のバッファで現在の行を抽出し、カーソルを正しく配置するために異なる最初の文字を見つける必要があります

両方のソリューションは、] cの後に実行する必要があり、vimスクリプトが必要です。

編集：これは動作するように思われる最初のドラフトです：

nnoremap <expr> <silent> <F3>   (&diff ? "]c:call \<sid>NextDiff()\<cr>" : ":cn\<cr>")

function! s:GotoWinline(w_l)
  normal! H
  while winline() < a:w_l
    normal! j
  endwhile
  " todo: beware of cases where the window is too little
endfunction

" Better ]c, [c jump
function! s:NextDiff()
  if ! &diffopt =~ 'filler' | return | endif

  let ignore_blanks = &diffopt =~ 'iwhite'

  " Assert: called just after a ]c or a [c
  " Forces the cursos to be synchronized in all synced windows
  " let diff_l = line()
  try 
    let foldenable = &foldenable
    set nofoldenable

    let w_l = winline() " problematic with enabled lines (from diff...)
    " echomsg w_l.'|'.line('.').'|'.getline('.')

    let lines = {}
    windo if &diff | call <sid>GotoWinline(w_l) | let lines[winnr()]={'text':getline('.'), 'number':line('.')} | endif
  finally
    let &foldenable = foldenable
  endtry

  " echomsg string(lines)
  if len(lines) < 2 | return | endif

  let indices = repeat([0], len(lines))
  let tLines = values(lines)
  let found = 0
  " infinite loop on two empty texts...
  while ! found
    let c = ''
    let next_idx = []
    let i = 0
    while i != len(indices)
      let crt_line = tLines[i].text
      let n = indices[i]
      if len(crt_line) == n
    let found = 1
    break
      endif

      let c2 = (len(crt_line) == n) ? 'EOL' : crt_line[n]
      if empty(c) 
    let c = c2
      endif

      " checks match
      let n += 1
      if c =~ '\s'
    if (c2 != c) && (ignore_blanks && c2 !~ '\s')
      let found = 1
      break
    else " advance
      while ignore_blanks && (n == len(crt_line) || crt_line[n] =~ '\s')
        let n += 1
      endwhile
    endif
      else
    if c2 != c
      let found = 1
      break
    endif
      endif
      let next_idx += [n]

      let i += 1
    endwhile
    if found | break | endif

    let indices = next_idx
  endwhile

  " now goto the right column
  let windows = keys(lines)
  " Assert len(windows) == len(indices)
  let w = 0
  while w != len(windows)
    " echomsg 'W#'.windows[w].' -> :'(tLines[w].number).'normal! '.(indices[w]+1).'|'
    exe windows[w].'wincmd w'
    silent! exe (tLines[w].number).'normal! 0'.(indices[w]).'l'
    let w += 1
  endwhile
  " echomsg string(indices)
endfunction

これは簡単な回避策です。

を使用できますset wrap。

これにより、違いが原因でテキストが不均等な行数で折り返される場合に問題が発生します。

vimdiffどちらでこれを行うかはわかりませんが、wdiff代わりにチェックアウトすることもできます。2つのファイルの違いを一度に1ワードずつ表示します。

ソースからコンパイルする必要がありました。

curl http://ftp.gnu.org/gnu/wdiff/wdiff-1.2.1.tar.gz > wdiff-1.2.1.tar.gz
tar -xzvf wdiff-1.2.1.tar.gz
cd wdiff-1.2.1
./configure
make
make install

ドキュメントから判断すると、それはできません。