Vimで行全体を上下に移動します

Notepad ++では、Ctrl+ Shift+ Up/ Downを使用して現在の行を上下に移動できます。Vimでこれに似たコマンドはありますか？私は無限のガイドを調べましたが、何も見つかりませんでした。

存在しない場合、アクションをそのキーの組み合わせにどのようにバインドできますか？

編集：Mykolaの回答は、バッファーの最初と最後の行を除いて、すべての行で機能します。最初の行を上または下の行に移動すると、その行が削除され、一番下の行を上に移動すると、ポーンのように最初に2つのスペースがジャンプします。誰でも何か改良を提供できますか？

以下をあなたの.vimrcに入れて仕事をしてください

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

行が消えるのはVimのバグのようです。それを避けるためにハックを入れました。おそらくもっと正確な解決策があります。

更新

Vimの組み合わせを使用するだけでは、多くの原因不明の問題があります。これらは行の欠落と余分な行ジャンプです。

したがって、これは.vimrcまたは〜/ .vim / plugin / swap_lines.vimのいずれかに配置できるスクリプトソリューションです。

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

1行を上の行と入れ替えたい場合は、通常次のようにします。

ddkP

説明

• ddは行を削除し、それをデフォルトのレジスターに追加します。
• kは1行上に移動します（jは1行下に移動します）
• Pは現在の行の上に貼り付けます

カーソルが移動したい行にあると仮定します。

上下:mに移動： 移動用

:m +1 -1行下に移動

:m -2 -1行上に移動

（+1は、上または下に移動する行数に応じて任意の数字に置き換えることができます。つまり、+ 2は2行下に移動し、-3は2行上に移動します）

特定の行に移動するには

:set number -数行を表示します（移動先を簡単に確認できます）

:m 3 -3行目の後に行を移動します（3を任意の行に置き換えます）

複数行の移動：

V（つまりShift- V）、コースを上下に移動してVIMで複数の行を選択します

ヒットを選択したら:、上のコマンドを実行して、m +1など

行を上に移動します。 ddkP

行を下に移動します。 ddp

これは私のために働きました：

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

ところで、ALT + some_keyを使用する必要があり、端末（urxvtがこれを行う）が準拠を拒否する場合は、.vimrcに次のように入力する必要があります。

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

ここで、^]はAltキーを表す単一の文字です。その文字を入力するにはC+v, Esc、Vim で使用C+q, Escします（Windowsの場合）。

以下を〜/ .vimrcファイルに追加します（n、mのマッピングがないことを確認してください）

nmap n :m +1<CR>
nmap m :m -2<CR>

nキーを押すと、行が下mに移動し、行が上に移動します。

コマンドモードで、カーソルを下に移動する行に置き、次に

ddp

説明：ddは、現在の行を一般バッファーに削除し、pはカーソル位置の後、または行全体の場合は1行下に戻します。

多くのドキュメントでは、コマンドpとPに関していくつかの混乱があります。実際には、pはAFTERカーソルとP ATカーソルを貼り付けます。

このコードを.vimrc（または.gvimrc）に追加するだけです

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

まさにこの素晴らしいプラグインで探しているもの：https : //github.com/vim-scripts/upAndDown

簡単な解決策は、あなたの中に入れてある.vimrcこれらの行：

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

.vimrcファイルの最後に次のコードを追加しました。

noremap H ddkkp
noremap N ddp

したがって、「H」と「N」は現在の行をそれぞれ上下に移動します。

これはWikia記事の例を使用したMacVimの簡易バージョンです（gunのコメントからのリンクを参照）。

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

現在の行を選択するにはShift-Vを使用し、オプションでカーソルを上下に移動してさらに行を選択するため、ブロック選択バリアントのみを使用しています。

上記のショートカットによると、Cmd-Shift-Up / Downを押すとブロック選択が上下にシフトします。"D"はMacVimのコマンドキーです。Windowsの場合、 "C"（Control）、または "A"（Alt）を試してください（たとえば、<CAf>はControl Alt fになります）。

ウィキアの記事はこれらに「= gv」を追加します。これは、周囲のテキストに基づいて、移動後のブロックのインデントを調整する効果があります。これは紛らわしいので削除し、代わりに選択範囲をすばやくインデントするショートカットを追加しました。

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

ちなみに、<<と>>でも同じことができますが、選択は失われるため、上記のショートカットを使用すると、複数回インデントを行っても、選択が維持されるため、ブロックを移動できます。

MacVimはCmd-Shift-Left / Rightでタブを切り替えるように設定されているので、Cmd-Alt-Left / Rightを使用しました。

MacVimのタブ切り替えは次のとおりです（残りは上記の.gvimrcに入れます）。

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

vimプラグインunimpaired.vim [eおよび] e

でコマンド:help moveをvim押すと、結果は次のようになります。

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

例： 現在の行を1行下に移動します=> :m+1。

例： 番号100の行を、番号80 =>の行の下に移動し :100 m 80ます。

例： 番号100の行を番号200 =>の行の下に移動し :100 m 200ます。

例： 番号が200の行の下にある[100、120]内の番号の行を移動=> :100,120 m 200。

これが私のマシンで動作するソリューションです ：VIM 8.1を実行しているMacBook Pro

これらのコマンドは、バッファーの上部または下部の行を削除しません。

Alt-JおよびAlt-K出力の実際のシンボルを使用することは、私の環境でキーコードが正しくマッピングされないための回避策です。

これを古い.vimrcに入れて、うまくいくかどうか確認してください。

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

私ddkkpはそれをしました（ddkP大文字のPを使用する代わりに、これも機能します）。

：m。+ 1または：m.-2は、1行を移動する場合に使用します。これが複数行を移動するためのスクリプトです。ビジュアルモードでは、Alt-up / Alt-downは、ビジュアル選択を含む行を1行上または下に移動します。挿入モードまたは通常モードでは、カウントプレフィックスが指定されていない場合、Alt-up / Alt-downは現在の行を移動します。countプレフィックスがある場合、Alt-up / Alt-downは、現在の行から開始してその行数だけ1行上/下に移動します。

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

特定の検索に一致する複数の行でこれを実行する場合：

• 上：:g/Your query/ normal ddpまたは:g/Your query/ m -1
• ダウン:g/Your query/ normal ddpまたは:g/Your query/ m +1