そのバーを何度も閉じるためにXを押す必要があるのは非常に苦痛です。ダウンロードが完了したら、Firefoxのステータスバーをダウンロードするのと同じように、バー自体をクリアして画面の下部に残すようにします。どうすればいいですか？

2019編集：以下の拡張機能は使用できなくなっているようですので、誰かがこの拡張機能が機能する可能性があると述べています：ダウンロードを常にクリア2

2012年の当初の情報： 今日このChrome拡張機能を見つけました。これは比較的新しく、2012年5月22日から利用可能です。

ダウンロードを常に消去する

完了したすべてのダウンロードのダウンロードリストを常に消去するGoogle Chrome拡張機能。

ユーザーレビュー：

• ダウンロードバーをクリアし、その後非表示にする最初の拡張機能。

• 私はこれを行う拡張機能を探していました！ありがとうございました。ダウンロードが完了した後、ダウンロードバーを非表示にするとうまく機能します。クリックを保存します。

簡単なキーボードショートカット（Windows）：Ctrl+ J、Ctrl+ W（[ダウンロード]タブを開いて閉じます。これにより、元のタブのダウンロードバーも閉じられます）。

Macの場合は、⌘ (Cmd)+ Shift+を使用しますJ。

Macユーザー向けのキーボードショートカットソリューション

ダウンロードバーは、Google Chromeを使い始めて以来、私の一番の不満であり、多くの場合、メインブラウザとしてSafariに切り替える理由でした。これに関するGoogleグループのすべてのトピックをたまに確認しますが、これに関するバグレポートや機能リクエストが何年もありましたが、Googleの誰も単純な「ダウンロードバーを閉じる」キーボードショートカットや設定の「ダウンロードバーを表示しない」チェックボックス。

さらに、ダウンロードバーが追加されていない内窓、窓のサイズが変更されると、その後のダウンロードバーが追加されます。こんにちはGoogle。これは、JavaScriptが常にアプリケーションウィンドウのサイズを変更している1995年ではありません。私はユーザーであり、ウィンドウの大きさを決定します。

ただし、すぐにDownloar Barを閉じると、ウィンドウサイズが復元されます。ただし、しばらく他のアプリケーションとやり取りしてからGoogle Chromeに戻ってダウンロードバーを閉じると、何らかの理由で元のウィンドウサイズを忘れてしまい、サイズ変更されたウィンドウが表示されたままになります。これはおそらく、高解像度の画面では問題になりませんが、画面のスペースが少ないラップトップでは、非常に迷惑です。

サイズ変更のため、AppleScriptを使用して解決策を見つけることを検討し始めました。それに取り組んでいる間に、ダウンロードバーの終了を自動化する方法を見つけました。

ダウンロードバーを閉じるAppleScript

以下がその機能です。

1. [ダウンロード]ウィンドウを開きます（ダウンロードバーが自動的に削除されます）
2. [ダウンロード]ウィンドウを閉じます
3. 以前にアクティブだったタブに戻ります
4. オプション：ウィンドウのサイズを好みのサイズに変更します

on run
    tell application "Google Chrome"
        activate

        -- know which tab to return to
        set active_tab to active tab index of front window

        tell application "System Events"
            tell application process "Google Chrome"
                -- opens download window and removes the download bar
                keystroke "j" using {command down, shift down}
                -- make sure the keystroke works
                delay 0.2
                -- closes the download window
                keystroke "w" using command down
            end tell
        end tell

        -- return to the tab
        set active tab index of front window to active_tab

        -- optional: resize to your preferred dimensions
        set bounds of front window to {50, 40, 1400, 810}
    end tell
end run

先ほど言ったように、しばらくすると、Google Chromeは元のウィンドウサイズを忘れます。スクリプトの境界は、MacBook Airの解像度でブラウザウィンドウをどのように好むかです。これを削除するか、必要なものに設定できます。ウィンドウのサイズを変更した後、境界が何であるかを判断し、ダウンロードバーの高さを差し引くと境界が何であるかを計算することも可能だと思います。

キーボードショートカットを使用してAppleScriptをサービスとしてインストールする

このスクリプトを実行する最も簡単な方法は、システム全体のサービスとしてインストールし、キーボードショートカットを使用してアクティブ化することです。これを行うには、次の手順を実行します。

1. Automatorアプリケーションを起動します
2. 「サービス」を作成する
3. 上部の[サービス受信]を[入力なし]（ドロップダウン）に設定します
4. 左側で「AppleScript」を検索します
5. 「AppleScriptを実行」アクションを右側のワークフローペインにドラッグします
6. 上記のコードを貼り付けます（必要に応じてテストします）
7. サービスを「Google Chrome：Close Download Bar」のような名前で保存します

次：

1. [システム環境設定]> [キーボード]に移動します
2. 左側の「サービス」を選択します
3. 「一般」という見出しの下の右側に、新しく作成したサービスを見つけます
4. その行の右側をダブルクリックして、ショートカット入力ボックスをアクティブにします
5. お好みのキーコンボを押します（Control–Option–Command–Jを使用しました）

以上です。これで、キーコンボを押すたびに、Google Chromeが有効になり（まだ有効になっていない場合）、ダウンロードバーを削除してAppleScriptが読み込まれます。したがって、ダウンロードしたファイルで何かをしたときなど、Chromeにすばやく戻る簡単な方法でもあります。

_{注1：これはGoogle Chrome Canaryでも機能します。AppleScriptの「Google Chrome Canary」を参照してください。
注2：同様のアプローチは、AutoHotKeyを使用してWindowsで機能するはずです。}

ダウンロードシェルフを自動的に閉じますか？ハ！それで頑張ってください。開発者は、あることが毅然とないことを実装するいくつかの理由で。ただし、ファイルを開くと（つまり、ダウンロードバーエントリをクリックして）ファイルが削除され、バーが空の場合は非表示になります。

彼らはまた、棚を全く見せないオプションを作ることを拒否します。

それが価値があるものについては、キーボードでそれを閉じることができます：

• Windows：CTRL- J、CTRL-W

• Macの場合：CMD- - SHIFT、-JCMDW

最初のコマンドはダウンロードを新しいタブにポップし、2番目のコマンドはダウンロードをすぐに閉じて、前のタブに戻ります。そうすると、「ダウンロード」バーが閉じます。

この拡張機能の使用方法について
https://chrome.google.com/webstore/detail/downloadr-download-manage/gjihnjejboipjmadkpmknccijhibnpfe

ダウンロードバーを占有する場所はもう表示されません。

私はここでアレックに近いことをしましたが、私のコードはもう少し効率的で弾力性があります-主にキーボードショートカットに依存せず（多く）、ショートカットが登録されるかどうかを動的にチェックするためです。楽しい！

tell application "Google Chrome" to set i to active tab index of first window
tell application "System Events" to keystroke "j" using {command down, shift down}
tell application "Google Chrome"
    repeat
        if URL of active tab of first window = "chrome://downloads/" then
            exit repeat
        else
            delay 0.1
        end if
    end repeat
    set j to active tab index of first window
    delete tab j of first window
    set active tab index of first window to i
end tell

キーボードショートカットを使用すると、Chromiumのダウンロードバーを削除できます。この目的のための拡張機能は、ここからダウンロードできます。

http://metalab.at/wiki/Benutzer:Tessellated/Chromium_Clicky

このプロジェクトは放棄されていることに注意してください。

ダウンロードバーを閉じるために思いついたスクリプトを次に示します。ダウンロードウィンドウを開いたり閉じたりする代わりに、ボタンをクリックするだけでダウンロードバーを閉じます。

tell application "System Events"
    tell application process "Google Chrome"
        tell window 1
            click button "Close"
        end tell
    end tell
end tell

@Alecが記述するメソッドも機能するはずですが、FastScripts経由で呼び出します。

ホットキーでダウンロードバーを閉じるためのChrome拡張機能「ダウンロードバーを閉じる」があります。