Oracle PL / SQL-単純な配列変数を作成する方法

PL / SQLコードで使用できるインメモリ配列変数を作成したいのですが。純粋なメモリを使用するOracle PL / SQLでコレクションを見つけることができません。それらはすべてテーブルに関連付けられているようです。PL / SQL（C＃構文）で次のようなことをしたいと考えています。

string[] arrayvalues = new string[3] {"Matt", "Joanne", "Robert"};

編集： Oracle：9i

固定サイズの配列にはVARRAYを使用できます。

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t('Matt', 'Joanne', 'Robert');
begin
   for i in 1..array.count loop
       dbms_output.put_line(array(i));
   end loop;
end;

または無制限配列のTABLE：

...
   type array_t is table of varchar2(10);
...

ここで「テーブル」という言葉は、データベーステーブルとはまったく関係がなく、混乱を招きます。どちらの方法でも、メモリ内配列が作成されます。

これらのいずれかを使用して、要素を追加する前にコレクションを初期化および拡張する必要があります。

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t(); -- Initialise it
begin
   for i in 1..3 loop
      array.extend(); -- Extend it
      array(i) := 'x';
   end loop;
end;

最初のインデックスは0ではなく1です。

DBMS_SQL.VARCHAR2_TABLEを宣言して、BINARY_INTEGERによってインデックスが付けられたメモリ内の可変長配列を保持できます。

DECLARE
   name_array dbms_sql.varchar2_table;
BEGIN
   name_array(1) := 'Tim';
   name_array(2) := 'Daisy';
   name_array(3) := 'Mike';
   name_array(4) := 'Marsha';
   --
   FOR i IN name_array.FIRST .. name_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

メモリー内配列であるため、PL / SQL表と呼ばれていた連想配列を使用できます。

DECLARE
   TYPE employee_arraytype IS TABLE OF employee%ROWTYPE
        INDEX BY PLS_INTEGER;
   employee_array employee_arraytype;
BEGIN
   SELECT *
     BULK COLLECT INTO employee_array
     FROM employee
    WHERE department = 10;
   --
   FOR i IN employee_array.FIRST .. employee_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

連想配列は、あらゆる種類のレコードタイプを保持できます。

それが役に立てば幸い、Ollie。

別の解決策は、Oracleコレクションをハッシュマップとして使用することです。

declare 
-- create a type for your "Array" - it can be of any kind, record might be useful
  type hash_map is table of varchar2(1000) index by varchar2(30);
  my_hmap hash_map ;
-- i will be your iterator: it must be of the index's type
  i varchar2(30);
begin
  my_hmap('a') := 'apple';
  my_hmap('b') := 'box';
  my_hmap('c') := 'crow';
-- then how you use it:

  dbms_output.put_line (my_hmap('c')) ;

-- or to loop on every element - it's a "collection"
  i := my_hmap.FIRST;

  while (i is not null)  loop     
    dbms_output.put_line(my_hmap(i));      
    i := my_hmap.NEXT(i);
  end loop;

end;

また、 oracle defined collection

DECLARE 
  arrayvalues sys.odcivarchar2list;
BEGIN
  arrayvalues := sys.odcivarchar2list('Matt','Joanne','Robert');
  FOR x IN ( SELECT m.column_value m_value
               FROM table(arrayvalues) m )
  LOOP
    dbms_output.put_line (x.m_value||' is a good pal');
  END LOOP;
END;

インメモリ配列を使用します。しかし、.COUNTウジベリアによって提案された改善により：

DECLARE
  TYPE t_people IS TABLE OF varchar2(10) INDEX BY PLS_INTEGER;
  arrayvalues t_people;
BEGIN
  SELECT *
   BULK COLLECT INTO arrayvalues
   FROM (select 'Matt' m_value from dual union all
         select 'Joanne'       from dual union all
         select 'Robert'       from dual
    )
  ;
  --
  FOR i IN 1 .. arrayvalues.COUNT
  LOOP
    dbms_output.put_line(arrayvalues(i)||' is my friend');
  END LOOP;
END;

別の解決策は、@ Jchomelのようにハッシュマップを使用することです。 ここでたです。。

注意：

Oracle 12cを使用すると、配列を直接クエリすることもできます。

以下のサンプルプログラムとリンクにも提供 https://oracle-concepts-learning.blogspot.com/

plsqlテーブルまたは関連する配列。

        DECLARE 
            TYPE salary IS TABLE OF NUMBER INDEX BY VARCHAR2(20); 
            salary_list salary; 
            name VARCHAR2(20); 
        BEGIN 
           -- adding elements to the table 
           salary_list('Rajnish') := 62000; salary_list('Minakshi') := 75000; 
           salary_list('Martin') := 100000; salary_list('James') := 78000; 
           -- printing the table name := salary_list.FIRST; WHILE name IS NOT null 
            LOOP 
               dbms_output.put_line ('Salary of ' || name || ' is ' || 
               TO_CHAR(salary_list(name))); 
               name := salary_list.NEXT(name); 
            END LOOP; 
        END; 
        /