プレビューで複数の開いているファイルの名前を付けて保存コマンドを自動化する方法

私はMac OSを使用して、PDFに印刷された11個のレポートを作成し、ファイルをMacプレビューで開く毎日のビジネスユーティリティを実行します。ファイルは、「Constant.pdf」や「Estimate.pdf」などの一般的なファイル名で作成されます。適切なファイル名でこれらのファイルを保存するための「テンプレート」として使用する空のPDFファイルのあるフォルダーがあります。空の各PDFファイルには、開いている各PDFレポートに使用するファイル名があります。最初に開いたPDFを取得し、Cmd+ Option+ Shift+ S（[名前を付けて保存]コマンドにアクセスする）を押して、Finderウィンドウで[保存先]を選択し、[保存]をクリックして[置換]をクリックします。 PDFファイルを閉じます。残りの10個のファイルでこの手順を繰り返します。

これらの手順を自動化する方法があることを願っています。幸いなことに、PDFファイルは特定の順序で印刷/作成され、プレビューはその順序でファイルを開き、手動で名前を付けて保存してファイルを閉じると同じ順序で表示されます。そのため、オートマトンは、各ファイル名を順番に割り当てるファイル名を知る必要があります。

助言がありますか？

11個のPDFテンプレートを永続的に保存できるフォルダーを作成します。で、ファイル名の前に付け01-、02-、...、 10-、11-PDFファイルは、（テンプレートが1-9でリードしていることが重要である保存されます処理される順序を示すために、0前に）。

以下のスクリプトでは、プロパティの値templatesFolder（行1）を変更して、PDFテンプレートが見つかるフォルダーへのパスを反映します。

スクリプトを使用するには、11個すべてのPDFを処理してPreviewで開くことを許可してから、スクリプトを実行します。Automator サービスにスクリプトを組み込み、それにキーボードショートカットを割り当てることができます。上の手順でシステム全体のサービスにする方法Automatorには、そのリンクで見つけることができます。

スクリプトを実行すると、ファイルシステムダイアログが開き、処理されたPDFを保存するフォルダーを選択できます。 Cancelスクリプトを中止します。をクリックするChooseと、PDFファイルは、テンプレートPDFのファイル名を使用して（ただし、プレフィックスなしで）、開かれた順序で保存されます。次に、各PDFが閉じられ、プレビューが閉じられ、保存されたPDFがFinderに表示されます。

スクリプト：

property templatesFolder : "~/Documents/PDFs/Templates"

set saveFolder to POSIX path of ¬
    (choose folder with prompt ("Select a folder to save PDFs") ¬
        default location path to documents folder)

tell application "System Events" to set pdfTemplates to the ¬
    name of the files in folder templatesFolder ¬
    whose name extension is "pdf"

set filenames to sort(the result)

repeat with D in my getPreviewDocumentsInOrder()
    set filename to text 4 thru -1 of item 1 of filenames
    set fp to POSIX file ([saveFolder, filename] as text)
    tell application "Preview"
        save D in fp
        close D
    end tell
    set filenames to rest of filenames
    if filenames = {} then exit repeat
end repeat

quit application "Preview"

tell application "Finder"
    open POSIX file saveFolder
    activate
end tell
--------------------------------------------------------------------------------
###HANDLERS
#
#
to getPreviewDocumentsInOrder()
    script
        use P : application "Preview"
        property idx : sort(id of P's windows)

        on docList(IDs)
            local IDs

            if IDs = {} then return {}
            script
                property L : IDs
            end script

            tell the result to set [d0, dN] to [first item, rest] of its L
            tell P to return {document of window id (d0)} & my docList(dN)
        end docList
    end script

    tell the result to return the docList(its idx)
end getPreviewDocumentsInOrder

to sort(L as list)
    local L

    if L = {} then return {}
    if L's length = 1 then return L

    script
        property Array : L

        on minimum(L as list)
            local L

            if L is {} then return {}
            if L's length = 1 then return L's first item

            script
                property Array : L
            end script

            set [x0, xN] to [first item, rest] of the result's Array
            set min to minimum(xN)
            if x0 < min then return x0
            return min
        end minimum

        on lastIndexOf(x, L as list)
            local x, L

            if x is not in L then return {}
            if L = {} then return

            script
                property Array : L
            end script

            tell the result
                set [x0, xN] to [last item, reverse of rest of reverse] of its Array
                if x0 = x then return (xN's length) + 1
                return lastIndexOf(x, xN)
            end tell
        end lastIndexOf

        to swap(L as list, i as integer, j as integer)
            local i, j, L

            set x to item i of L
            set item i of L to item j of L
            set item j of L to x
        end swap
    end script

    tell the result
        set i to lastIndexOf(minimum(its Array), its Array)
        if i ≠ 1 then swap(its Array, 1, i)
        set [x0, xN] to [first item, rest] of its Array
        return [x0] & sort(xN)
    end tell
end sort