オートホットキーを使用して、「コンテナ」ウィンドウではなく、既存のGoogle Chromeタブに焦点を合わせるにはどうすればよいですか？

オートホットキーを使用して、「コンテナ」ウィンドウではなく、既存のGoogle Chromeタブに焦点を合わせるにはどうすればよいですか？

詳細

Google Chromeは、1つ以上のタブを含むコンテナウィンドウハンドルで各ウィンドウを表しているようです。タブ（少なくとも現在のもの）には、独自のウィンドウハンドルがあります。タブウィンドウハンドルにはウィンドウタイトル（現在はすべて「-Google Chrome」で終わる）がありますが、コンテナーウィンドウハンドルにはありません。次のオートホットキーコードは、Google Chromeで意図したとおりに機能しません。

^+i::
if WinExist("ahk_class Chrome_WidgetWin_0")
    WinActivate
else
    Run "C:\Users\vleeshue\AppData\Local\Google\Chrome\Application\chrome.exe"
return

このバインディングは、Google Chromeウィンドウが存在する場合、またはGoogle Chromeを実行する場合にフォーカスします。ただし、多くの場合、コンテナウィンドウをターゲットにします（Window Spyでは、ウィンドウタイトルは空白です）。コンテナウィンドウをアクティブにすると、Google Chromeのキーボードショートカットを使用できなくなります。アクセスできないキーボードショートカットには、オムニバーにアクセスするためのすべての重要なctrl + lが含まれています。コンテナウィンドウの代わりに一貫してタブウィンドウをアクティブにする方法をまだ見つけていないので、私の回避策はマウスを使用することですが、可能であればそれを避けることを望みます。

Window Spyスクリーンショット

バックグラウンド

現在のGoogle Chromeバージョン：5.0.317.2 dev

私が使用する一般的な自動ホットキーバインディングは、特定のアプリケーションが既に実行されている場合はそのアプリケーションにフォーカスし、実行されていない場合はそのアプリケーションを実行するキーボードショートカットです。

たとえば、foobar2000にこれを使用します

^+m::
If WinExist("foobar2000")
    WinActivate
else
    Run "C:\Program Files (x86)\foobar2000\foobar2000.exe"
return

^+i::
if WinExist("ahk_class Chrome_WindowImpl_0")
  {
  WinActivate
  ControlFocus, Chrome_AutocompleteEditView1
  }
else
  Run "C:\Users\vleeshue\AppData\Local\Google\Chrome\Application\chrome.exe"
return

トリックを行う必要があります

（「Chrome_AutocompleteEditView1」はオムニバーコントロールの名前なので、追加Send ^aしてすべて選択できます）

注：取得するにはahk_class例えばクロム、のバージョンに、ahk_class Chrome_WindowImp1-0使用するAU3_Spy.exeAutoHotkeyをディレクトリ内。これにより、例が機能しない場合に、Chromeブラウザの正しいahkクラスを見つけることができます。

更新：再現できません。別のコントロールを使用した方がいいかもしれません...ウィンドウコントロールのリストを作成するには、次のコードを使用します。

#Persistent
SetTimer, WatchCursor, 100
return

WatchCursor:
  MouseGetPos, , , id, control
  WinGetTitle, title, ahk_id %id%
  WinGetClass, class, ahk_id %id%
  WinGet, ControlList, ControlList, A
  ToolTip, Under Cursor:`nahk_id: %id%`nahk_class: %class%`nTitle:%title%`nControl: %control%`n`nWindow Control List:`n%ControlList%
return

したがって、私のGoogle Chrome 4.0.249.78ベータ版（36714）のコントロールは次のとおりです。

• ViewsTextfieldEdit1
• Chrome_RenderWidgetHostWND1
• Chrome_AutocompleteEditView1
• Chrome_WindowImpl_01
• Chrome_WindowImpl_02

Alt + Tabを使用した回避策：

; Activates the window identified with wintitle if it's active,
; else opens a new one
OpenWindow(wintitle, runCommand)
{
    if WinExist(wintitle)
        WinActivate ; activates the window found above. Sweet.
    else
        Run %runCommand%
}

#g::
AppsKey & g::
    prevKeyDelay := A_KeyDelay
    SetKeyDelay, 100
    OpenWindow("ahk_class Chrome_WidgetWin_0", A_AppData
                . "\Local\Google\Chrome\Application\chrome.exe")
    SendEvent {Alt down}{Tab}
    SendEvent +{Tab}
    SendEvent {Alt up}
    SetKeyDelay, prevKeyDelay
return

必要に応じて引数を調整します。速すぎる送信が機能しないため、SetKeyDelayが使用されます。

AutoHotkeyの代わりにChrome拡張機能を使用することを検討してください。拡張機能は、URLやタブのフォーカスを変更する機能など、開いているすべてのタブにアクセスできます。それ以外の場合は、Chrome のアクセシビリティ機能を使用してアクティブウィンドウをクエリする必要があります。それがRescueTimeのようなプログラムがアクティブなURLを追跡する方法だと思います。たとえば、Windows 7 SDKのAccessible Event Watcher（AccEvent）を使用すると、Chromeのタブを変更するときに次のイベントが表示されます。

クロムのタブを見つけたい場合は、これを使用できます

SetTitleMatchMode, 2
If WinExist("your title ahk_exe chrome.exe")

     .... do your stuff ... 

else {
     .... do your other stuff ...
}

return

Chromeではすべてがプロセスであるため、タブもプロセスです。

Window Spyは、「Visible Window Text」フィールドにタブタイトルを返します。

目的のテキストが見つかるまで、タブをループできます。タブからタブに切り替えるには、CTRL+ TABキーを送信します。問題はある時点で停止することですが、最大でX個のタブを使用しないことがわかっている場合、ループにカウンターを含めて、目的のタブが見つからない場合にある時点で中断することができます。

AutoHotkeyのWinActivate関数にはバグがあるようです。（http://productivegeek.com/forums/topic/autohotkey-problem-restoring-minimized-window-and-giving-keyboard-focus）

したがって、WinActivate行の代わりに、

WinGet, winid, ID, 
DllCall("SwitchToThisWindow", "UInt", winid, "UInt", 1)

!f::
    IfWinExist ahk_class Chrome_WidgetWin_0
    {   IfWinActive ahk_class Chrome_WidgetWin_0
        {   Loop, 60
            {   GetKeyState, state, C
                if state = D
                {   KeyWait, c

                    KeyWait, LAlt
                    Sleep 10

                    ;must send RCtrl!!!
                    Send {RCtrl down}
                    Send {w down}
                    Sleep 10
                    Send {w up}
                    Send {RCtrl up}

                    break
                }
                Sleep 1
            }

        }

        else
        {   KeyWait,f
            KeyWait,LAlt
            ;don't hijack other apps
            Send f
        }
    }

    return

これがあなたにもっと役立つか、またはあなたにもっと多くのアイデアを与えるかどうか見てください。上記のいずれも使用していません。

!z::
WinWait, Yahoo,
IfWinNotActive, Yahoo, , WinActivate,Yahoo,
WinWaitActive, Yahoo, 
Sleep, 100
return

このAHK関数は、存在する場合はGoogle Chromeタブをアクティブにし、trueを返します。それ以外の場合、falseを返します。

; Activates tab in Google Chrome if it exists
; Returns true if exists, false if does not exist
; Leaves original tab activated if sought tab does not exist
; Known issue: will stop searching tabs if two tabs have same name
ActivateChromeTab(soughtTab)
{
  SetTitleMatchMode 2 ; Allows for partial matches in window titles

  IfWinNotExist Google Chrome
  {
    return false
  }

  WinActivate Google Chrome
  WinWaitActive Google Chrome
  WinGetTitle, currentTab, A
  firstTab := currentTab

  if (InStr(currentTab, soughtTab) > 0)
  {
    return true
  }

  Loop
  {
    Send {CtrlDown}{Tab}{CtrlUp}
    Sleep 50 ; Requires some time to update the window titles
    WinGetTitle, currentTab, A
    foundTab := InStr(currentTab, soughtTab) > 0
  }
  Until (foundTab || currentTab == firstTab)

  return foundTab
}