CMDが管理者として実行されているか、昇格された特権を持っているかどうかを検出するにはどうすればよいですか？

バッチファイル内から、管理者特権または昇格された特権で実行しているかどうかをテストしたいと思います。

「管理者として実行」を選択してもユーザー名は変更されないため、機能しません。

効果はないが管理者特権を必要とする普遍的に利用可能なコマンドがある場合、特権をテストするためにそれを実行してエラーコードをチェックすることができます。これまでのところ、そのようなコマンドは見つかりませんでした。私が見つけたコマンドは、何かを示す可能性がある単一の非特定のエラーコードを返しているようで、さまざまな理由で失敗する傾向があります。

私はWindows 7だけを気にしますが、以前のオペレーティングシステムのサポートは素晴らしいでしょう。

補遺：Windows 8の場合、これは機能しません。代わりにこの優れた答えをご覧ください。

このソリューションはここにあります：http : //www.robvanderwoude.com/clevertricks.php

AT > NUL
IF %ERRORLEVEL% EQU 0 (
    ECHO you are Administrator
) ELSE (
    ECHO you are NOT Administrator. Exiting...
    PING 127.0.0.1 > NUL 2>&1
    EXIT /B 1
)

それが機能しないと仮定し、Win7について話しているので、適切であれば、Powershellで以下を使用できます。

$principal = new-object System.Security.Principal.WindowsPrincipal([System.Security.Principal.WindowsIdentity]::GetCurrent())
$principal.IsInRole([System.Security.Principal.WindowsBuiltInRole]::Administrator)

そうでない場合（おそらく、バッチファイルを明示的に提案しているため、おそらくそうではありません）、上記を.NETで記述し、使用するバッチファイルの結果に基づいて、exeから終了コードを返すことができます。

このトリックで必要なコマンドは1つだけnet sessionです。コマンドプロンプトに入力します。

あなたがいる場合は管理者でない、あなたはアクセスがメッセージを拒否され得ます。

System error 5 has occurred.

Access is denied.

あなたが管理者である場合は、別のメッセージが表示されますが、最も一般的なものは次のとおりです。

There are no entries in the list.

MS Technetから：

パラメータなしで使用すると、net sessionはローカルコンピュータとのすべてのセッションに関する情報を表示します。

RushyoのAT使用の提案は気に入っていますが、これは別のオプションです。

whoami /groups | findstr /b BUILTIN\Administrators | findstr /c:"Enabled group" && goto :isadministrator

このアプローチでは、必要に応じて、非管理者と昇格していない管理者を区別することもできます。昇格していない管理者は、グループリストにまだBUILTIN \ Administratorsがありますが、有効になっていません。

ただし、これは一部の英語以外の言語システムでは機能しません。代わりに、試してください

whoami /groups | findstr /c:" S-1-5-32-544 " | findstr /c:" Enabled group" && goto :isadministrator

（これはWindows 7で動作するはずですが、以前のバージョンについてはわかりません。）

他の人が以前に配置したものとほぼ同じですが、バッチコマンドの最初に配置できる1つのライナーとして。（まあ、通常@echoオフの後で。）

net.exe session 1>NUL 2>NUL || (Echo This script requires elevated rights. & Exit /b 1)

Vista、Win 7以降でこれを行う最も簡単な方法は、トークングループを列挙し、現在の整合性レベル（またはグループのメンバーシップのみが重要な場合は管理者のsid）を探すことです。

管理者特権で実行しているかどうかを確認します。

whoami /groups | find "S-1-16-12288" && Echo I am running elevated, so I must be an admin anyway ;-)

ローカル管理者に属しているかどうかを確認します。

whoami /groups | find "S-1-5-32-544" && Echo I am a local admin

ドメイン管理者に属しているかどうかを確認します。

whoami /groups | find "-512 " && Echo I am a domain admin

次の記事は、Windowsが使用する整合性レベルのSIDの一覧です。http：//msdn.microsoft.com/en-us/library/bb625963.aspx

これは、昇格したステータスに焦点を当てたハリーの回答のわずかな変更です。install.batファイルの先頭でこれを使用しています：

set IS_ELEVATED=0
whoami /groups | findstr /b /c:"Mandatory Label\High Mandatory Level" | findstr /c:"Enabled group" > nul: && set IS_ELEVATED=1
if %IS_ELEVATED%==0 (
    echo You must run the command prompt as administrator to install.
    exit /b 1
)

これは間違いなく私にとってはうまくいき、原則はしっかりしているようです。MSFTのクリス・ジャクソン：

昇格を実行している場合、トークンにはMandatory Label \ High Mandatory LevelというACEが含まれています。

ソリューション：

at >nul
if %ErrorLevel% equ 0 ( echo Administrator ) else ( echo NOT Administrator )

Windows 10では機能しません

Windowsのすべてのバージョンでそうすることができます：

openfiles >nul 2>&1
if %ErrorLevel% equ 0 ( echo Administrator ) else ( echo NOT Administrator )

私は多くの（ほとんど？）応答を読み、Win 8.1で動作するbatファイルを開発しました。共有したいと思いました。

setlocal
set runState=user
whoami /groups | findstr /b /c:"Mandatory Label\High Mandatory Level" > nul && set runState=admin
whoami /groups | findstr /b /c:"Mandatory Label\System Mandatory Level" > nul && set runState=system
echo Running in state: "%runState%"
if not "%runState%"=="user" goto notUser
  echo Do user stuff...
  goto end
:notUser
if not "%runState%"=="admin" goto notAdmin
  echo Do admin stuff...
  goto end
:notAdmin
if not "%runState%"=="system" goto notSystem
  echo Do admin stuff...
  goto end
:notSystem
echo Do common stuff...
:end

誰かがこれが便利だと思うことを願っています:)

https://stackoverflow.com/a/38856823/2193477の「not-a-one-liner」バージョン

@echo off
net.exe session 1>NUL 2>NUL || goto :not_admin
echo SUCCESS
goto :eof

:not_admin
echo ERROR: Please run as a local administrator.
exit /b 1

私は本当にこのパーティーに遅れていることを知っていますが、これは管理者のフードを決定するための私の1つのライナーです。

エラーレベルには依存せず、単に次のようにしsysteminfoます。

for /f "tokens=1-6" %%a in ('"net user "%username%" | find /i "Local Group Memberships""') do (set admin=yes & if not "%%d" == "*Administrators" (set admin=no) & echo %admin%)

ユーザーの管理ステータスに応じて、yesまたはnoを返します...

また、変数「admin」の値を「yes」または「no」に設定します。

管理者権限を持つユーザーとして実行している場合、環境変数SessionNameは定義されず、バッチファイルを実行するときにも管理者権限がありません。

「net session」コマンドを使用して、エラー戻りコード「0」を探し、管理者権限を確認する必要があります。

例; -最初のエコーステートメントはベルキャラクターです net session >nul 2>&1 if not %errorlevel%==0 (echo echo You need to start over and right-click on this file, echo then select "Run as administrator" to be successfull. echo.&pause&exit)

以下は、Windows 7からWindows 10で使用した簡単な方法です。基本的には、「IF EXIST」コマンドを使用して、Windows \ System32 \ WDI \ LogFilesフォルダーを確認します。WDIフォルダーは、少なくとも7以降のWindowsのすべてのインストールに存在し、アクセスするには管理者権限が必要です。WDIフォルダーには常にLogFilesフォルダーが含まれています。したがって、WDI \ LogFilesフォルダーで「IF EXIST」を実行すると、管理者として実行されている場合はtrueが返され、管理者として実行されていない場合はfalseが返されます。これをバッチファイルで使用して特権レベルを確認し、その結果に基づいて必要なコマンドに分岐できます。

これがサンプルコードの短いスニペットです：

IF EXIST %SYSTEMROOT%\SYSTEM32\WDI\LOGFILES GOTO GOTADMIN
(Commands for running with normal privileges)

:GOTADMIN
(Commands for running with admin privileges)

この方法は、デフォルトのセキュリティ権限がWDIフォルダで変更されていないことを前提としていることに注意してください（ほとんどの状況では起こりそうにありませんが、以下の警告＃2を参照してください）。その場合でも、管理者アクセスを必要とする別の一般的なファイル/フォルダーをチェックするようにコードを変更するだけの問題です（System32 \ config \ SAMは代替候補として適切かもしれません）。または、そのための独自のファイルを作成することもできます目的。

ただし、この方法には2つの注意点があります。

1. UACを無効にすると、すべてがとにかく管理者として実行されるという単純な事実を打破する可能性があります。

2. WindowsエクスプローラーでWDIフォルダーを開き、プロンプトが表示されたら[続行]をクリックすると、そのユーザーアカウントに永続的なアクセス権が追加され、メソッドが壊れます。これが発生した場合は、WDIフォルダーのセキュリティ権限からユーザーアカウントを削除することで修正できます。何らかの理由でユーザーがWindowsエクスプローラーでWDIフォルダーにアクセスできる必要がある場合は、コードを変更して別のフォルダーを確認する必要があります（上記のように、この目的のために独自のフォルダーを作成することをお勧めします）。 。

だから、確かに私の方法は壊れる可能性があるため完璧ではありませんが、実装が簡単で、Windows 7、8、10のすべてのバージョンと同等の互換性がある比較的速い方法です。 100％効果的でした。

Win7 EnterpriseおよびWin10 Enterpriseに対応

@if DEFINED SESSIONNAME (
    @echo.
    @echo You must right click to "Run as administrator"
    @echo Try again
    @echo.
    @pause
    @goto :EOF
)