Windows Vista：「管理者として」コマンドで.exeプログラムを実行する方法

12

はい、それだけです。dos cmd行でプログラム.exeを実行する必要があり、ボタンを右クリックして「管理者として実行」を選択したときのように実行する必要があります。

windows-vista  shell  command-line 
— BinaryMisfit
ソース
私もそれについて疑問に思いました。私の解決策は、コマンドでバッチファイルを作成し、常に管理者として実行するか、管理者としてcmdを開くことでした。しかし、エレガントな解決策があるはずだと感じています。
— オレゴンゴースト2008

回答:

7

管理者としてcmd自体を実行すると、そこから実行する他のすべても実行されます。管理者として開くコマンドプロンプトへのショートカットを設定するだけです。そこからすべてが行って良いです。

— キルホッファー
ソース
5

私はelevateと呼ばれる.cmdと.vbsスクリプトのデュオを使用しましたが、それは私のニーズに合っています。必要なのは入力するだけです

昇格[コマンド]
[スタート]> [実行]またはコマンドラインから、管理者権限でコマンドを実行します。それが役に立てば幸い！

elevate.cmdは次のとおりです。

:: //***************************************************************************
:: // ***** Script Header *****
:: //
:: // File:      Elevate.cmd
:: //
:: // Additional files required:  Elevate.vbs
:: //
:: // Purpose:   To provide a command line method of launching applications that
:: //            prompt for elevation (Run as Administrator) on Windows Vista.
:: //
:: // Usage:     elevate.cmd application <application arguments>
:: //
:: // Version:   1.0.0
:: // Date :     01/02/2007
:: //
:: // History:
:: // 1.0.0   01/02/2007  Created initial version.
:: //
:: // ***** End Header *****
:: //***************************************************************************


@echo off

:: Pass raw command line agruments and first argument to Elevate.vbs
:: through environment variables.
set ELEVATE_CMDLINE=%*
set ELEVATE_APP=%1

start wscript //nologo "%~dpn0.vbs" %*

およびelevate.vbs：

' //***************************************************************************
' // ***** Script Header *****
' //
' // File:      Elevate.vbs
' //
' // Additional files required:  Elevate.cmd
' //
' // Purpose:   To provide a command line method of launching applications that
' //            prompt for elevation (Run as Administrator) on Windows Vista.
' //
' // Usage:     (Not used directly.  Launched from Elevate.cmd.)
' //
' // Version:   1.0.1
' // Date :     01/03/2007
' //
' // History:
' // 1.0.0   01/02/2007  Created initial version.
' // 1.0.1   01/03/2007  Added detailed usage output.
' //
' // ***** End Header *****
' //***************************************************************************


Set objShell = CreateObject("Shell.Application")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWshProcessEnv = objWshShell.Environment("PROCESS")

' Get raw command line agruments and first argument from Elevate.cmd passed
' in through environment variables.
strCommandLine = objWshProcessEnv("ELEVATE_CMDLINE")
strApplication = objWshProcessEnv("ELEVATE_APP")
strArguments = Right(strCommandLine, (Len(strCommandLine) - Len(strApplication)))

If (WScript.Arguments.Count >= 1) Then
    strFlag = WScript.Arguments(0)
    If (strFlag = "") OR (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
        OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "-?") OR (strFlag="h") _
        OR (strFlag = "?") Then
        DisplayUsage
        WScript.Quit
    Else
        objShell.ShellExecute strApplication, strArguments, "", "runas"
    End If
Else
    DisplayUsage
    WScript.Quit
End If


Sub DisplayUsage

    WScript.Echo "Elevate - Elevation Command Line Tool for Windows Vista" & vbCrLf & _
                 "" & vbCrLf & _
                 "Purpose:" & vbCrLf & _
                 "--------" & vbCrLf & _
                 "To launch applications that prompt for elevation (i.e. Run as Administrator)" & vbCrLf & _
                 "from the command line, a script, or the Run box." & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage:   " & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate application <arguments>" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate notepad ""C:\Windows\win.ini""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate cmd /k cd ""C:\Program Files""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command Set-Location 'C:\Windows'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage with scripts: When using the elevate command with scripts such as" & vbCrLf & _
                 "Windows Script Host or Windows PowerShell scripts, you should specify" & vbCrLf & _
                 "the script host executable (i.e., wscript, cscript, powershell) as the " & vbCrLf & _
                 "application." & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage with scripts:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate wscript ""C:\windows\system32\slmgr.vbs"" –dli" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command & 'C:\Temp\Test.ps1'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "The elevate command consists of the following files:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate.cmd" & vbCrLf & _
                 "    elevate.vbs" & vbCrLf

End Sub
— コリー
ソース
好奇心が強い、runasに対するこの利点は何ですか？
— tfinniga
ああ！まいったよ！:) runasに対する利点はわかりませんが、runasがわからない場合は、これが唯一の選択肢です。私は間違いなく恥ずかしいです:)
スクリプトとして使用しているものを一度読んだら、助けになると思います！
1
2
昇格スクリプトの明確な利点は、管理者ユーザーとパスワードを提供する必要なく（管理者ユーザーとしてログインしている場合）、ユーザーをUACで管理者に昇格できることです。runas.exeでできますか？
2

Windowsキーを押してCMDと入力することもできます。これにより、cmdがプログラムに一覧表示され、右クリック->プロパティ->互換性->管理者としてこのプログラムを実行します

これは常に管理者として実行されます。

— 郵便配達員
ソース
Ctrl + Shift + Enterを使用することもできます。
— ジョーイ
1

誰かが同等のVBSを投稿したので、ここにPowerShellのInvoke-Admin関数があります

function Invoke-Admin() {
param ( [string]$program = $(throw "Please specify a program" ),
        [string]$argumentString = "",
        [switch]$waitForExit )

$psi = new-object "Diagnostics.ProcessStartInfo"
$psi.FileName = $program 
$psi.Arguments = $argumentString
$psi.Verb = "runas"
$proc = [Diagnostics.Process]::Start($psi)
if ( $waitForExit ) {
    $proc.WaitForExit();
}

}

— ジャレッドパー
ソース
0

要するに：

  • [スタート]をクリック/押し、次にCTRL + SHIFTおよびENTERを押します。確認。

詳細に：

  1. [スタート]ボタンを押す「cmd」と入力します（引用符なし）すぐに（1）
  2. CtrlキーとShiftキーを押しながら
  3. ENTERを押す
  4. Windows Vista UACダイアログボックスを確認する

（1）「すぐに」は、「実行」ボックスではなく「検索」ボックスに入力することを意味します。

— マカイアイ
ソース
0

VBScriptを使用できます。.vbsファイルを作成します、例えばambika.vbs：

Set objShell = CreateObject(“Shell.Application”)
Set objWshShell = WScript.CreateObject(“WScript.Shell”)
Set objWshProcessEnv = objWshShell.Environment(“PROCESS”)

objShell.ShellExecute “C:\Windows\system32\cmd.exe”, “/k”, “”, “runas”
— アンビカ・シン
ソース
弊社のサイトを使用することにより、あなたは弊社のクッキーポリシーおよびプライバシーポリシーを読み、理解したものとみなされます。
Licensed under cc by-sa 3.0 with attribution required.