スクリプト内のファイルパスにスペースが含まれているため、バッチファイルをダブルクリックしても機能しません

以下は私のバッチスクリプトです。ファイルを拡張子file.batで保存し、ダブルクリックしました。ファイルパスにスペースが含まれているため、何も表示されません（set file="C:\SUPPORT\APAC SIT\NewtextDoc.txt"）

私が使用する場合set file="C:\SUPPORT\APACSIT\NewtextDoc.txt" 、それは動作します。
使用するとset file="C:\SUPPORT\APAC SIT\NewtextDoc.txt"、機能しません。

@ECHO OFF
REM  The below command will look for the size of file on the server and
     inform the user if scheduler is down.
setlocal  
set nl=^& echo.
set file="C:\SUPPORT\APAC SIT\NewtextDoc.txt"
set maxbytesize=0

FOR /F "usebackq" %%A IN ('%file%') DO set size=%%~zA

if %size% EQU %maxbytesize% (echo WARNING !!! %nl%Scheduler File is ^= 

%maxbytesize% bytes%nl%Please do not process invoices, contact Webcenter 
Support) else (echo Scheduler File OK)

PAUSE

• 含む文字列エスケープcmd 有毒文字を二重引用符を使用して変数に変数を定義するときに：
  • set "_nl=& echo."
  • set "_file=path with spaces\name.ext"
  • （別のエスケープスキーマが必要な場合にのみ、いくつかのまれな状況があります）
• そして、適切な方法で変数を使用します：
  • エスケープなし： echo WARNING !!!%_nl%Scheduler File is ^=%_size% bytes
  • エスケープ： FOR /F "usebackq delims=" %%A IN ('"%_file%"') DO set "_size=%%~zA"

_デバッグを容易にするために、次のスクリプトで定義された変数名の下線（アンダースコア）に注意してください。SET _&PAUSEデバッグ（一時）出力を参照してください。

コメント付きスクリプト：

@ECHO OFF
SETLOCAL EnableExtensions DisableDelayedExpansion
REM  The below command will look for the size of file on the server
REM                         and inform the user if scheduler is down.

set "_nl=& echo."                                  escape ampersand by double quotes
set "_file=D:\bat\odds and ends\a b\testfile.txt"  escape spaces using double quotes
rem set "_file=C:\SUPPORT\APAC SIT\NewtextDoc.txt" 

set "_maxbytesize=0"                    keep using double quotes even if unnecessary

if not exist "%_file%" (
    set /A "_size=_maxbytesize-1"
    echo "%_file%" does not exist
) else (
    FOR /F "usebackq delims=" %%A IN ('"%_file%"') DO set "_size=%%~zA"
)

echo debugging output should show variables _file, _maxbytesize, _nl, _size 
SET _&PAUSE

if %_size% LEQ %_maxbytesize% (
    echo WARNING !!!%_nl%Scheduler File is ^=%_size% bytes
    echo Please do not process invoices, contact Webcenter Support
) else (
    echo Scheduler File OK%_nl%"%_file%" filesize is %_size% bytes
)
PAUSE

出力：

==> rename "D:\bat\odds and ends\a b\testfile.txt" testfilea.txt

==> set _
Environment variable _ not defined

==> D:\bat\SU\1130895.bat
"D:\bat\odds and ends\a b\testfile.txt" does not exist
debugging output should show variables _file, _maxbytesize, _nl, _size
_file=D:\bat\odds and ends\a b\testfile.txt
_maxbytesize=0
_nl=& echo.
_size=-1
Press any key to continue . . .
WARNING !!!
Scheduler File is =-1 bytes
Please do not process invoices, contact Webcenter Support
Press any key to continue . . .

==> rename "D:\bat\odds and ends\a b\testfilea.txt" testfile.txt

==> D:\bat\SU\1130895.bat
debugging output should show variables _file, _maxbytesize, _nl, _size
_file=D:\bat\odds and ends\a b\testfile.txt
_maxbytesize=0
_nl=& echo.
_size=13
Press any key to continue . . .
Scheduler File OK
"D:\bat\odds and ends\a b\testfile.txt" filesize is 13 bytes
Press any key to continue . . .

==>