バッチファイル。ディレクトリ内のすべてのファイルとフォルダーを削除する

ワイヤレスツールキットのキャッシュフォルダーにあるすべてのフォルダーとファイルを削除するバッチファイルが必要です。

現在、私は以下を持っています：

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

これにより、RMSディレクトリ内のすべての.dbファイルが削除されますが、このディレクトリからすべてのものを削除したいと思います。これどうやってするの？

del *.*の代わりにdel *.db。それですべてが削除されます。

使用する：

• バッチファイルを作成する

• 以下のテキストをバッチファイルにコピーします

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

すべてのファイルとフォルダを削除します。

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

これにより、フォルダー（およびフォルダー自体）からすべてが削除されます。

del *.*ファイルのみを削除し、サブディレクトリは削除しません。ディレクトリの内容を核にするには、次のスクリプトを使用できます。

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

pushd子を削除するディレクトリへの変更。次にrd、現在のディレクトリとすべてのサブディレクトリを削除するように要求すると、サブディレクトリの削除は成功しますが、現在のディレクトリの削除は失敗します。これにより、2> NUL飲み込むエラーが発生します。（2はエラーストリームです）。

私はこれをmorty346が投稿したものからまとめました：

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

変数で定義されたフォルダが最初に存在することを簡単に確認し、ディレクトリをそのフォルダに変更し、内容を削除します。

delと/Sフラグを使用してこれを行うことができます（すべてのサブディレクトリからすべてのファイルを再帰するように指示します）。

del /S C:\Path\to\directory\*

RDのコマンドも使用することができます。プロンプトなしで再帰的にサイレントに削除します。

@RD /S /Q %VAR_PATH%

rmdir（rd）

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

以下を試してください。わたしにはできる。

「C：\ tmp」フォルダにデータをダンプするアプリケーションがあり、次のものが最適です。データの削除を「はい」または「いいえ」で要求することもありません。5分ごとに実行するようにスケジュールを設定しました

cd "C:\tmp"

del *.* /Q

さらに良いことに、私はC:\windows\tempフォルダの下にあるすべてのものを削除したいとしましょう。

@echo off
rd C:\windows\temp /s /q

robocopyを使用して、空のフォルダーをクリアするフォルダーにミラーリングできます。

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

実際のフォルダを削除または再作成できない場合にも機能します。

既存の空のディレクトリが必要です。

使用する

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

このバージョンは確認なしで削除します。

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

例：

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

これはクリアされC:\foo1\foo\foo\foo3ます。

_{（Abdullah Sabouinの回答について述べたいと思います。私が彼をコピーすることに混乱がありました。私は彼の投稿に気付きませんでした。エラーを指摘してくれたmelpomeneに感謝します！）}

いずれかrmdirまたはdel単独ですべてを削除することはできません。

• rmdir /s /qワイルドカードパラメータは使用できません。そうrmdir /s /q *エラーになります。
• del /s /f /q すべてのファイルを削除しますが、空のサブディレクトリは残ります。

（私が他の多くのバッチファイルで使用したので）私の好ましい解決策は：

rmdir /s /q . 2>NUL

GregMの回答の修正バージョン：

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

あなたは正しい軌道に乗っていました。削除されたフォルダを再び追加するコードを追加するだけです。

すべてのファイルを削除するには、次のコマンドを実行する必要があります。

del*.*