私はCMAKEの初心者です。以下は、mingw環境ウィンドウでうまく機能する単純なcmakeファイルです。問題は明らかにtarget_link_libraries()、libwsock32.aをリンクしているCMAKEの機能にあります。Windowsではこれが機能し、結果が得られます。

ただし、予想通り、Linuxでは、Linux OSにはないもの/usr/bin/ldを探します-lwsock32。

私の問題は、Linux OSでwsock32ライブラリをリンクしないようにCMAKEにどのように指示するのですか？

どんな助けでも大歓迎です。

私のシンプルなCMakeファイル：

 PROJECT(biourl)
 set (${PROJECT_NAME}_headers ./BioSocketAddress.h  ./BioSocketBase.h ./BioSocketBuffer.h ./BioSocketCommon.h  ./BioSocketListener.h  ./BioSocketPrivate.h  ./BioSocketStream.h ./BioUrl.h BioDatabase.h )

set (${PROJECT_NAME}_sources BioSocketAddress.C  BioSocketBase.C  BioSocketCommon.C BioSocketStream.C  BioUrl.C BioDatabase.C )

add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_headers} ${${PROJECT_NAME}_sources} )

# linkers
#find_library(ws NAMES wsock32 PATHS ${PROJECT_SOURCE_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_DEFAULT_PATH)

target_link_libraries(${PROJECT_NAME} bioutils wsock32)

install (TARGETS ${PROJECT_NAME}
       RUNTIME DESTINATION bin
       LIBRARY DESTINATION lib
       ARCHIVE DESTINATION lib/archive )

使用する

if (WIN32)
    #do something
endif (WIN32)

または

if (UNIX)
    #do something
endif (UNIX)

または

if (MSVC)
    #do something
endif (MSVC)

または類似

CMakeの有用な変数 とCMakeチェックプラットフォームを参照してください

これがそのような一般的な問題であることを考えると、ジェロント投稿：

    if(UNIX AND NOT APPLE)
        set(LINUX TRUE)
    endif()

    # if(NOT LINUX) should work, too, if you need that
    if(LINUX) 
        message(STATUS ">>> Linux")
        # linux stuff here
    else()
        message(STATUS ">>> Not Linux")
        # stuff that should happen not on Linux 
    endif()

CMakeブール論理ドキュメント

CMakeプラットフォーム名など

一般に

そのようないくつかのオペレーティングシステムの変数を検出して指定できます。

Microsoft Windowsを検出する

if(WIN32)
    # for Windows operating system in general
endif()

または：

if(MSVC OR MSYS OR MINGW)
    # for detecting Windows compilers
endif()

Apple MacOSを検出する

if(APPLE)
    # for MacOS X or iOS, watchOS, tvOS (since 3.10.3)
endif()

UnixとLinuxを検出する

if(UNIX AND NOT APPLE)
    # for Linux, BSD, Solaris, Minix
endif()

特定のリンカーの問題

Windows固有のwsock32ライブラリの問題を解決するには、次のように他のシステムから削除します。

if(WIN32)
    target_link_libraries(${PROJECT_NAME} bioutils wsock32)
else
    target_link_libraries(${PROJECT_NAME} bioutils)
endif()

CMAKEからの特別な言葉があります。見てみましょう。

if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    // do something for Linux
else
    // do something for other OS

ジェネレータ式も可能です。

target_link_libraries(
    target_name
    PUBLIC
        libA
        $<$<PLATFORM_ID:Windows>:wsock32>
    PRIVATE
        $<$<PLATFORM_ID:Linux>:libB>
        libC
)

これは、WindowsではlibA、wsock32、libCをリンクし、LinuxではlibA、libB、libCをリンクします。

CMakeジェネレーター式

それを試してください：

if(WIN32)
    set(ADDITIONAL_LIBRARIES wsock32)
else()
    set(ADDITIONAL_LIBRARIES "")
endif()

target_link_libraries(${PROJECT_NAME} bioutils ${ADDITIONAL_LIBRARIES})

他の便利な変数はここにあります。

Android SDK for WindowsでAndroid向けにコンパイルするときに苦労したので、ここに残しておきます。

CMakeはTARGETとHOSTプラットフォームを区別します。

私のターゲットはAndroidだったので、CMAKE_SYSTEM_NAMEのような変数の値は「Android」であり、ここで他の回答からの変数WIN32は定義されていませんでした。しかし、Windows、Linux、IOのいずれかでコンパイルする場合、いくつかのことを異なる方法で行う必要があるため、HOSTシステムがWindowsであるかどうかを知りたいと思いました。そのために、ほとんどの人にとってTARGEtとHOSTが同じであるか気にしないため、ほとんど知られていないか、どこにも言及されていないことがわかったCMAKE_HOST_SYSTEM_NAMEを使用しました。

これが誰かを助けることを願っています...

いくつかのプリプロセッサマクロを使用して、それがWindowsまたはLinuxにあるかどうかを確認します。例えば

#ifdef WIN32
LIB= 
#elif __GNUC__
LIB=wsock32
#endif

ビルドコマンドに-l $（LIB）を含めます。

コマンドライン引数を指定して、両方を区別することもできます。