xsl：for-eachループ内のカウンター

89

現在処理されている要素の数を反映するxsl：for-eachループ内のカウンターを取得する方法。
たとえば、私のソースXMLは

<books>
    <book>
        <title>The Unbearable Lightness of Being </title>
    </book>
    <book>
        <title>Narcissus and Goldmund</title>
    </book>
    <book>
        <title>Choke</title>
    </book>
</books>

私が入手したいのは：

<newBooks>
    <newBook>
        <countNo>1</countNo>
        <title>The Unbearable Lightness of Being </title>
    </newBook>
    <newBook>
        <countNo>2</countNo>
        <title>Narcissus and Goldmund</title>
    </newBook>
    <newBook>
        <countNo>3</countNo>
        <title>Choke</title>
    </newBook>
</newBooks>

変更するXSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <newBooks>
            <xsl:for-each select="books/book">
                <newBook>
                    <countNo>???</countNo>
                    <title>
                        <xsl:value-of select="title"/>
                    </title>
                </newBook>
            </xsl:for-each>
        </newBooks>
    </xsl:template>
</xsl:stylesheet>

したがって、問題は???の代わりに何を置くかです。標準的なキーワードはありますか、それとも変数を宣言してループ内でインクリメントするだけですか？

質問がかなり長いので、おそらく1行または1単語の回答を期待する必要があります:)

xml xslt loops

— クリストフ
ソース

141

position()。例えば：

<countNo><xsl:value-of select="position()" /></countNo>

— 赤の広場
ソース

9

これは、xsl：for-each内にxsl：ifのようなフィルターを追加する必要があるまで、問題なくうまくいきます。次に、position（）は無用であり、適切なカウンターが必要です。

— Mike Starov、2012年

4

@マイクスタブロフそれは質問の一部ではありませんでした！すべての状況をカバーすることはできません

— redsquare 2012年

@redsquare正解。ちょうど私の2セントを追加します。説明した状況を解決するために、XSL拡張関数を作成する必要がありました。多分私はここの人々にもっと良い解決策について尋ねるべきです。

— マイクスタロフ

2

@MikeStarovでは、xsl:if内部にある場合はどうすればよいxsl:for-eachですか？「適切なカウンター」とは何ですか？いくつかのリソースを指すことができますか？

— lajarre

@lajarre XSLから呼び出されるカスタム拡張関数を記述します。2パス処理を行うこともできます。1回処理して、xsl：variableに保存します。次に、xsl変数の内容にテンプレートを適用し、position（）を使用して番号付けを追加します

— Mike Starov

13

<xsl:number format="1. "/><xsl:value-of select="."/><xsl:text>???のところに挿入してみてください。

「1.」に注意してください-これは数値形式です。詳細：こちら

— m_pGladiator
ソース

いくつかのフォーマットが必要な場合にwell.Iは、おそらくそのアプローチを使用するようおかげで、それは興味深い読まれる

— クリストフ

XSLT 1.0バージョン：<xsl:number format="1. " value="position()"/>

— jsuddsjr 2015年

10

試してください：

<xsl:value-of select="count(preceding-sibling::*) + 1" />

編集 -そこで脳がフリーズした、position（）はより簡単です！

— ルーク・ベネット
ソース

3

それでも、特にposition（）以外の基準に基づいて選択している場合は便利です。+1

— jsuddsjr 2015年

7

また、Postion（）で条件ステートメントを実行することもできます。これは、多くのシナリオで非常に役立ちます。

たとえば。

 <xsl:if test="(position( )) = 1">
     //Show header only once
    </xsl:if>

— アルンアランギル
ソース

2

xsl：sortなどのフィルターがある場合、これは失敗します。これは、最初の項目が最初に処理されない可能性があるためです。

— Alexis Wilke、2012年

5

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <newBooks>
                <xsl:for-each select="books/book">
                        <newBook>
                                <countNo><xsl:value-of select="position()"/></countNo>
                                <title>
                                        <xsl:value-of select="title"/>
                                </title>
                        </newBook>
                </xsl:for-each>
        </newBooks>
    </xsl:template>
</xsl:stylesheet>

— サンティアゴセパス
ソース