多くのExcelファイルのデータを単一のExcelファイルにマージする[終了]

VBAを使用して、100以上のExcelファイルのデータを単一のファイルにマージする必要があります。

私のリポジトリ（D：\ rep）には、（file1、file2 ...など）という名前の100以上のファイルが含まれています

Excelファイルのサンプル

これらすべてのファイルのデータを1つのファイルにマージし、次のようにデータを結合する必要があります。

行は新しいファイルでも同じです。列1は（ファイル1）列で、その値は次の図に示すように行の値の合計を参照します

マージされたファイルのサンプル

Excel 2010バージョンに適切なオプションが含まれている場合、VBAよりもはるかに簡単で優れた方法があります...

これをExcel 2010で使用したことはありませんが、PowerQueryはMicrosoftから無料のアドインとして入手できます。2010アドインバージョンがPowerQueryの現在のバージョンのようなものである場合、フォルダーからすべてまたは一部のファイルをロードしてマージするクエリを簡単に作成できます。

PowerQueryは、Excel用のポイントアンドクリックETL（抽出、変換、ロード）ツールであり、（かなり）使いやすく、非常に強力です。

VBAでこれを行うには、はるかに複雑です。

ただし、Microsoftは、出発点として使用できるサンプルコードを提供しています

Sub MergeAllWorkbooks()
    Dim SummarySheet As Worksheet
    Dim FolderPath As String
    Dim NRow As Long
    Dim FileName As String
    Dim WorkBk As Workbook
    Dim SourceRange As Range
    Dim DestRange As Range

    ' Create a new workbook and set a variable to the first sheet. 
    Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)

    ' Modify this folder path to point to the files you want to use.
    FolderPath = "C:\Users\Peter\invoices\"

    ' NRow keeps track of where to insert new rows in the destination workbook.
    NRow = 1

    ' Call Dir the first time, pointing it to all Excel files in the folder path.
    FileName = Dir(FolderPath & "*.xl*")

    ' Loop until Dir returns an empty string.
    Do While FileName <> ""
        ' Open a workbook in the folder
        Set WorkBk = Workbooks.Open(FolderPath & FileName)

        ' Set the cell in column A to be the file name.
        SummarySheet.Range("A" & NRow).Value = FileName

        ' Set the source range to be A9 through C9.
        ' Modify this range for your workbooks. 
        ' It can span multiple rows.
        Set SourceRange = WorkBk.Worksheets(1).Range("A9:C9")

        ' Set the destination range to start at column B and 
        ' be the same size as the source range.
        Set DestRange = SummarySheet.Range("B" & NRow)
        Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
           SourceRange.Columns.Count)

        ' Copy over the values from the source to the destination.
        DestRange.Value = SourceRange.Value

        ' Increase NRow so that we know where to copy data next.
        NRow = NRow + DestRange.Rows.Count

        ' Close the source workbook without saving changes.
        WorkBk.Close savechanges:=False

        ' Use Dir to get the next file name.
        FileName = Dir()
    Loop

    ' Call AutoFit on the destination sheet so that all 
    ' data is readable.
    SummarySheet.Columns.AutoFit
End Sub

詳細については、こちらをご覧ください。

Stackにはすでに例があります：

https://stackoverflow.com/questions/31313377/excel-vba-combine-multiple-workbooks-into-one-workbook