Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

基本的に、元のワークブックのすべてのシートをループしてから設定します destsheet現在反復されているシートと同じ名前のシートを、ターゲットのワークブックにします。

そのシートが存在するかどうかをどのようにテストできますか？何かのようなもの：

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then 

一部の人々は、エラー処理の「不適切な」使用のためにこのアプローチを嫌っていますが、VBAでは許容できると考えられています...別のアプローチは、一致が見つかるまですべてのシートをループすることです。

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

ワークシートのみに特に関心がある場合は、単純なEvaluate呼び出しを使用できます。

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

これを実行するためにエラー処理は必要ありません。あなたがしなければならないのは、すべてのワークシートを反復処理し、指定された名前が存在するかどうかを確認することだけです。

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

コレクションのメンバーをチェックすることは一般的な問題なので、ここにティムの答えの抽象化されたバージョンがあります：

関数Contains（objCollection As Object、strName as String）As Boolean
    オブジェクトを暗くする
    エラー時に再開
    set o = objCollection（strName）
    含む=（エラー番号= 0）
    エラークリア
 終了機能

この関数は、オブジェクト（のような任意のコレクションで使用することができShapes、Range、Names、Workbooks、など）。

シートの存在を確認するには、 If Contains(Sheets, "SheetName") ...

修正： エラー処理なし：

Function CheckIfSheetExists(SheetName As String) As Boolean
      CheckIfSheetExists = False
      For Each WS In Worksheets
        If SheetName = WS.name Then
          CheckIfSheetExists = True
          Exit Function
        End If
      Next WS
End Function

誰もがVBAを避け、純粋にセル数式内にワークシートが存在するかどうかをテストする場合は、ISREFおよびINDIRECT関数を使用して可能です。

=ISREF(INDIRECT("SheetName!A1"))

これは戻りますTRUE、ブックと呼ばれるシートが含まれている場合SheetNameとFALSEそうでありませんの。

私はこれを書いた：

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

私の解決策はTimsによく似ていますが、ワークシートシート以外の場合にも機能します-グラフ

Public Function SheetExists(strSheetName As String, Optional wbWorkbook As Workbook) As Boolean
    If wbWorkbook Is Nothing Then Set wbWorkbook = ActiveWorkbook 'or ThisWorkbook - whichever appropriate
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbWorkbook.Sheets(strSheetName)
    SheetExists = True
    Exit Function
HandleError:
    SheetExists = False
End Function

。

テストを関数に入れると、それを再利用できるようになり、コードが読みやすくなります。

「On Error Resume Next」はコードの他の部分と競合する可能性があるため、使用しないでください。

Sub DoesTheSheetExists()
    If SheetExist("SheetName") Then
        Debug.Print "The Sheet Exists"
    Else
        Debug.Print "The Sheet Does NOT Exists"
    End If
End Sub

Function SheetExist(strSheetName As String) As Boolean
    Dim i As Integer

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = strSheetName Then
            SheetExist = True
            Exit Function
        End If
    Next i
End Function

何年も遅れたが、私はこれを行う必要があり、投稿されたソリューションのどれも好きではなかった...それで、私は1つを作成した。

Evaluate("IsError(" & vSheetName & "!1:1)")

Sheetが存在しない場合はTRUEを返します。シートが存在する場合はFALSE。「1：1」は任意の範囲に置き換えることができますが、エラー（＃N / Aなど）が含まれている場合はTrueを返す単一のセルを使用しないことをお勧めします。

コンパクトなwsExists機能_{^{（エラー処理に依存しない！）}}

以下は、ワークシートが存在するかどうかを判断するためのエラー処理に依存しない、短くてシンプルな関数です（そして、どのような状況でも機能するように適切に宣言されています！）

Function wsExists(wsName As String) As Boolean
    Dim ws: For Each ws In Sheets
    wsExists = (wsName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

使用例：

次の例では、という名前の新しいワークシートmyNewSheetがまだ存在しない場合、追加します。

If Not wsExists("myNewSheet") Then Sheets.Add.Name = "myNewSheet"

詳しくは：

• MSDN：For Each… Nextステートメント（VBA）
• MSDN：Exitステートメント（VBA）
• MSDN：比較演算子（VBA）

小さなループを使用して、名前付きワークシートが存在するかどうかを判断しないのはなぜですか？現在開いているワークブックで「Sheet1」という名前のワークシートを探していたとしましょう。

Dim wb as Workbook
Dim ws as Worksheet

Set wb = ActiveWorkbook

For Each ws in wb.Worksheets

    if ws.Name = "Sheet1" then
        'Do something here
    End if

Next

あなたはのファンならWorksheetFunction.またはあなたは、これは良い解決策、その作品で英語以外のエクセルで英語以外の国からの仕事します：

WorksheetFunction.IsErr(Evaluate("'" & wsName & "'!A1"))

または次のような関数で：

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Not WorksheetFunction.IsErr(Evaluate("'" & sName & "'!A1"))
End Function

Public Function WorkSheetExists(ByVal strName As String) As Boolean
   On Error Resume Next
   WorkSheetExists = Not Worksheets(strName) Is Nothing
End Function

sub test_sheet()

 If Not WorkSheetExists("SheetName") Then
 MsgBox "Not available"
Else MsgBox "Available"
End If

End Sub

    For Each Sheet In Worksheets
    If UCase(Sheet.Name) = "TEMP" Then
    'Your Code when the match is True
        Application.DisplayAlerts = False
        Sheet.Delete
        Application.DisplayAlerts = True
    '-----------------------------------
    End If
Next Sheet

「データ」を、テストしているシート名に変更します...

On Error Resume Next 

Set DataSheet = Sheets("Data")

If DataSheet Is Nothing Then

     Sheets.Add(after:=ActiveSheet).Name = "Data"
     ''or whatever alternate code you want to execute''
End If

On Error GoTo 0

上記の関数が機能することは間違いありませんが、次のコードでかなりうまくいきました。

Sub Sheet_exist ()
On Error Resume Next
If Sheets("" & Range("Sheet_Name") & "") Is Nothing Then
    MsgBox "doesnt exist"
Else
    MsgBox "exist"
End if
End sub

注：Sheets_Nameここでは、ユーザーに名前の入力を求めています。そのため、これは同じではない場合があります。

私は別のことをしました：シートが存在する場合にのみシートを削除します-シートが存在しない場合でもエラーになりません：

Excel.DisplayAlerts = False 
Dim WS
For Each WS In Excel.Worksheets
    If WS.name = "Sheet2" Then
        Excel.sheets("Sheet2").Delete
        Exit For
    End If
Next
Excel.DisplayAlerts = True

簡単な方法を考え出しましたが、そのための新しいサブを作成していません。代わりに、私が取り組んでいたサブ内で「チェックを実行」しました。私たちが探しているシート名が「Sheet_Exist」であり、見つかった場合にそれをアクティブ化したいと仮定します。

Dim SheetCounter As Integer

SheetCounter = 1

Do Until Sheets(SheetCounter).Name = "Sheet_Exist" Or SheetCounter = Sheets.Count + 1
 SheetCounter = SheetCounter +1
Loop
If SheetCounter < Sheets.Count + 1 Then
 Sheets("Sheet_Exist").Activate
Else
 MsgBox("Worksheet ""Sheet_Exist"" was NOT found")
End If

シートが存在しない場合のポップアップも追加しました。

私はそれが古い記事であることを知っていますが、これは高速な別の簡単な解決策です。

Public Function worksheetExists(ByVal wb As Workbook, ByVal sheetNameStr As String) As Boolean

On Error Resume Next
worksheetExists = (wb.Worksheets(sheetNameStr).Name <> "")
Err.Clear: On Error GoTo 0

End Function

短くてきれい：

Function IsSheet(n$) As Boolean
    IsSheet = Not IsError(Evaluate(n & "!a1"))
End Function

実際には、シートが存在するかどうかを確認してからいくつかの命令を実行する簡単な方法がありました。

私の場合、シートを削除してから同じ名前で同じシートを再作成したかったのですが、すでに削除されているためプログラムがシートを削除できなかった場合、コードが中断されました。

Sub Foo ()

    Application.DisplayAlerts = False

    On Error GoTo instructions
    Sheets("NAME OF THE SHEET").Delete

    instructions:

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "NAME OF THE SHEET"

End Sub