TSQL-BEGIN .. ENDブロック内でGOを使用する方法

複数の開発データベースからステージング/プロダクションに変更を自動的に移行するためのスクリプトを生成しています。基本的に、これは一連の変更スクリプトを受け取り、それらを単一のスクリプトにマージして、各スクリプトをIF whatever BEGIN ... ENDステートメントにラップします。

ただし、一部のスクリプトではGOステートメントが必要になるため、たとえば、SQLパーサーは、作成後に新しい列を認識します。

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

しかし、それをIFブロックでラップすると：

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

BEGIN一致しないを送信しているため、失敗しますEND。しかし、それを削除するGOと、不明な列について再び不平を言います。

単一のIFブロック内で同じ列を作成および更新する方法はありますか？

私は同じ問題を抱えていて、ついにSET NOEXECを使用してそれを解決することができました。

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO SQLではありません-これは単に、一部のMS SQLツールで使用されるバッチセパレータです。

これを使用しない場合は、ステートメントが個別に実行されるようにする必要があります-異なるバッチで、またはポピュレーションに動的SQLを使用して（@gbnに感謝）：

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

以下の例に示すように、sp_executesql各GOステートメント間のコンテンツを個別の文字列に分割して実行することができます。また、例外が発生したデバッグを容易にするために実行されているステートメントを追跡する@statementNo変数もあります。行番号は、エラーの原因となった関連するステートメント番号の先頭を基準にしています。

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

上記の例で示したように、複数行のステートメントを単一引用符（'）で囲むだけで簡単に実行することもできます。''スクリプトを生成するときは、文字列内に含まれる一重引用符を二重一重引用符（）でエスケープすることを忘れないでください。

私は最終的にそれをGOそれ自身の行のすべてのインスタンスを

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

これは、ステートメントのすべてのグループを文字列でラップするよりもはるかに望ましい方法ですが、理想とはほど遠いものです。誰かがより良い解決策を見つけたら、投稿してください。代わりにそれを受け入れます。

文の間のGOではなく、BEGINとENDでステートメントを囲むことができます。

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

（Northwindデータベースでテスト済み）

編集：（おそらくSQL2012でテスト済み）

あなたはこの解決策を試すことができます：

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

RAISERROR過去に使ったことがあります

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

GOTOand LABELステートメントを組み込んでコードをスキップし、GOキーワードをそのままにしておくことができます。