SQL Serverのforループの構文

forTSQLのループの構文は何ですか？

T-SQLにはFORループがありませんが、ループがありWHILEます
WHILE（Transact-SQL）

WHILE Boolean_expression
BEGIN

END

forループはなく、whileループのみです。

DECLARE @i int = 0

WHILE @i < 20
BEGIN
    SET @i = @i + 1
    /* do some work */
END

追加情報

ループ内のデータセットを実際に反復する方法を含む回答を誰も投稿していないので、追加するために、キーワードOFFSET FETCHを使用できます。

使用法

DECLARE @i INT = 0;
SELECT @count=  Count(*) FROM {TABLE}

WHILE @i <= @count
BEGIN

    SELECT * FROM {TABLE}
    ORDER BY {COLUMN}
    OFFSET @i ROWS   
    FETCH NEXT 1 ROWS ONLY  

    SET @i = @i + 1;

END

DECLARE @intFlag INT
SET @intFlag = 1
WHILE (@intFlag <=5) 
BEGIN
    PRINT @intFlag
    SET @intFlag = @intFlag + 1
END
GO

これはどう：

BEGIN
   Do Something
END
GO 10

...もちろん、カウントする必要がある場合は、その中に増分カウンターを置くことができます。

forループは、SQLサーバーではまだ正式にサポートされていません。FORを達成するための答えはすでにありますループのさまざまな方法ます。SQL Serverでさまざまな種類のループを実現する方法について詳しく説明しています。

FORループ

DECLARE @cnt INT = 0;

WHILE @cnt < 10
BEGIN
   PRINT 'Inside FOR LOOP';
   SET @cnt = @cnt + 1;
END;

PRINT 'Done FOR LOOP';

わかっている場合は、とにかくループの最初の反復を完了する必要がある場合は、SQLサーバーのDO..WHILEまたはREPEAT..UNTILバージョンを試すことができます。

DO..WHILEループ

DECLARE @X INT=1;

WAY:  --> Here the  DO statement

  PRINT @X;

  SET @X += 1;

IF @X<=10 GOTO WAY;

REPEAT..UNTILループ

DECLARE @X INT = 1;

WAY:  -- Here the REPEAT statement

  PRINT @X;

  SET @X += 1;

IFNOT(@X > 10) GOTO WAY;

参照

簡単な答えはNO !!です。

そこにはありませんFORSQLで、しかし、あなたは使用することができますWHILEまたはGOTOどのような方法を達成するためにFOR動作しますが。

WHILE：

DECLARE @a INT = 10

WHILE @a <= 20
BEGIN
    PRINT @a
    SET @a = @a + 1
END

GOTO：

DECLARE @a INT = 10
a:
PRINT @a
SET @a = @a + 1
IF @a < = 20
BEGIN
    GOTO a
END

私はいつも好むWHILE上GOTOの文。

T-SQLのWhileループの例は、当月の開始日から終了日までをリストしています。

DECLARE @Today DATE= GETDATE() ,
@StartOfMonth DATE ,
@EndOfMonth DATE;

DECLARE @DateList TABLE ( DateLabel VARCHAR(10) );
SET @EndOfMonth = EOMONTH(GETDATE());
SET @StartOfMonth = DATEFROMPARTS(YEAR(@Today), MONTH(@Today), 1);

WHILE @StartOfMonth <= @EndOfMonth
BEGIN
    INSERT  INTO @DateList
    VALUES  ( @StartOfMonth );
    SET @StartOfMonth = DATEADD(DAY, 1, @StartOfMonth);
END;

SELECT  DateLabel
FROM    @DateList;  

試して、学んでください：

DECLARE @r INT = 5
DECLARE @i INT = 0
DECLARE @F varchar(max) = ''
WHILE @i < @r
BEGIN

    DECLARE @j INT = 0
    DECLARE @o varchar(max) = ''
    WHILE @j < @r - @i - 1
    BEGIN
        SET @o = @o + ' '
        SET @j += 1
    END

    DECLARE @k INT = 0
    WHILE @k < @i + 1
    BEGIN
        SET @o = @o + ' *'  -- '*'
        SET @k += 1
    END
    SET @i += 1
    SET @F = @F + @o + CHAR(13)
END
PRINT @F

日付あり：

DECLARE @d DATE = '2019-11-01'
WHILE @d < GETDATE()
BEGIN
    PRINT @d
    SET @d = DATEADD(DAY,1,@d)
END
PRINT 'n'
PRINT @d